meta-openembedded: subtree update:fd1a0c9210..1bfaa2e63a

Alex Kiernan (1):
      ostree: Upgrade 2019.3 -> 2019.4

Alexander Kanavin (1):
      lua: change a hard readline dependency into an optional one

Andreas Müller (5):
      catfish: upgrade 1.4.9 -> 1.4.10
      polkit-group-rules: Fix error in do_rootfs for rpm package-manager
      jack: upgrade 1.9.12 -> 1.9.13
      fluidsynth: upgrade 2.0.6 -> 2.0.7
      xfce4-panel: upgrade 4.14.0 -> 4.14.1

Bartosz Golaszewski (3):
      networkd-dispatcher: use distro_features_check to check for systemd
      networkd-dispatcher: remove unneeded RDEPENDS
      networkd-dispatcher: inherit systemd class

Changqing Li (1):
      multipath-tools: upgrade 0.8.1 -> 0.8.2

Hongxu Jia (1):
      lvm2: remove unsupported OPTIONS+="event_timeout" rule

Khem Raj (6):
      nvme-cli: Use install-spec target
      jsonrpc: Disable coverage in default build
      bdwgc: Enable C++ support and Additional options for musl
      a2jmidid: Fix build on risv
      tinyalsa: Update to latest
      packagegroup-meta-multimedia: Remove libsquish from rdeps

Martin Schwan (1):
      python-waitress: Add recipes

Paul Eggleton (1):
      mosquitto: update to 1.6.7

Peiran Hong (1):
      tcpdump: Delete unused patch

Peter Kjellerstedt (1):
      kconfig-frontends: Retrieve the Git repository from GitLab

Randy MacLeod (1):
      rwmem: add DESCRIPTION since the summary is vague

Trevor Gamblin (1):
      rsyslog: fix CVE-2019-17040

Zang Ruochen (7):
      firewalld: upgrade 0.7.1 -> 0.7.2
      fetchmail: upgrade 6.3.26 -> 6.4.1
      python-asn1crypto: upgrade 0.24.0 -> 1.0.1
      python-attrs: upgrade 19.1.0 -> 19.2.0
      python-beautifulsoup4: upgrade 4.8.0 -> 4.8.1
      python-cmd2: upgrade 0.9.17 -> 0.9.18
      python-jinja2: upgrade 2.10.1 -> 2.10.3

Change-Id: Ief2d129403b43b308c19093ac63a498c8d51eb50
Signed-off-by: Brad Bishop <bradleyb@fuzziesquirrel.com>

1 files changed, 98 insertions, 0 deletions

diff --git a/meta-openembedded/meta-networking/recipes-connectivity/mosquitto/mosquitto_1.6.7.bb b/meta-openembedded/meta-networking/recipes-connectivity/mosquitto/mosquitto_1.6.7.bb
new file mode 100644
index 000000000..340f643d4
--- /dev/null
+++ b/meta-openembedded/meta-networking/recipes-connectivity/mosquitto/mosquitto_1.6.7.bb
@@ -0,0 +1,98 @@
+SUMMARY = "Open source MQTT implementation"
+DESCRIPTION = "Mosquitto is an open source (Eclipse licensed) message broker \
+that implements the MQ Telemetry Transport protocol version 3.1, 3.1.1 and \
+5, providing both an MQTT broker and several command-line clients. MQTT \
+provides a lightweight method of carrying out messaging using a \
+publish/subscribe model. "
+HOMEPAGE = "http://mosquitto.org/"
+SECTION = "console/network"
+LICENSE = "EPL-1.0 | EDL-1.0"
+LIC_FILES_CHKSUM = "file://LICENSE.txt;md5=62ddc846179e908dc0c8efec4a42ef20 \
+                    file://edl-v10;md5=c09f121939f063aeb5235972be8c722c \
+                    file://epl-v10;md5=8d383c379e91d20ba18a52c3e7d3a979 \
+                    file://notice.html;md5=a00d6f9ab542be7babc2d8b80d5d2a4c \
+"
+DEPENDS = "uthash"
+
+SRC_URI = "http://mosquitto.org/files/source/mosquitto-${PV}.tar.gz \
+           file://mosquitto.init \
+"
+
+SRC_URI[md5sum] = "ec9074c4f337f64eaa9a4320c6dab020"
+SRC_URI[sha256sum] = "bcd31a8fbbd053fee328986fadd8666d3058357ded56b9782f7d4f19931d178e"
+
+inherit systemd update-rc.d useradd
+
+PACKAGECONFIG ??= "ssl uuid \
+                  ${@bb.utils.filter('DISTRO_FEATURES','systemd', d)} \
+                  "
+
+PACKAGECONFIG[dns-srv] = "WITH_SRV=yes,WITH_SRV=no,c-ares"
+PACKAGECONFIG[ssl] = "WITH_TLS=yes WITH_TLS_PSK=yes,WITH_TLS=no WITH_TLS_PSK=no,openssl"
+PACKAGECONFIG[uuid] = "WITH_UUID=yes,WITH_UUID=no,util-linux"
+PACKAGECONFIG[systemd] = "WITH_SYSTEMD=yes,WITH_SYSTEMD=no,systemd"
+PACKAGECONFIG[websockets] = "WITH_WEBSOCKETS=yes,WITH_WEBSOCKETS=no,libwebsockets"
+
+EXTRA_OEMAKE = " \
+    prefix=${prefix} \
+    mandir=${mandir} \
+    localedir=${localedir} \
+    ${PACKAGECONFIG_CONFARGS} \
+    STRIP=/bin/true \
+    WITH_DOCS=no \
+    WITH_BUNDLED_DEPS=no \
+"
+
+export LIB_SUFFIX = "${@d.getVar('baselib').replace('lib', '')}"
+
+do_install() {
+    oe_runmake 'DESTDIR=${D}' install
+
+    install -d ${D}${systemd_unitdir}/system/
+    install -m 0644 ${S}/service/systemd/mosquitto.service.notify ${D}${systemd_unitdir}/system/mosquitto.service
+
+    install -d ${D}${sysconfdir}/mosquitto
+    install -m 0644 ${D}${sysconfdir}/mosquitto/mosquitto.conf.example \
+                    ${D}${sysconfdir}/mosquitto/mosquitto.conf
+
+    install -d ${D}${sysconfdir}/init.d/
+    install -m 0755 ${WORKDIR}/mosquitto.init ${D}${sysconfdir}/init.d/mosquitto
+    sed -i -e 's,@SBINDIR@,${sbindir},g' \
+        -e 's,@BASE_SBINDIR@,${base_sbindir},g' \
+        -e 's,@LOCALSTATEDIR@,${localstatedir},g' \
+        -e 's,@SYSCONFDIR@,${sysconfdir},g' \
+        ${D}${sysconfdir}/init.d/mosquitto
+}
+
+PACKAGES += "libmosquitto1 libmosquittopp1 ${PN}-clients"
+
+PACKAGE_BEFORE_PN = "${PN}-examples"
+
+FILES_${PN} = "${sbindir}/mosquitto \
+               ${bindir}/mosquitto_passwd \
+               ${sysconfdir}/mosquitto \
+               ${sysconfdir}/init.d \
+               ${systemd_unitdir}/system/mosquitto.service \
+"
+
+CONFFILES_${PN} += "${sysconfdir}/mosquitto/mosquitto.conf"
+
+FILES_libmosquitto1 = "${libdir}/libmosquitto.so.1"
+
+FILES_libmosquittopp1 = "${libdir}/libmosquittopp.so.1"
+
+FILES_${PN}-clients = "${bindir}/mosquitto_pub \
+                       ${bindir}/mosquitto_sub \
+                       ${bindir}/mosquitto_rr \
+"
+
+FILES_${PN}-examples = "${sysconfdir}/mosquitto/*.example"
+
+SYSTEMD_SERVICE_${PN} = "mosquitto.service"
+
+INITSCRIPT_NAME = "mosquitto"
+INITSCRIPT_PARAMS = "defaults 30"
+
+USERADD_PACKAGES = "${PN}"
+USERADD_PARAM_${PN} = "--system --no-create-home --shell /bin/false \
+                       --user-group mosquitto"