meta-openembedded: subtree update:9fdc7960ba..e4a3c66505

Alexander Kanavin (4):
      msgpack-c: update 3.2.1 -> 4.0.0, add msgpack-cpp
      can-utils: rrecommend iproute2 to make it possible to configure can interfaces
      fmt: update 7.1.3 -> 8.0.1
      spdlog: update 1.8.2 -> 1.9.2

Changqing Li (3):
      ndpi: upgrade 3.4 -> 4.0
      ntopng: upgrade 4.2 -> 5.0
      postgresql: upgrade 13.3 -> 13.4

Jan-Simon Moeller (1):
      Remove patch that produces a segfault in the ptest of lua

Joe Slater (1):
      redis: advance to version 6.2.5

Khem Raj (10):
      gjs: Remove valgrind dependency on rv32/rv64
      toybox-inittab: Use 0BSD for LIC_FILES_CHKSUM
      python3-kivy: Remove hardcoded include paths
      python3-kivy: Check for x11 and opengl before enabling the recipe
      packagegroup-meta-python: Add python3-kivy
      packagegroup-meta-python: Add python3-portalocker
      gst-shark: Define SRCREV_FORMAT
      android-tools: Define SRCREV_FORMAT
      packagegroup-meta-oe: Add pahole
      pahole: Add missing rdep for python

Kristian Klausen (1):
      cryptsetup: Add runtime dependency on lvm2-udevrules for udev

Martin Jansa (1):
      python3-regex: upgrade to 2021.8.28

Matteo Croce (2):
      recipes-devtools: add pahole
      libbpf: bump to 0.5.0

Mingli Yu (1):
      polkit: add the CVE tag

Patrick Williams (2):
      gjs: fix typo in RDEPENDS variable name
      ndisc6: fix typo in DESCRIPTION variable name

Peter Morrow (1):
      libbpf: remove kernel configuration dependency

Samuel Dolt (4):
      python3-alembic: add native and nativesdk to BBCLASSEXTEND
      python3-editor: add native and nativesdk to BBCLASSEXTEND
      python3-sqlalchemy: add native and nativesdk to BBCLASSEXTEND
      python3-portalocker: add recipe

Trevor Gamblin (2):
      python3-pytest-subtests: add recipe
      python3-pillow: upgrade 8.3.1 -> 8.3.2

Wang Mingyu (3):
      python3-cryptography-vectors: upgrade 3.4.7 -> 3.4.8
      python3-google-api-python-client: upgrade 2.18.0 -> 2.19.1
      dnf-plugin-tui: upgrade 1.2 -> 1.3

William A. Kennington III (1):
      ndisc6: Upgrade 1.0.4 -> 1.0.5

William Huang (1):
      recipes-devtools: python: add support for Kivy

Yi Zhao (4):
      krb5: fix CVE-2021-36222
      krb5: fix CVE-2021-37750
      net-snmp: drop unused patch
      net-snmp: make sure snmpd always exit after displaying usage

wangmy (10):
      cjson: upgrade 1.7.14 -> 1.7.15
      libwebsockets: upgrade 4.2.1 -> 4.2.2
      monit: upgrade 5.28.1 -> 5.29.0
      nlohmann-json: upgrade 3.9.1 -> 3.10.2
      cppzmq: upgrade 4.7.1 -> 4.8.0
      dfu-util: upgrade 0.10 -> 0.11
      libqmi: upgrade 1.30.0 -> 1.30.2
      lockfile-progs: upgrade 0.1.18 -> 0.1.19
      poppler-data: upgrade 0.4.10 -> 0.4.11
      dnsmasq: upgrade 2.85 -> 2.86

zangrc (11):
      python3-ipython: upgrade 7.26.0 -> 7.27.0
      python3-kiwisolver: upgrade 1.3.1 -> 1.3.2
      python3-ruamel-yaml: upgrade 0.17.13 -> 0.17.16
      python3-traitlets: upgrade 5.0.5 -> 5.1.0
      gsl: upgrade 2.6 -> 2.7
      crash: upgrade 7.2.9 -> 7.3.0
      dash: upgrade 0.5.11.3 -> 0.5.11.5
      python3-bitarray: upgrade 2.3.2 -> 2.3.3
      python3-lrparsing: upgrade 1.0.16 -> 1.0.17
      python3-transitions: upgrade 0.8.8 -> 0.8.9
      libxmlb: upgrade 0.3.1 -> 0.3.2

zhengruoqin (15):
      wireshark: upgrade 3.4.7 -> 3.4.8
      uhubctl: upgrade 2.3.0 -> 2.4.0
      unclutter-xfixes: upgrade 1.5 -> 1.6
      avro-c: upgrade 1.9.2 -> 1.10.2
      ctags: upgrade 5.9.20210815 -> 5.9.20210905
      xf86-video-nouveau: upgrade 1.0.16 -> 1.0.17
      fuse3: upgrade 3.10.4 -> 3.10.5
      mosquitto: upgrade 2.0.11 -> 2.0.12
      poppler: upgrade 21.08.0 -> 21.09.0
      libbytesize: upgrade 2.4 -> 2.6
      libeigen: upgrade 3.3.9 -> 3.4.0
      libjcat: upgrade 0.1.7 -> 0.1.8
      unbound: upgrade 1.12.0 -> 1.13.2
      xterm: upgrade 367 -> 368
      zchunk: upgrade 1.1.9 -> 1.1.16

Change-Id: I5a866e7773b8c906bc2bd8a4ddf99f006534bf53
Signed-off-by: William A. Kennington III <wak@google.com>

1 files changed, 90 insertions, 0 deletions

diff --git a/meta-openembedded/meta-networking/recipes-connectivity/mosquitto/mosquitto_2.0.12.bb b/meta-openembedded/meta-networking/recipes-connectivity/mosquitto/mosquitto_2.0.12.bb
new file mode 100644
index 000000000..2df400846
--- /dev/null
+++ b/meta-openembedded/meta-networking/recipes-connectivity/mosquitto/mosquitto_2.0.12.bb
@@ -0,0 +1,90 @@
+SUMMARY = "Open source MQTT implementation"
+DESCRIPTION = "Mosquitto is an open source (Eclipse licensed) message broker \
+that implements the MQ Telemetry Transport protocol version 3.1, 3.1.1 and \
+5, providing both an MQTT broker and several command-line clients. MQTT \
+provides a lightweight method of carrying out messaging using a \
+publish/subscribe model. "
+HOMEPAGE = "http://mosquitto.org/"
+SECTION = "console/network"
+LICENSE = "EPL-2.0 | EDL-1.0"
+LIC_FILES_CHKSUM = "file://LICENSE.txt;md5=ca9a8f366c6babf593e374d0d7d58749 \
+                    file://edl-v10;md5=c09f121939f063aeb5235972be8c722c \
+                    file://epl-v20;md5=d9fc0efef5228704e7f5b37f27192723 \
+                    file://NOTICE.md;md5=a7a91b4754c6f7995020d1b49bc829c6 \
+"
+DEPENDS = "uthash cjson dlt-daemon"
+
+SRC_URI = "http://mosquitto.org/files/source/mosquitto-${PV}.tar.gz \
+           file://mosquitto.init \
+           file://1571.patch \
+"
+
+SRC_URI[sha256sum] = "31cf0065cb431d6f4e57a5f4d56663e839c9d177362eff89582d7cfde191c933"
+
+inherit systemd update-rc.d useradd cmake
+
+PACKAGECONFIG ??= "ssl dlt websockets \
+                  ${@bb.utils.filter('DISTRO_FEATURES','systemd', d)} \
+                  "
+
+PACKAGECONFIG[manpages] = "-DDOCUMENTATION=ON,-DDOCUMENTATION=OFF,libxslt-native docbook-xsl-stylesheets-native"
+PACKAGECONFIG[dns-srv] = "-DWITH_SRV=ON,-DWITH_SRV=OFF,c-ares"
+PACKAGECONFIG[ssl] = "-DWITH_TLS=ON -DWITH_TLS_PSK=ON -DWITH_EC=ON,-DWITH_TLS=OFF -DWITH_TLS_PSK=OFF -DWITH_EC=OFF,openssl"
+PACKAGECONFIG[systemd] = "-DWITH_SYSTEMD=ON,-DWITH_SYSTEMD=OFF,systemd"
+PACKAGECONFIG[websockets] = "-DWITH_WEBSOCKETS=ON,-DWITH_WEBSOCKETS=OFF,libwebsockets"
+PACKAGECONFIG[dlt] = "-DWITH_DLT=ON,-DWITH_DLT=OFF,dlt-daemon"
+
+EXTRA_OECMAKE = " \
+    -DWITH_BUNDLED_DEPS=OFF \
+    -DWITH_ADNS=ON \
+"
+
+do_install:append() {
+    install -d ${D}${systemd_unitdir}/system/
+    install -m 0644 ${S}/service/systemd/mosquitto.service.notify ${D}${systemd_unitdir}/system/mosquitto.service
+
+    install -d ${D}${sysconfdir}/init.d/
+    install -m 0755 ${WORKDIR}/mosquitto.init ${D}${sysconfdir}/init.d/mosquitto
+    sed -i -e 's,@SBINDIR@,${sbindir},g' \
+        -e 's,@BASE_SBINDIR@,${base_sbindir},g' \
+        -e 's,@LOCALSTATEDIR@,${localstatedir},g' \
+        -e 's,@SYSCONFDIR@,${sysconfdir},g' \
+        ${D}${sysconfdir}/init.d/mosquitto
+}
+
+PACKAGES += "libmosquitto1 libmosquittopp1 ${PN}-clients"
+
+PACKAGE_BEFORE_PN = "${PN}-examples"
+
+FILES:${PN} = "${sbindir}/mosquitto \
+               ${bindir}/mosquitto_passwd \
+               ${bindir}/mosquitto_ctrl \
+               ${libdir}/mosquitto_dynamic_security.so \
+               ${sysconfdir}/mosquitto \
+               ${sysconfdir}/init.d \
+               ${systemd_unitdir}/system/mosquitto.service \
+"
+
+CONFFILES:${PN} += "${sysconfdir}/mosquitto/mosquitto.conf"
+
+FILES:libmosquitto1 = "${libdir}/libmosquitto.so.*"
+
+FILES:libmosquittopp1 = "${libdir}/libmosquittopp.so.*"
+
+FILES:${PN}-clients = "${bindir}/mosquitto_pub \
+                       ${bindir}/mosquitto_sub \
+                       ${bindir}/mosquitto_rr \
+"
+
+FILES:${PN}-examples = "${sysconfdir}/mosquitto/*.example"
+
+SYSTEMD_SERVICE:${PN} = "mosquitto.service"
+
+INITSCRIPT_NAME = "mosquitto"
+INITSCRIPT_PARAMS = "defaults 30"
+
+USERADD_PACKAGES = "${PN}"
+USERADD_PARAM:${PN} = "--system --no-create-home --shell /bin/false \
+                       --user-group mosquitto"
+
+BBCLASSEXTEND += "native nativesdk"