diff options
author | William A. Kennington III <wak@google.com> | 2021-09-16 02:19:36 +0300 |
---|---|---|
committer | Andrew Geissler <geissonator@yahoo.com> | 2021-09-19 20:39:58 +0300 |
commit | 49e9566eb60669f7b1535f0653aa52a1c9ea8af0 (patch) | |
tree | d9b5df56dd979a0d096c11d8b14711c9a7aefe57 /meta-openembedded/meta-networking/recipes-support/wireshark/wireshark_3.4.8.bb | |
parent | 7f8954e7a7576c28a6773be2f0e306551c0aa754 (diff) | |
download | openbmc-49e9566eb60669f7b1535f0653aa52a1c9ea8af0.tar.xz |
meta-openembedded: subtree update:9fdc7960ba..e4a3c66505
Alexander Kanavin (4):
msgpack-c: update 3.2.1 -> 4.0.0, add msgpack-cpp
can-utils: rrecommend iproute2 to make it possible to configure can interfaces
fmt: update 7.1.3 -> 8.0.1
spdlog: update 1.8.2 -> 1.9.2
Changqing Li (3):
ndpi: upgrade 3.4 -> 4.0
ntopng: upgrade 4.2 -> 5.0
postgresql: upgrade 13.3 -> 13.4
Jan-Simon Moeller (1):
Remove patch that produces a segfault in the ptest of lua
Joe Slater (1):
redis: advance to version 6.2.5
Khem Raj (10):
gjs: Remove valgrind dependency on rv32/rv64
toybox-inittab: Use 0BSD for LIC_FILES_CHKSUM
python3-kivy: Remove hardcoded include paths
python3-kivy: Check for x11 and opengl before enabling the recipe
packagegroup-meta-python: Add python3-kivy
packagegroup-meta-python: Add python3-portalocker
gst-shark: Define SRCREV_FORMAT
android-tools: Define SRCREV_FORMAT
packagegroup-meta-oe: Add pahole
pahole: Add missing rdep for python
Kristian Klausen (1):
cryptsetup: Add runtime dependency on lvm2-udevrules for udev
Martin Jansa (1):
python3-regex: upgrade to 2021.8.28
Matteo Croce (2):
recipes-devtools: add pahole
libbpf: bump to 0.5.0
Mingli Yu (1):
polkit: add the CVE tag
Patrick Williams (2):
gjs: fix typo in RDEPENDS variable name
ndisc6: fix typo in DESCRIPTION variable name
Peter Morrow (1):
libbpf: remove kernel configuration dependency
Samuel Dolt (4):
python3-alembic: add native and nativesdk to BBCLASSEXTEND
python3-editor: add native and nativesdk to BBCLASSEXTEND
python3-sqlalchemy: add native and nativesdk to BBCLASSEXTEND
python3-portalocker: add recipe
Trevor Gamblin (2):
python3-pytest-subtests: add recipe
python3-pillow: upgrade 8.3.1 -> 8.3.2
Wang Mingyu (3):
python3-cryptography-vectors: upgrade 3.4.7 -> 3.4.8
python3-google-api-python-client: upgrade 2.18.0 -> 2.19.1
dnf-plugin-tui: upgrade 1.2 -> 1.3
William A. Kennington III (1):
ndisc6: Upgrade 1.0.4 -> 1.0.5
William Huang (1):
recipes-devtools: python: add support for Kivy
Yi Zhao (4):
krb5: fix CVE-2021-36222
krb5: fix CVE-2021-37750
net-snmp: drop unused patch
net-snmp: make sure snmpd always exit after displaying usage
wangmy (10):
cjson: upgrade 1.7.14 -> 1.7.15
libwebsockets: upgrade 4.2.1 -> 4.2.2
monit: upgrade 5.28.1 -> 5.29.0
nlohmann-json: upgrade 3.9.1 -> 3.10.2
cppzmq: upgrade 4.7.1 -> 4.8.0
dfu-util: upgrade 0.10 -> 0.11
libqmi: upgrade 1.30.0 -> 1.30.2
lockfile-progs: upgrade 0.1.18 -> 0.1.19
poppler-data: upgrade 0.4.10 -> 0.4.11
dnsmasq: upgrade 2.85 -> 2.86
zangrc (11):
python3-ipython: upgrade 7.26.0 -> 7.27.0
python3-kiwisolver: upgrade 1.3.1 -> 1.3.2
python3-ruamel-yaml: upgrade 0.17.13 -> 0.17.16
python3-traitlets: upgrade 5.0.5 -> 5.1.0
gsl: upgrade 2.6 -> 2.7
crash: upgrade 7.2.9 -> 7.3.0
dash: upgrade 0.5.11.3 -> 0.5.11.5
python3-bitarray: upgrade 2.3.2 -> 2.3.3
python3-lrparsing: upgrade 1.0.16 -> 1.0.17
python3-transitions: upgrade 0.8.8 -> 0.8.9
libxmlb: upgrade 0.3.1 -> 0.3.2
zhengruoqin (15):
wireshark: upgrade 3.4.7 -> 3.4.8
uhubctl: upgrade 2.3.0 -> 2.4.0
unclutter-xfixes: upgrade 1.5 -> 1.6
avro-c: upgrade 1.9.2 -> 1.10.2
ctags: upgrade 5.9.20210815 -> 5.9.20210905
xf86-video-nouveau: upgrade 1.0.16 -> 1.0.17
fuse3: upgrade 3.10.4 -> 3.10.5
mosquitto: upgrade 2.0.11 -> 2.0.12
poppler: upgrade 21.08.0 -> 21.09.0
libbytesize: upgrade 2.4 -> 2.6
libeigen: upgrade 3.3.9 -> 3.4.0
libjcat: upgrade 0.1.7 -> 0.1.8
unbound: upgrade 1.12.0 -> 1.13.2
xterm: upgrade 367 -> 368
zchunk: upgrade 1.1.9 -> 1.1.16
Change-Id: I5a866e7773b8c906bc2bd8a4ddf99f006534bf53
Signed-off-by: William A. Kennington III <wak@google.com>
Diffstat (limited to 'meta-openembedded/meta-networking/recipes-support/wireshark/wireshark_3.4.8.bb')
-rw-r--r-- | meta-openembedded/meta-networking/recipes-support/wireshark/wireshark_3.4.8.bb | 88 |
1 files changed, 88 insertions, 0 deletions
diff --git a/meta-openembedded/meta-networking/recipes-support/wireshark/wireshark_3.4.8.bb b/meta-openembedded/meta-networking/recipes-support/wireshark/wireshark_3.4.8.bb new file mode 100644 index 000000000..faf2a3ad1 --- /dev/null +++ b/meta-openembedded/meta-networking/recipes-support/wireshark/wireshark_3.4.8.bb @@ -0,0 +1,88 @@ +DESCRIPTION = "wireshark - a popular network protocol analyzer" +HOMEPAGE = "http://www.wireshark.org" +SECTION = "net" +LICENSE = "GPL-2.0" +LIC_FILES_CHKSUM = "file://COPYING;md5=6e271234ba1a13c6e512e76b94ac2f77" + +DEPENDS = "pcre expat glib-2.0 glib-2.0-native libgcrypt libgpg-error libxml2 bison-native c-ares" + +DEPENDS:append:class-target = " wireshark-native chrpath-replacement-native " + +SRC_URI = "https://1.eu.dl.wireshark.org/src/all-versions/wireshark-${PV}.tar.xz" + +SRC_URI += " \ + file://0001-wireshark-src-improve-reproducibility.patch \ + file://0002-flex-Remove-line-directives.patch \ + file://0003-bison-Remove-line-directives.patch \ + file://0004-lemon-Remove-line-directives.patch \ +" + +UPSTREAM_CHECK_URI = "https://1.as.dl.wireshark.org/src" + +SRC_URI[sha256sum] = "58a7fa8dfe2010a8c8b7dcf66438c653e6493d47eb936ba48ef49d4aa4dbd725" + +PE = "1" + +inherit cmake pkgconfig python3native perlnative upstream-version-is-even mime mime-xdg + +PACKAGECONFIG ?= "libpcap gnutls libnl libcap sbc" + +PACKAGECONFIG:class-native = "libpcap gnutls ssl libssh" + +PACKAGECONFIG[libcap] = "-DENABLE_CAP=ON,-DENABLE_CAP=OFF -DENABLE_PCAP_NG_DEFAULT=ON, libcap" +PACKAGECONFIG[libpcap] = "-DENABLE_PCAP=ON,-DENABLE_PCAP=OFF -DENABLE_PCAP_NG_DEFAULT=ON , libpcap" +PACKAGECONFIG[libsmi] = "-DENABLE_SMI=ON,-DENABLE_SMI=OFF,libsmi" +PACKAGECONFIG[libnl] = ",,libnl" +PACKAGECONFIG[portaudio] = "-DENABLE_PORTAUDIO=ON,-DENABLE_PORTAUDIO=OFF, portaudio-v19" +PACKAGECONFIG[gnutls] = "-DENABLE_GNUTLS=ON,-DENABLE_GNUTLS=OFF, gnutls" +PACKAGECONFIG[ssl] = ",,openssl" +PACKAGECONFIG[krb5] = "-DENABLE_KRB5=ON,-DENABLE_KRB5=OFF, krb5" +PACKAGECONFIG[lua] = "-DENABLE_LUA=ON,-DENABLE_LUA=OFF, lua" +PACKAGECONFIG[zlib] = "-DENABLE_ZLIB=ON,-DENABLE_ZLIB=OFF, zlib" +PACKAGECONFIG[geoip] = ",, geoip" +PACKAGECONFIG[plugins] = "-DENABLE_PLUGINS=ON,-DENABLE_PLUGINS=OFF" +PACKAGECONFIG[sbc] = "-DENABLE_SBC=ON,-DENABLE_SBC=OFF, sbc" +PACKAGECONFIG[libssh] = ",,libssh2" +PACKAGECONFIG[lz4] = "-DENABLE_LZ4=ON,-DENABLE_LZ4=OFF, lz4" +PACKAGECONFIG[zstd] = "-DENABLE_STTD=ON,-DENABLE_ZSTD=OFF, zstd" + +# these next two options require addional layers +PACKAGECONFIG[c-ares] = "-DENABLE_CARES=ON,-DENABLE_CARES=OFF, c-ares" +PACKAGECONFIG[qt5] = "-DENABLE_QT5=ON -DBUILD_wireshark=ON, -DENABLE_QT5=OFF -DBUILD_wireshark=OFF, qttools-native qtmultimedia qtsvg" + +inherit ${@bb.utils.contains('PACKAGECONFIG', 'qt5', 'cmake_qt5', '', d)} + +EXTRA_OECMAKE += "-DENABLE_NETLINK=ON \ + -DBUILD_mmdbresolve=OFF \ + -DBUILD_randpktdump=OFF \ + -DBUILD_androiddump=OFF \ + -DBUILD_dcerpcidl2wrs=OFF \ + -DM_INCLUDE_DIR=${includedir} \ + -DM_LIBRARY=${libdir} \ + " +CFLAGS:append = " -lm" + +do_install:append:class-native() { + install -d ${D}${bindir} + for f in lemon + do + install -m 0755 ${B}/run/$f ${D}${bindir} + done +} + +do_install:append:class-target() { + for f in `find ${D}${libdir} ${D}${bindir} -type f -executable` + do + chrpath --delete $f + done +} + +PACKAGE_BEFORE_PN += "tshark" + +FILES:tshark = "${bindir}/tshark ${mandir}/man1/tshark.*" + +FILES:${PN} += "${datadir}*" + +RDEPENDS:tshark = "wireshark" + +BBCLASSEXTEND = "native" |