meta-openembedded: subtree update:f623d8b574..936f2380bb

Alexander Vickberg (2):
      libwebsockets: upgrade to 4.1.6
      mbedtls: upgrade to 2.24.0

Bartosz Golaszewski (1):
      libgpiod: update v1.4.5 -> v1.6.2

Beniamin Sandu (1):
      trace-cmd: create recipe for version 2.9.1

Fabio Berton (2):
      beep: Add recipe for version 1.2.2
      linuxconsole: Add recipe for version 1.7.0

Gianfranco (1):
      dlt-daemon: add upstream patch to fix CVE-2020-29394

Kai Kang (1):
      colord: fix installed-vs-shipped error

Khem Raj (1):
      packagegroup-meta-python: Remove packages moved to core

Luca Boccassi (3):
      dbus-broker: rdepend on dbus-common
      dbus-brocker: upgrade 23 -> 24
      dbus-broker: upgrade 24 -> 25

Martin Jansa (1):
      nanopb: move to dynamic-layers

Michael Vetter (1):
      jasper: upgrade 2.0.22 -> 2.0.23

Philip Balister (1):
      spdlog: Fix recipe so other recipes can use spdlog with external fmt.

Robert Karszniewicz (1):
      firmwared: add recipe

Roland Hieber (5):
      pcsc-lite: provide pcsc-lite-lib-native explicitly for native build
      lockfile-progs: use DEBIAN_MIRROR in SRC_URI
      fbset: use DEBIAN_MIRROR in SRC_URI
      liboop: use upstream SRC_URI
      openct: use upstream SRC_URI

Senthil Selvaganesan (1):
      fcgiwrap: add recipe

Thomas Perrot (1):
      openocd: disable the support of ccache

Trevor Woerner (4):
      glmark2: update information
      glmark2: update to latest
      glmark2: add support for dispmanx
      glmark2: revert to previous behaviour

Vyacheslav Yurkov (1):
      python3-aiohttp: added missing RDEPENDs

Wang Mingyu (2):
      gensio: 2.1.4 -> 2.2.0
      ser2net: 4.2.0 -> 4.3.0

Zang Ruochen (7):
      dialog: upgrade 1.3-20200327 -> 1.3-20201126
      fmt: upgrade 7.1.2 -> 7.1.3
      hidapi: upgrade 0.10.0 -> 0.10.1
      opensc: upgrade 0.20.0 -> 0.20.1
      pugixml: upgrade 1.10 -> 1.11
      satyr: upgrade 0.31 -> 0.35
      nanopb: upgrade 0.4.3 -> 0.4.4

zhengruoqin (9):
      c-periphery: upgrade 2.2.4 -> 2.2.5
      crash: upgrade 7.2.8 -> 7.2.9
      dfu-util: upgrade 0.9 -> 0.10
      monit: upgrade 5.26.0 -> 5.27.1
      qpdf: upgrade 10.0.1 -> 10.0.4
      tcsh: upgrade 6.22.02 -> 6.22.03
      xserver-xorg-cvt-native: upgrade 1.20.5 -> 1.20.9
      zchunk: upgrade 1.1.6 -> 1.1.7
      libconfig-autoconf-perl: upgrade 0.318 -> 0.319

Signed-off-by: Andrew Geissler <geissonator@yahoo.com>
Change-Id: I8371eb789fa288193da895bd51ce2160194809d8

1 files changed, 53 insertions, 0 deletions

diff --git a/meta-openembedded/meta-oe/recipes-support/monit/monit_5.27.1.bb b/meta-openembedded/meta-oe/recipes-support/monit/monit_5.27.1.bb
new file mode 100644
index 000000000..0a1442fc7
--- /dev/null
+++ b/meta-openembedded/meta-oe/recipes-support/monit/monit_5.27.1.bb
@@ -0,0 +1,53 @@
+DESCRIPTION = "Monit is a free open source utility for managing and monitoring, \
+processes, programs, files, directories and filesystems on a UNIX system. \
+Monit conducts automatic maintenance and repair and can execute meaningful \
+causal actions in error situations."
+
+HOMEPAGE = "http://mmonit.com/monit/"
+
+LICENSE = "AGPL-3.0"
+LIC_FILES_CHKSUM = "file://COPYING;md5=ea116a7defaf0e93b3bb73b2a34a3f51 \
+                    file://libmonit/COPYING;md5=2405f1c59ed1bf3714cebdb40162ce92"
+
+SRC_URI = " \
+	https://mmonit.com/monit/dist/monit-${PV}.tar.gz \
+	file://monit \
+	file://monitrc \
+"
+
+SRC_URI[md5sum] = "200068f37847e3402f6a9b061c2d327e"
+SRC_URI[sha256sum] = "f57408d16185687513a3c4eb3f2bb72eef76331ac16210e9652e846e5c84ed51"
+
+DEPENDS = "zlib bison-native libnsl2 flex-native openssl virtual/crypt"
+
+inherit autotools-brokensep systemd update-rc.d
+
+PACKAGECONFIG ??= "${@bb.utils.filter('DISTRO_FEATURES', 'pam', d)}"
+PACKAGECONFIG[pam] = "--with-pam,--without-pam,libpam"
+
+EXTRA_OECONF = "\
+    libmonit_cv_setjmp_available=no \
+    libmonit_cv_vsnprintf_c99_conformant=no \
+    --with-ssl-lib-dir=${STAGING_LIBDIR} \
+    --with-ssl-incl-dir=${STAGING_INCDIR} \
+"
+
+SYSTEMD_SERVICE_${PN} = "monit.service"
+SYSTEMD_AUTO_ENABLE = "enable"
+
+INITSCRIPT_PACKAGES = "${PN}"
+INITSCRIPT_NAME_${PN} = "monit"
+INITSCRIPT_PARAMS_${PN} = "defaults 89"
+
+do_install_append() {
+
+    # Configuration file
+    install -Dm 0600 ${WORKDIR}/monitrc ${D}${sysconfdir}/monitrc
+
+    # SystemD
+    install -Dm 0644 ${S}/system/startup/monit.service.in ${D}${systemd_system_unitdir}/monit.service
+    sed -i -e 's,@prefix@,${exec_prefix},g' ${D}${systemd_unitdir}/system/monit.service
+
+    # SysV
+    install -Dm 0755 ${WORKDIR}/monit ${D}${sysconfdir}/init.d/monit
+}