meta-phosphor: sdbusplus: rename as git

Rename sdbusplus recipe as _git due to git source.

(From meta-phosphor rev: 66d1584e1701b8db8f0e39c5085b92f59a5102e9)

Change-Id: I6c596e2dd21b35ae90a5a86763d07dd366d85515
Signed-off-by: Patrick Venture <venture@google.com>
Signed-off-by: Brad Bishop <bradleyb@fuzziesquirrel.com>

1 files changed, 56 insertions, 0 deletions

diff --git a/meta-phosphor/recipes-extended/sdbusplus/sdbusplus_git.bb b/meta-phosphor/recipes-extended/sdbusplus/sdbusplus_git.bb
new file mode 100644
index 000000000..21c334a7f
--- /dev/null
+++ b/meta-phosphor/recipes-extended/sdbusplus/sdbusplus_git.bb
@@ -0,0 +1,56 @@
+SUMMARY = "C++ bindings for systemd dbus APIs"
+DESCRIPTION = "C++ bindings for systemd dbus APIs."
+HOMEPAGE = "http://github.com/openbmc/sdbusplus"
+PR = "r1"
+PV = "1.0+git${SRCPV}"
+LICENSE = "Apache-2.0"
+LIC_FILES_CHKSUM = "file://LICENSE;md5=e3fc50a88d0a364313df4b21ef20c29e"
+
+inherit autotools pkgconfig
+inherit obmc-phosphor-python-autotools
+
+DEPENDS += " \
+        autoconf-archive-native \
+        python-inflection-native \
+        python-mako-native \
+        python-pyyaml-native \
+        "
+RDEPENDS_sdbus++ += " \
+        python-inflection \
+        python-mako \
+        python-pyyaml \
+        "
+
+# sdbus++ has a handful of runtime dependencies on other python packages.
+# Bitbake doesn't do anything with RDEPENDS in native context because
+# native context doesn't have packages.
+#
+# While technically sdbus++ doesn't require its runtime dependencies to be
+# installed to build, work around the above native context behavior
+# by adding a build dependency so that clients don't have to DEPEND
+# on sdbus++ runtime dependencies manually.
+
+DEPENDS_append_class-native = " \
+        python-inflection-native \
+        python-mako-native \
+        python-pyyaml-native \
+        "
+
+SRC_URI += "git://github.com/openbmc/sdbusplus"
+SRCREV = "ad7e686b5563a146728aa9477f6e814dc0a3cbd4"
+
+PACKAGECONFIG ??= "libsdbusplus transaction"
+PACKAGECONFIG[libsdbusplus] = "--enable-libsdbusplus,--disable-libsdbusplus,systemd,libsystemd"
+PACKAGECONFIG[transaction] = "--enable-transaction,--disable-transaction"
+
+S = "${WORKDIR}/git"
+
+PROVIDES_prepend = "sdbus++ "
+PACKAGE_BEFORE_PN = "sdbus++"
+FILES_sdbus++_append = " ${bindir}/sdbus++"
+PYTHON_AUTOTOOLS_PACKAGE = "sdbus++"
+
+PACKAGECONFIG_remove_class-native = "libsdbusplus"
+PACKAGECONFIG_remove_class-nativesdk = "libsdbusplus"
+
+BBCLASSEXTEND += "native nativesdk"