meta-phosphor: mboxd: drop symlink

Drop symlink and rename bb for mboxd.

(From meta-phosphor rev: 281a99e15a4903a883b2a127701a30b0f337cbdb)

Change-Id: I7350cf0c28cdd1ff6a2807d9310c0e0293972e60
Signed-off-by: Patrick Venture <venture@google.com>
Signed-off-by: Brad Bishop <bradleyb@fuzziesquirrel.com>

1 files changed, 52 insertions, 1 deletions

diff --git a/meta-phosphor/recipes-phosphor/mboxd/mboxd_git.bb b/meta-phosphor/recipes-phosphor/mboxd/mboxd_git.bb
index 72426c069..e1583d7a7 120000..100644
--- a/meta-phosphor/recipes-phosphor/mboxd/mboxd_git.bb
+++ b/meta-phosphor/recipes-phosphor/mboxd/mboxd_git.bb
@@ -1 +1,52 @@
-mboxd.bb
\ No newline at end of file
+SUMMARY = "Phosphor OpenBMC MBOX Daemon"
+DESCRIPTION = "Phosphor OpenBMC MBOX Daemon"
+PR = "r1"
+PV = "1.0+git${SRCPV}"
+LICENSE = "Apache-2.0"
+LIC_FILES_CHKSUM = "file://LICENSE;md5=e3fc50a88d0a364313df4b21ef20c29e"
+
+inherit autotools pkgconfig
+inherit obmc-phosphor-systemd
+
+DEPENDS += "autoconf-archive-native"
+DEPENDS += "systemd"
+DEPENDS += "phosphor-logging"
+RDEPENDS_${PN} += "libsystemd"
+
+S = "${WORKDIR}/git"
+
+SRC_URI += "git://github.com/openbmc/mboxbridge.git"
+
+SRC_URI += "file://99-aspeed-mbox.rules"
+SRC_URI += "file://99-aspeed-lpc-ctrl.rules"
+SRC_URI += "file://aspeed-lpc-ctrl-h.patch"
+
+SRCREV="5f86227e1619f60dadc8a053d14b20338d0fbdac"
+
+PROVIDES += "mboxctl"
+
+MBOXD_FLASH_SIZE ??= "32M"
+SYSTEMD_SUBSTITUTIONS += "FLASH_SIZE:${MBOXD_FLASH_SIZE}:${PN}.service"
+
+# Hacks because ${STAGING_KERNEL_DIR} points to the kernel source tree, not the
+# installed, pre-processed headers. Requires the aspeed-lpc-ctrl-h patch above.
+CFLAGS_append = " -I include"
+
+do_install_append() {
+    install -d ${D}/lib/udev/rules.d
+    install -m 0644 ${WORKDIR}/99-aspeed-mbox.rules ${D}/lib/udev/rules.d
+    install -m 0644 ${WORKDIR}/99-aspeed-lpc-ctrl.rules ${D}/lib/udev/rules.d
+}
+
+TMPL = "mboxd-reload@.service"
+TGTFMT = "obmc-chassis-poweron@{0}.target"
+INSTFMT = "mboxd-reload@{0}.service"
+FMT = "../${TMPL}:${TGTFMT}.wants/${INSTFMT}"
+
+SYSTEMD_SERVICE_${PN} += "mboxd.service"
+SYSTEMD_SERVICE_${PN} += "mboxd-reload@.service"
+SYSTEMD_LINK_${PN} += "${@compose_list(d, 'FMT', 'OBMC_CHASSIS_INSTANCES')}"
+
+# Enable virtual-pnor by DISTRO_FEATURE openpower-ubi-fs.
+PACKAGECONFIG_append_df-openpower-ubi-fs = "virtual-pnor"
+PACKAGECONFIG[virtual-pnor] = "--enable-virtual-pnor,--disable-virtual-pnor"