meta-xilinx: subtree update:874b9cee5e..569f52f275

Jaewon Lee (1):
      xilinx-board.inc: Introducing inc file to add BOARD/BOARD_VARIANT

Madhurkiran Harikrishnan (2):
      weston.ini: Do not set hard requirement for input devices
      libmali-xlnx: Update the mali userspace libraries to 2020.2

Mark Hatle (2):
      libmali-xlnx: Fix the package arch
      Various: Packages using libGL may need to be declared SOC_VARIANT_ARCH

Raju Kumar Pothuraju (1):
      versal-generic.conf:zynqmp-generic.conf: Add MACHINE_ESSENTIAL_EXTRA_RDEPENDS variable only for specific machines.

Sai Hari Chandana Kalluri (7):
      Add meta-python2 in bblayers.conf
      xrt_git.bb: Replace deprecated boost macros
      perf: Fix compilation issues Fix perf variable definition and libtraceevent with binutils. The above errors are fixed by including the following patches to the kernel tree: 	0001-libtraceevent-Fix-build-with-binutils-2.35.patch         0001-perf-bench-Share-some-global-variables-to-fix-build-.patch         0001-perf-cs-etm-Move-definition-of-traceid_list-global-v.patch         0001-perf-tests-bp_account-Make-global-variable-static.patch
      opencv_3.4.3: Remove support for opencv 3.4
      Update commit id and branch for components for 2020.2 release
      update XILINX_VER_MAIN to 2020.2
      bootgen: Update commit id for 2020.2 release

Sandeep Gundlupet Raju (1):
      kernel-module-dp: Add support for Xilinx DP drivers

Vishal Sagar (1):
      kernel-module-hdmi: Update commit id and license md5sum for 2020.2

ch vamshi krishna (3):
      updating xrt commit id
      updating final XRT commit id for 2020.2
      updating XRT/Zocl commit id for 2020.2

rbramand (1):
      ] CR-1076958 Put libxrt libs softlinks in the main package

Signed-off-by: Andrew Geissler <geissonator@yahoo.com>
Change-Id: I4c6b12024c4d07388334e29177417e34fe6dea87

1 files changed, 69 insertions, 0 deletions

diff --git a/meta-xilinx/meta-xilinx-standalone/recipes-standalone/plm/plm_2020.2.bb b/meta-xilinx/meta-xilinx-standalone/recipes-standalone/plm/plm_2020.2.bb
new file mode 100644
index 000000000..c5a68ef17
--- /dev/null
+++ b/meta-xilinx/meta-xilinx-standalone/recipes-standalone/plm/plm_2020.2.bb
@@ -0,0 +1,69 @@
+inherit deploy
+
+LICENSE = "Proprietary"
+LIC_FILES_CHKSUM = "file://../../../../license.txt;md5=39ab6ab638f4d1836ba994ec6852de94"
+
+SRCREV = "e8db5fb118229fdc621e0ec7848641a23bf60998"
+PV = "${XILINX_RELEASE_VERSION}+git${SRCPV}"
+
+SRC_URI = "git://github.com/Xilinx/embeddedsw.git;protocol=https;nobranch=1"
+
+COMPATIBLE_HOST = "microblaze.*-elf"
+COMPATIBLE_MACHINE = "versal-mb"
+
+
+S = "${WORKDIR}/git/lib/sw_apps/versal_plm/src"
+
+# The makefile does not handle parallelization
+PARALLEL_MAKE = ""
+
+do_configure() {
+    # manually do the copy_bsp step first, so as to be able to fix up use of
+    # mb-* commands
+    ${S}/../misc/copy_bsp.sh
+}
+
+COMPILER = "${CC}"
+COMPILER_FLAGS = "-O2 -c"
+EXTRA_COMPILER_FLAGS = "-g -Wall -Wextra -Os -flto -ffat-lto-objects"
+ARCHIVER = "${AR}"
+
+BSP_DIR ?= "${S}/../misc/versal_plm_bsp"
+BSP_TARGETS_DIR ?= "${BSP_DIR}/psv_pmc_0/libsrc"
+
+def bsp_make_vars(d):
+    s = ["COMPILER", "CC", "COMPILER_FLAGS", "EXTRA_COMPILER_FLAGS", "ARCHIVER", "AR", "AS"]
+    return " ".join(["\"%s=%s\"" % (v, d.getVar(v)) for v in s])
+
+do_compile() {
+    # the Makefile in ${S}/../misc/Makefile, does not handle CC, AR, AS, etc
+    # properly. So do its job manually. Preparing the includes first, then libs.
+    for i in $(ls ${BSP_TARGETS_DIR}/*/src/Makefile); do
+        oe_runmake -C $(dirname $i) -s include ${@bsp_make_vars(d)}
+    done
+    for i in $(ls ${BSP_TARGETS_DIR}/*/src/Makefile); do
+        oe_runmake -C $(dirname $i) -s libs ${@bsp_make_vars(d)}
+    done
+
+    # --build-id=none is required due to linker script not defining a location for it.
+    # Again, recipe-systoot include is necessary
+    oe_runmake CC="${CC}" CC_FLAGS="-MMD -MP -Wl,--build-id=none -I${STAGING_DIR_TARGET}/usr/include"
+}
+
+do_install() {
+    :
+}
+
+PLM_BASE_NAME ?= "${BPN}-${PKGE}-${PKGV}-${PKGR}-${MACHINE}-${DATETIME}"
+PLM_BASE_NAME[vardepsexclude] = "DATETIME"
+
+do_deploy() {
+    install -Dm 0644 ${B}/plm.elf ${DEPLOYDIR}/${PLM_BASE_NAME}.elf
+    ln -sf ${PLM_BASE_NAME}.elf ${DEPLOYDIR}/${BPN}-${MACHINE}.elf
+    ${OBJCOPY} -O binary ${B}/plm.elf ${B}/plm.bin
+    install -m 0644 ${B}/plm.bin ${DEPLOYDIR}/${PLM_BASE_NAME}.bin
+    ln -sf ${PLM_BASE_NAME}.bin ${DEPLOYDIR}/${BPN}-${MACHINE}.bin
+}
+
+addtask deploy before do_build after do_install
+