poky: thud refresh 87e3a9739d..1cab405d88

Update poky to thud HEAD.

Adrian Bunk (1):
      archiver.bbclass: Fix COPYLEFT_LICENSE_{IN, EX}CLUDE

Adrian Freihofer (2):
      systemd: fix PN-container package splitting
      devtool: fix target-deploy --strip

Alejandro Enedino Hernandez Samaniego (1):
      python: Adds instructions to the manifest file

Alexander Kanavin (3):
      meson: do not manipulate the environment when looking for python via pkg-config
      openssl: update to 1.1.1a
      libc-package: fix postinst error when ENABLE_BINARY_LOCALE_GENERATION = "0"

Alexey Brodkin (1):
      gdb: Remove long ago upstreamed patch

André Draszik (1):
      linux-firmware: better packaging for TI wl12xx & wl18xx firmwares

Anuj Mittal (13):
      maintainers.inc: update Intel owners
      gst-plugins-bad: add PACKAGECONFIG for msdk
      gstreamer1.0: upgrade 1.14.3 -> 1.14.4
      gstreamer1.0-plugins-base: upgrade 1.14.3 -> 1.14.4
      gstreamer1.0-plugins-good: upgrade 1.14.3 -> 1.14.4
      gstreamer1.0-plugins-bad: upgrade 1.14.3 -> 1.14.4
      gstreamer1.0-plugins-ugly: upgrade 1.14.3 -> 1.14.4
      gstreamer1.0-libav: upgrade 1.14.3 -> 1.14.4
      gstreamer1.0-vaapi: upgrade 1.14.3 -> 1.14.4
      gstreamer1.0-rtsp-server: upgrade 1.14.3 -> 1.14.4
      gstreamer1.0-omx: upgrade 1.14.3 -> 1.14.4
      gstreamer1.0-python: upgrade 1.14.3 -> 1.14.4
      gst-validate: upgrade 1.14.2 -> 1.14.4

Armin Kuster (1):
      gnutls: update to 3.6.4

Bruce Ashfield (13):
      linux-yocto: remove obselete options from lxc config
      linux-yocto/4.14: configuration cleanups
      linux-yocto/4.18: -rt sync and config cleanups
      linux-yocto/tiny: switch default branch to standard/tiny/base
      linux-yocto/tiny: restore qemuarm support
      linux-yocto/4.18: bug fixes and configuration tweaks
      linux-yocto/4.18: update to v4.18.17
      linux-yocto/4.14: update to v4.14.79
      linux-yocto/4.18: integrate CVE fixes
      linux-yocto/4.18: update to v4.18.20
      linux-yocto/4.18: update to v4.18.21
      linux-yocto: configuration updates (virtio and tpm)
      linux-yocto: correct qemumips64el definition

Carlos Rafael Giani (10):
      gstreamer1.0: upgrade to version 1.14.3
      gstreamer1.0-plugin-base: upgrade to version 1.14.3
      gstreamer1.0-plugin-good: upgrade to version 1.14.3
      gstreamer1.0-plugin-bad: upgrade to version 1.14.3
      gstreamer1.0-plugin-ugly: upgrade to version 1.14.3
      gstreamer1.0-libav: upgrade to version 1.14.3
      gstreamer1.0-rtsp-server: upgrade to version 1.14.3
      gstreamer1.0-vaapi: upgrade to version 1.14.3
      gstreamer1.0-omx: upgrade to version 1.14.3
      gstreamer1.0-python: upgrade to version 1.14.3

Changhyeok Bae (2):
      iproute2: 4.18.0 -> 4.19.0
      ethtool: 4.17 -> 4.19

Christophe PRIOUZEAU (1):
      openssl: correct bad path on package preprocess

Douglas Royds (4):
      boost-context: Reproducibility: Set .file section for all *_elf_gas.S files
      reproducible: Refactor: Break out fixed_source_date_epoch() function
      reproducible: Don't look for youngest file when no source tarball
      ptest: Reproducibility: Take control of umask

Eric Chanudet (1):
      licence: Add license file CC-BY-SA-4.0

Hongxu Jia (6):
      elfutils: 0.174 -> 0.175
      gnupg: upgrade 2.2.9 -> 2.2.10
      gnupg: upgrade 2.2.10 -> 2.2.11
      libgcrypt: upgrade 1.8.3 -> 1.8.4
      ghostscript: 9.25 -> 9.26
      go 1.9/1.11: fix textrel qa warning for non mips arch

Joshua Watt (3):
      meta/icecc.bbclass: Move system blacklist to variables
      meta/icecc.bbclass: Update system blacklists
      classes/icecc.bbclass: Fix ccache disable

Kai Kang (1):
      multilib_script: fix packages split

Khem Raj (3):
      valgrind: Skip vgpreload_memcheck shared object from stripping
      populate_sdk_ext.bbclass: Include site.conf in parsing for contents for local.conf
      local.conf.sample: Update the sample config as per new migration manual

Ming Liu (1):
      image.bbclass: fix a wrong position blank

Mingli Yu (2):
      mdadm: improve the run-ptest
      nspr: improve reproducibility

Niko Mauno (1):
      opkg-utils: Fix update-alternatives link relocation

Otavio Salvador (1):
      linux-firmware: Bump revision to 1baa348

Paul Eggleton (1):
      socat: fix LICENSE

Peter Kjellerstedt (3):
      meson: Correct use of the _append operator
      bitbake: bitbake-diffsigs: Merge with bitbake-dumpsig
      bitbake: bitbake-diffsigs: Support recursive deps with signature files

Richard Purdie (9):
      meson: Disable rpath stripping at install time
      scripts/runqemu: Fix logic error causing failures with MACHINE from the environment
      meta-selftest/error: Cleanup large trailing whitespace
      bitbake: server/process: Make lockfile handling clearer
      bitbake: server/process: Show the last 60 log lines, not the last 10
      bitbake: server/process: Show last 60 lines of the log if the server didn't start
      poky.conf: Update the distros we test against on the autobuilder
      poky: Update version to 2.6.1
      build-appliance-image: Update to thud head revision

Robert Yang (5):
      classes: Remove tab indentations in python code
      recipes: Remove tab indentations in python code
      bugzilla.bbclass: Remove it since obsoleted
      sstate.bbclass: Only remove sstate file when task is existed
      bitbake: server/process: print a message when no logfile

Ross Burton (12):
      cpio: fix crash when appending to archives
      image_types: use cpio-native to build cpio images
      libtasn1: no need to inherit binconfig
      binconfig: only try to mangles files
      piglit: add missing waffle-bin dependency
      ruby: upgrade 2.5.1 -> 2.5.3
      insane: Clarify GNU_HASH warning
      patchreview: Various fixes/improvements
      python3: don't cripple target distutils
      python3: drop redundant patch
      bitbake: layerindex: don't use shell=True when cloning
      bitbake: fetch: don't use shell=True when listing ar files

Zheng Ruoqin (2):
      nss: Fix SHA_HTONL bug for arm 32be.
      createrepo-c: Fix setup of logging (log domains)

Change-Id: I025dd27f44e57af38abff110ebc331e371bc461b
Signed-off-by: Brad Bishop <bradleyb@fuzziesquirrel.com>

1 files changed, 203 insertions, 0 deletions

diff --git a/poky/meta/recipes-connectivity/openssl/openssl_1.1.1a.bb b/poky/meta/recipes-connectivity/openssl/openssl_1.1.1a.bb
new file mode 100644
index 000000000..be31e9f76
--- /dev/null
+++ b/poky/meta/recipes-connectivity/openssl/openssl_1.1.1a.bb
@@ -0,0 +1,203 @@
+SUMMARY = "Secure Socket Layer"
+DESCRIPTION = "Secure Socket Layer (SSL) binary and related cryptographic tools."
+HOMEPAGE = "http://www.openssl.org/"
+BUGTRACKER = "http://www.openssl.org/news/vulnerabilities.html"
+SECTION = "libs/network"
+
+# "openssl" here actually means both OpenSSL and SSLeay licenses apply
+# (see meta/files/common-licenses/OpenSSL to which "openssl" is SPDXLICENSEMAPped)
+LICENSE = "openssl"
+LIC_FILES_CHKSUM = "file://LICENSE;md5=d57d511030c9d66ef5f5966bee5a7eff"
+
+DEPENDS = "hostperl-runtime-native"
+
+SRC_URI = "http://www.openssl.org/source/openssl-${PV}.tar.gz \
+           file://run-ptest \
+           file://openssl-c_rehash.sh \
+           file://0001-skip-test_symbol_presence.patch \
+           file://0001-buildinfo-strip-sysroot-and-debug-prefix-map-from-co.patch \
+           "
+
+SRC_URI_append_class-nativesdk = " \
+           file://environment.d-openssl.sh \
+           "
+
+SRC_URI[md5sum] = "963deb2272d6be7d4c2458afd2517b73"
+SRC_URI[sha256sum] = "fc20130f8b7cbd2fb918b2f14e2f429e109c31ddd0fb38fc5d71d9ffed3f9f41"
+
+inherit lib_package multilib_header ptest
+
+B = "${WORKDIR}/build"
+do_configure[cleandirs] = "${B}"
+
+#| ./libcrypto.so: undefined reference to `getcontext'
+#| ./libcrypto.so: undefined reference to `setcontext'
+#| ./libcrypto.so: undefined reference to `makecontext'
+EXTRA_OECONF_append_libc-musl = " no-async"
+
+# This prevents openssl from using getrandom() which is not available on older glibc versions
+# (native versions can be built with newer glibc, but then relocated onto a system with older glibc)
+EXTRA_OECONF_class-native = "--with-rand-seed=devrandom"
+EXTRA_OECONF_class-nativesdk = "--with-rand-seed=devrandom"
+
+# Relying on hardcoded built-in paths causes openssl-native to not be relocateable from sstate.
+CFLAGS_append_class-native = " -DOPENSSLDIR=/not/builtin -DENGINESDIR=/not/builtin"
+CFLAGS_append_class-nativesdk = " -DOPENSSLDIR=/not/builtin -DENGINESDIR=/not/builtin"
+
+do_configure () {
+	os=${HOST_OS}
+	case $os in
+	linux-gnueabi |\
+	linux-gnuspe |\
+	linux-musleabi |\
+	linux-muslspe |\
+	linux-musl )
+		os=linux
+		;;
+	*)
+		;;
+	esac
+	target="$os-${HOST_ARCH}"
+	case $target in
+	linux-arm*)
+		target=linux-armv4
+		;;
+	linux-aarch64*)
+		target=linux-aarch64
+		;;
+	linux-i?86 | linux-viac3)
+		target=linux-x86
+		;;
+	linux-gnux32-x86_64 | linux-muslx32-x86_64 )
+		target=linux-x32
+		;;
+	linux-gnu64-x86_64)
+		target=linux-x86_64
+		;;
+	linux-mips | linux-mipsel)
+		# specifying TARGET_CC_ARCH prevents openssl from (incorrectly) adding target architecture flags
+		target="linux-mips32 ${TARGET_CC_ARCH}"
+		;;
+	linux-gnun32-mips*)
+		target=linux-mips64
+		;;
+	linux-*-mips64 | linux-mips64 | linux-*-mips64el | linux-mips64el)
+		target=linux64-mips64
+		;;
+	linux-microblaze* | linux-nios2* | linux-sh3 | linux-sh4 | linux-arc*)
+		target=linux-generic32
+		;;
+	linux-powerpc)
+		target=linux-ppc
+		;;
+	linux-powerpc64)
+		target=linux-ppc64
+		;;
+	linux-riscv32)
+		target=linux-generic32
+		;;
+	linux-riscv64)
+		target=linux-generic64
+		;;
+	linux-sparc | linux-supersparc)
+		target=linux-sparcv9
+		;;
+	esac
+
+	useprefix=${prefix}
+	if [ "x$useprefix" = "x" ]; then
+		useprefix=/
+	fi
+	# WARNING: do not set compiler/linker flags (-I/-D etc.) in EXTRA_OECONF, as they will fully replace the
+	# environment variables set by bitbake. Adjust the environment variables instead.
+	PERL5LIB="${S}/external/perl/Text-Template-1.46/lib/" \
+	perl ${S}/Configure ${EXTRA_OECONF} ${PACKAGECONFIG_CONFARGS} --prefix=$useprefix --openssldir=${libdir}/ssl-1.1 --libdir=${libdir} $target
+}
+
+do_install () {
+	oe_runmake DESTDIR="${D}" MANDIR="${mandir}" MANSUFFIX=ssl install
+
+	oe_multilib_header openssl/opensslconf.h
+
+	# Create SSL structure for packages such as ca-certificates which
+	# contain hard-coded paths to /etc/ssl. Debian does the same.
+	install -d ${D}${sysconfdir}/ssl
+	mv ${D}${libdir}/ssl-1.1/certs \
+	   ${D}${libdir}/ssl-1.1/private \
+	   ${D}${libdir}/ssl-1.1/openssl.cnf \
+	   ${D}${sysconfdir}/ssl/
+
+	# Although absolute symlinks would be OK for the target, they become
+	# invalid if native or nativesdk are relocated from sstate.
+	ln -sf ${@oe.path.relative('${libdir}/ssl-1.1', '${sysconfdir}/ssl/certs')} ${D}${libdir}/ssl-1.1/certs
+	ln -sf ${@oe.path.relative('${libdir}/ssl-1.1', '${sysconfdir}/ssl/private')} ${D}${libdir}/ssl-1.1/private
+	ln -sf ${@oe.path.relative('${libdir}/ssl-1.1', '${sysconfdir}/ssl/openssl.cnf')} ${D}${libdir}/ssl-1.1/openssl.cnf
+}
+
+do_install_append_class-native () {
+	create_wrapper ${D}${bindir}/openssl \
+	    OPENSSL_CONF=${libdir}/ssl-1.1/openssl.cnf \
+	    SSL_CERT_DIR=${libdir}/ssl-1.1/certs \
+	    SSL_CERT_FILE=${libdir}/ssl-1.1/cert.pem \
+	    OPENSSL_ENGINES=${libdir}/ssl-1.1/engines
+
+	# Install a custom version of c_rehash that can handle sysroots properly.
+	# This version is used for example when installing ca-certificates during
+	# image creation.
+	install -Dm 0755 ${WORKDIR}/openssl-c_rehash.sh ${D}${bindir}/c_rehash
+	sed -i -e 's,/etc/openssl,${sysconfdir}/ssl,g' ${D}${bindir}/c_rehash
+}
+
+do_install_append_class-nativesdk () {
+	mkdir -p ${D}${SDKPATHNATIVE}/environment-setup.d
+	install -m 644 ${WORKDIR}/environment.d-openssl.sh ${D}${SDKPATHNATIVE}/environment-setup.d/openssl.sh
+	sed 's|/usr/lib/ssl/|/usr/lib/ssl-1.1/|g' -i ${D}${SDKPATHNATIVE}/environment-setup.d/openssl.sh
+}
+
+do_install_ptest () {
+	# Prune the build tree
+	rm -f ${B}/fuzz/*.* ${B}/test/*.*
+
+	cp ${S}/Configure ${B}/configdata.pm ${D}${PTEST_PATH}
+	cp -r ${S}/external ${B}/test ${S}/test ${B}/fuzz ${S}/util ${B}/util ${D}${PTEST_PATH}
+
+	# For test_shlibload
+	ln -s ${libdir}/libcrypto.so.1.1 ${D}${PTEST_PATH}/libcrypto.so
+	ln -s ${libdir}/libssl.so.1.1 ${D}${PTEST_PATH}/libssl.so
+
+	install -d ${D}${PTEST_PATH}/apps
+	ln -s ${bindir}/openssl ${D}${PTEST_PATH}/apps
+	install -m644 ${S}/apps/*.pem ${S}/apps/*.srl ${S}/apps/openssl.cnf ${D}${PTEST_PATH}/apps
+	install -m755 ${B}/apps/CA.pl ${D}${PTEST_PATH}/apps
+
+	install -d ${D}${PTEST_PATH}/engines
+	install -m755 ${B}/engines/ossltest.so ${D}${PTEST_PATH}/engines
+}
+
+# Add the openssl.cnf file to the openssl-conf package. Make the libcrypto
+# package RRECOMMENDS on this package. This will enable the configuration
+# file to be installed for both the openssl-bin package and the libcrypto
+# package since the openssl-bin package depends on the libcrypto package.
+
+PACKAGES =+ "libcrypto libssl openssl-conf ${PN}-engines ${PN}-misc"
+
+FILES_libcrypto = "${libdir}/libcrypto${SOLIBS}"
+FILES_libssl = "${libdir}/libssl${SOLIBS}"
+FILES_openssl-conf = "${sysconfdir}/ssl/openssl.cnf"
+FILES_${PN}-engines = "${libdir}/engines-1.1"
+FILES_${PN}-misc = "${libdir}/ssl-1.1/misc"
+FILES_${PN} =+ "${libdir}/ssl-1.1/*"
+FILES_${PN}_append_class-nativesdk = " ${SDKPATHNATIVE}/environment-setup.d/openssl.sh"
+
+CONFFILES_openssl-conf = "${sysconfdir}/ssl/openssl.cnf"
+
+RRECOMMENDS_libcrypto += "openssl-conf"
+RDEPENDS_${PN}-bin = "perl"
+RDEPENDS_${PN}-misc = "perl"
+RDEPENDS_${PN}-ptest += "openssl-bin perl perl-modules bash python"
+
+RPROVIDES_openssl-conf = "openssl10-conf"
+RREPLACES_openssl-conf = "openssl10-conf"
+RCONFLICTS_openssl-conf = "openssl10-conf"
+
+BBCLASSEXTEND = "native nativesdk"