From 720e4b07b8bee6e7a46b9b1b0b57b13cf32ff12b Mon Sep 17 00:00:00 2001
From: Jie Yang <jjy@google.com>
Date: Fri, 23 Jul 2021 02:30:19 -0700
Subject: meta-phosphor: Add openbmc/smbios-mdr recipe

Signed-off-by: Jie Yang <jjy@google.com>
Change-Id: I856cf1519e033b9b68788f5236c3de727e72ab32
---
 .../recipes-phosphor/smbios/smbios-mdr_git.bb      | 39 ++++++++++++++++++++++
 1 file changed, 39 insertions(+)
 create mode 100644 meta-phosphor/recipes-phosphor/smbios/smbios-mdr_git.bb

diff --git a/meta-phosphor/recipes-phosphor/smbios/smbios-mdr_git.bb b/meta-phosphor/recipes-phosphor/smbios/smbios-mdr_git.bb
new file mode 100644
index 000000000..b4c15c069
--- /dev/null
+++ b/meta-phosphor/recipes-phosphor/smbios/smbios-mdr_git.bb
@@ -0,0 +1,39 @@
+HOMEPAGE = "http://github.com/openbmc/smbios-mdr"
+SUMMARY = "Extract CPU and Memory Inventory from SMSMBIOS Table and PECI"
+DESCRIPTION = "This package parses SMBIOS tables, reads Intel CPU PIROM and PECI and provides a dedicated IPMI blob to receive SMBIOS tables sent from LinuxBoot"
+
+PR = "r1"
+PV = "1.0+git${SRCPV}"
+
+LICENSE = "Apache-2.0"
+LIC_FILES_CHKSUM = "file://LICENSE;md5=e3fc50a88d0a364313df4b21ef20c29e"
+
+inherit cmake systemd
+inherit obmc-phosphor-ipmiprovider-symlink
+
+DEPENDS += " \
+    boost \
+    systemd \
+    sdbusplus \
+    phosphor-dbus-interfaces \
+    phosphor-logging \
+    "
+
+PACKAGECONFIG ?= "cpuinfo"
+PACKAGECONFIG[smbios-no-dimm] = "-DDIMM_DBUS=OFF,-DDIMM_DBUS=ON"
+PACKAGECONFIG[cpuinfo] = "-DCPU_INFO=ON,-DCPU_INFO=OFF,libpeci i2c-tools"
+PACKAGECONFIG[smbios-ipmi-blob] = "-DIPMI_BLOB=ON,-DIPMI_BLOB=OFF,phosphor-ipmi-blobs"
+
+EXTRA_OECMAKE = "-DYOCTO=ON"
+
+S = "${WORKDIR}/git"
+SRC_URI = "git://github.com/openbmc/smbios-mdr.git"
+SRCREV = "6e3e9c2598a7a14f31e2581a472686368f00e5b4"
+
+SYSTEMD_SERVICE:${PN} += "smbios-mdrv2.service"
+SYSTEMD_SERVICE:${PN} += "${@bb.utils.contains('PACKAGECONFIG', 'cpuinfo', 'xyz.openbmc_project.cpuinfo.service', '', d)}"
+
+FILES:${PN}:append = " ${libdir}/ipmid-providers/lib*${SOLIBS}"
+FILES:${PN}:append = " ${libdir}/blob-ipmid/lib*${SOLIBS}"
+FILES:${PN}-dev:append  = " ${libdir}/ipmid-providers/lib*${SOLIBSDEV}"
+BLOBIPMI_PROVIDER_LIBRARY += "${@bb.utils.contains('PACKAGECONFIG', 'smbios-ipmi-blob', 'libsmbiosstore.so', '', d)}"
-- 
cgit v1.2.3