From b598a9268e7a75c5e01ee7ff3543beee5d045762 Mon Sep 17 00:00:00 2001
From: Brad Bishop <bradleyb@fuzziesquirrel.com>
Date: Thu, 8 Feb 2018 15:23:05 -0500
Subject: u-boot: Move recipes to the Aspeed BSP layer

Move the u-boot recipes out of the Phosphor layer to the Aspeed layer.
When a SOC requires a specific u-boot tree, convention dictates the
BSP layer supporting the SOC includes recipes for that tree.

Tested: Built image and verified in witherspoon qemu
Change-Id: I4d5bade05566ae4cbcf5a2c637a1ed275c63ab36
Signed-off-by: Brad Bishop <bradleyb@fuzziesquirrel.com>
---
 .../common/recipes-bsp/u-boot/u-boot-common.inc    | 17 +++++++++++
 .../recipes-bsp/u-boot/u-boot-fw-utils_2016.07.bb  | 34 ++++++++++++++++++++++
 .../common/recipes-bsp/u-boot/u-boot_2016.07.bb    |  4 +++
 3 files changed, 55 insertions(+)
 create mode 100644 meta-openbmc-bsp/meta-aspeed/common/recipes-bsp/u-boot/u-boot-common.inc
 create mode 100644 meta-openbmc-bsp/meta-aspeed/common/recipes-bsp/u-boot/u-boot-fw-utils_2016.07.bb
 create mode 100644 meta-openbmc-bsp/meta-aspeed/common/recipes-bsp/u-boot/u-boot_2016.07.bb

(limited to 'meta-openbmc-bsp')

diff --git a/meta-openbmc-bsp/meta-aspeed/common/recipes-bsp/u-boot/u-boot-common.inc b/meta-openbmc-bsp/meta-aspeed/common/recipes-bsp/u-boot/u-boot-common.inc
new file mode 100644
index 000000000..8e278bdff
--- /dev/null
+++ b/meta-openbmc-bsp/meta-aspeed/common/recipes-bsp/u-boot/u-boot-common.inc
@@ -0,0 +1,17 @@
+HOMEPAGE = "https://github.com/openbmc/u-boot"
+SECTION = "bootloaders"
+
+LICENSE = "GPLv2+"
+LIC_FILES_CHKSUM = "file://Licenses/README;md5=a2c678cfd4a4d97135585cad908541c6"
+PE = "1"
+
+# We use the revision in order to avoid having to fetch it from the
+# repo during parse
+SRCREV = "7fb88a88d08c19b0e6f88c0a484ab001a4476a27"
+
+UBRANCH = "v2016.07-aspeed-openbmc"
+SRC_URI = "git://git@github.com/openbmc/u-boot.git;branch=${UBRANCH};protocol=https"
+
+S = "${WORKDIR}/git"
+
+PV = "v2016.07+git${SRCPV}"
diff --git a/meta-openbmc-bsp/meta-aspeed/common/recipes-bsp/u-boot/u-boot-fw-utils_2016.07.bb b/meta-openbmc-bsp/meta-aspeed/common/recipes-bsp/u-boot/u-boot-fw-utils_2016.07.bb
new file mode 100644
index 000000000..e5a90367f
--- /dev/null
+++ b/meta-openbmc-bsp/meta-aspeed/common/recipes-bsp/u-boot/u-boot-fw-utils_2016.07.bb
@@ -0,0 +1,34 @@
+SUMMARY = "U-Boot bootloader fw_printenv/setenv utilities"
+DEPENDS = "mtd-utils"
+
+require u-boot-common.inc
+
+INSANE_SKIP_${PN} = "already-stripped"
+EXTRA_OEMAKE_class-target = 'CROSS_COMPILE=${TARGET_PREFIX} CC="${CC} ${CFLAGS} ${LDFLAGS}" V=1'
+EXTRA_OEMAKE_class-cross = 'ARCH=${TARGET_ARCH} CC="${CC} ${CFLAGS} ${LDFLAGS}" V=1'
+
+inherit uboot-config
+
+do_compile () {
+	oe_runmake ${UBOOT_MACHINE}
+	oe_runmake env
+}
+
+do_install () {
+	install -d ${D}${base_sbindir}
+	install -d ${D}${sysconfdir}
+	install -m 755 ${S}/tools/env/fw_printenv ${D}${base_sbindir}/fw_printenv
+	install -m 755 ${S}/tools/env/fw_printenv ${D}${base_sbindir}/fw_setenv
+	install -m 0644 ${S}/tools/env/fw_env.config ${D}${sysconfdir}/fw_env.config
+}
+
+do_install_class-cross () {
+	install -d ${D}${bindir_cross}
+	install -m 755 ${S}/tools/env/fw_printenv ${D}${bindir_cross}/fw_printenv
+	install -m 755 ${S}/tools/env/fw_printenv ${D}${bindir_cross}/fw_setenv
+}
+
+SYSROOT_DIRS_append_class-cross = " ${bindir_cross}"
+
+PACKAGE_ARCH = "${MACHINE_ARCH}"
+BBCLASSEXTEND = "cross"
diff --git a/meta-openbmc-bsp/meta-aspeed/common/recipes-bsp/u-boot/u-boot_2016.07.bb b/meta-openbmc-bsp/meta-aspeed/common/recipes-bsp/u-boot/u-boot_2016.07.bb
new file mode 100644
index 000000000..0df7f2b0d
--- /dev/null
+++ b/meta-openbmc-bsp/meta-aspeed/common/recipes-bsp/u-boot/u-boot_2016.07.bb
@@ -0,0 +1,4 @@
+require recipes-bsp/u-boot/u-boot.inc
+require u-boot-common.inc
+
+DEPENDS += "dtc-native"
-- 
cgit v1.2.3