blob: 768ec91f9efd2f6139100208d148b105e8130d9a (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
|
SUMMARY = "Parser for OpenPOWER-format FRU VPD"
DESCRIPTION = "Parse OpenPOWER-format FRU VPD and update inventory"
PR = "r1"
PV = "1.0+git${SRCPV}"
inherit meson pkgconfig
inherit openpower-fru-vpd
inherit python3native
inherit obmc-phosphor-systemd
require ${BPN}.inc
SRC_URI += "file://70-op-vpd.rules"
DEPENDS += " \
virtual/openpower-fru-vpd-layout \
virtual/openpower-fru-inventory \
virtual/openpower-fru-properties \
sdbusplus \
phosphor-logging \
${PYTHON_PN}-mako-native \
${PYTHON_PN}-pyyaml-native \
autoconf-archive-native \
"
SYSTEMD_SERVICE:${PN} += "op-vpd-parser.service"
S = "${WORKDIR}/git"
PACKAGECONFIG ??= ""
PACKAGECONFIG[ibm-parser] = "-Dibm-parser=enabled, -Dibm-parser=disabled, libgpiod nlohmann-json cli11"
PACKAGECONFIG[vpd-manager] = "-Dvpd-manager=enabled, -Dvpd-manager=disabled"
EXTRA_OEMESON = " \
-Dtests=disabled \
-DFRU_YAML=${STAGING_DIR_NATIVE}${vpdlayout_datadir}/layout.yaml \
-DPROP_YAML=${STAGING_DIR_NATIVE}${properties_datadir}/out.yaml \
"
do_install:append() {
SRC=${STAGING_DATADIR_NATIVE}${inventory_datadir_name}
DEST=${D}${inventory_envdir}
install -d ${DEST}
install ${SRC}/inventory ${DEST}
install -d ${D}/${nonarch_base_libdir}/udev/rules.d/
install -m0644 ${WORKDIR}/70-op-vpd.rules ${D}/${nonarch_base_libdir}/udev/rules.d/
}
|
