meta-openembedded: subtree update:da393545a2..08c0280b7c

Andreas Müller (8):
      networkmanager-openvpn: Fix packageing
      mousepad: upgrade 0.5.3 -> 0.5.4
      xfce4-battery-plugin: upgrade 1.1.3 -> 1.1.4
      gigolo: upgrade 0.5.1 -> 0.5.2
      thunar: upgrade 4.16.4 -> 4.16.6
      poppler: upgrade 21.03.0 -> 21.04.0
      catfish: add python3-dbus to RDEPENDS
      fluidsynth: upgrade 2.1.7 -> 2.2.0

Andrew Geissler (1):
      nodejs: ppc64le machine support

Awais Belal (1):
      libnet-ssleay-perl: add rdep on perl-module-autoloader

Hermes Zhang (1):
      gpsd: backport d-bus message time patch from upstream

Hongxu Jia (1):
      debootstrap: 1.0.67 -> 1.0.123

Kamil Dziezyk (1):
      bats: upgrade 1.1.0 -> 1.3.0

Kartikey Rameshbhai Parmar (1):
      fluidsynth: update SRC_URI to remove non-existing 2.1.x branch

Khem Raj (12):
      mariadb: Fix build on newer 32bit architectures
      iwd: Upgade to 1.13
      libmanette: Add recipe
      pidgin-sipe: Fix build with glib-2.0 >= 2.68
      gjs: Fix build with gcc11
      poppler: Backport patches to fix build with glib-2.0 2.68+ and GCC11
      opencv: Upgrade to 5.4.2
      Revert "iwd: Upgade to 1.13"
      core-image-minimal-xfce: Use graphical.target as default
      tbb: Fix build with musl
      vnstat: Disable install parallism to fix a potential install race
      open-vm-tools: Fix build with gcc 11

Leon Anavi (57):
      python3-sqlalchemy: Upgrade 1.4.3 -> 1.4.4
      python3-bitarray: Upgrade 1.8.1 -> 1.8.2
      python3-httplib2: Upgrade 0.19.0 -> 0.19.1
      python3-parso: Upgrade 0.8.1 -> 0.8.2
      python3-matplotlib: Upgrade 3.3.4 -> 3.4.1
      python3-pyroute2: Upgrade 0.5.15 -> 0.5.16
      python3-h5py: Upgrade 3.1.0 -> 3.2.1
      python3-cheetah: Upgrade 3.2.6 -> 3.2.6.post1
      python3-google-api-python-client: Upgrade 2.0.2 -> 2.1.0
      python3-xlsxwriter: Upgrade 1.3.7 -> 1.3.8
      python3-pymisp: Upgrade 2.4.140 -> 2.4.141
      python3-tqdm: Upgrade 4.58.0 -> 4.59.0
      python3-contextlib2: Upgrade 0.6.0 -> 0.6.0.post1
      python3-typeguard: Upgrade 2.11.1 -> 2.12.0
      python3-decorator: Upgrade 4.4.2 -> 5.0.1
      python3-pillow: Upgrade 8.1.2 -> 8.2.0
      python3-aiohttp: Upgrade 3.7.4 -> 3.7.4.post0
      python3-networkx: Upgrade 2.5 -> 2.5.1
      python3-pysonos: Upgrade 0.0.40 -> 0.0.41
      python3-docutils: Upgrade 0.16 -> 0.17
      python3-bitarray: Upgrade 1.8.2 -> 1.9.0
      python3-regex: Upgrade 2021.3.17 -> 2021.4.4
      python3-sqlalchemy: Upgrade 1.4.4 -> 1.4.5
      python3-pychromecast: Upgrade 9.1.1 -> 9.1.2
      python3-decorator: Upgrade 5.0.1 -> 5.0.5
      python3-pymisp: Upgrade 2.4.141 -> 2.4.141.1
      python3-pyroute2: Upgrade 0.5.16 -> 0.5.17
      python3-transitions: Upgrade 0.8.7 -> 0.8.8
      python3-sqlalchemy: Upgrade 1.4.5 -> 1.4.6
      python3-bitarray: Upgrade 1.9.0 -> 1.9.1
      python3-pysonos: Upgrade 0.0.41 -> 0.0.42
      python3-django: Upgrade 3.1.7 -> 3.2
      python3-tqdm: Upgrade 4.59.0 -> 4.60.0
      python3-xmlschema: Upgrade 1.5.3 -> 1.6.0
      python3-ruamel-yaml: Upgrade 0.17.2 -> 0.17.4
      python3-croniter: Upgrade 1.0.10 -> 1.0.11
      python3-decorator: Upgrade 5.0.5 -> 5.0.6
      python3-grpcio-tools: Upgrade 1.36.1 -> 1.37.0
      python3-speedtest-cli: Upgrade 2.1.2 -> 2.1.3
      python3-python-vlc: Upgrade 3.0.11115 -> 3.0.12117
      python3-robotframework: Upgrade 4.0 -> 4.0.1
      python3-grpcio: Upgrade 1.36.1 -> 1.37.0
      python3-cerberus: Upgrade 1.3.2 -> 1.3.3
      python3-humanize: Upgrade 3.3.0 -> 3.4.0
      python3-monotonic: Upgrade 1.5 -> 1.6
      python3-sqlalchemy: Upgrade 1.4.6 -> 1.4.7
      python3-typed-ast: Upgrade 1.4.2 -> 1.4.3
      python3-backports-functools-lru-cache: Upgrade 1.6.3 -> 1.6.4
      python3-xmlschema: Upgrade 1.6.0 -> 1.6.1
      python3-pyroute2: Upgrade 0.5.17 -> 0.5.18
      python3-sympy: Upgrade 1.7.1 -> 1.8
      python3-pandas: Upgrade 1.2.3 -> 1.2.4
      python3-humanize: Upgrade 3.4.0 -> 3.4.1
      python3-decorator: Upgrade 5.0.6 -> 5.0.7
      python3-colorlog: Upgrade 4.8.0 -> 5.0.1
      python3-google-api-python-client: Upgrade 2.1.0 -> 2.2.0
      python3-croniter: Upgrade 1.0.11 -> 1.0.12

Martin Jansa (13):
      packagegroup-meta-oe: include glfw, icewm, geis only with x11 in DISTRO_FEATURES
      phonet-utils: remove
      packagegroup-meta-oe: use 4 spaces for identation
      telepathy-glib: respect GI_DATA_ENABLED when enabling vala-bindings
      uml-utilities: fix installed-vs-shipped with usrmerge
      libsmi: use /bin/sh instead of ${base_bindir}/sh to silence QA error with usrmerge
      libyui: switch to libyui-old repo which still has this SRCREV
      libyui(-ncurses): upgrade to 4.1.1, libyui repo was rewritten completely
      android-tools: use PN instead of BPN in RDEPENDS
      pidgin-sipe: fix g_memdup2 changes to be backwards compatible with glib-1.67
      pidgin: upgrade to 2.14.2
      opencv: fetch wechat_qrcode files used by dnn PACKAGECONFIG
      opencv: link sfm module with Glog

Mingli Yu (2):
      freeradius: Upgrade to 3.0.21
      hostapd: fix CVE-2021-0326 and CVE-2021-27803

Naveen Saini (2):
      tbb: upgrade 2020.3 -> 2021.2.0
      ocl-icd: upgrade 2.2.14 -> 2.3.0

Randy MacLeod (2):
      doxygen: Upgrade 1.8.20 -> 1.9.1
      open-vm-tools: upgrade 11.0.1 -> 11.2.5

Ross Burton (1):
      fwts: upgrade to 21.03.00

Stefan Ghinea (1):
      hostapd: fix CVE-2021-30004

Vinicius Aquino (1):
      networkmanager: upgrade 1.28.0 -> 1.30.2

Vinícius Ossanes Aquino (2):
      modemmanager: upgrade 1.14.10 -> 1.16.2
      libqmi: upgrade 1.26.6 -> 1.28.2

Yi Fan Yu (2):
      rsyslog: fix some of the ptests
      redis: upgrade 6.0.9 -> 6.2.1

hasan.men (2):
      librdkafka: Add initial recipe v1.6.1
      libcppkafka: Add initial recipe for cppkafka wrapper

persianpros (5):
      PEP8 double aggressive E701, E70 and E502
      PEP8 double aggressive E20 and E211
      PEP8 double aggressive E22, E224, E241, E242 and E27
      PEP8 double aggressive E301 ~ E306
      PEP8 double aggressive W291 ~ W293 and W391

wangmy (2):
      mariadb: upgrade 10.5.8 -> 10.5.9
      uftrace: Fix error on aarch64 when binutils update to 2.35.1

zangrc (14):
      gnome-autoar: upgrade 0.2.4 -> 0.3.1
      emacs: upgrade 27.1 -> 27.2
      fbgrab: upgrade 1.4 -> 1.5
      ostree: upgrade 2020.8 -> 2021.1
      zabbix: upgrade 5.2.5 -> 5.2.6
      libxaw: upgrade 1.0.13 -> 1.0.14
      mosquitto: upgrade 2.0.9 -> 2.0.10
      nbdkit: upgrade 1.25.4 -> 1.25.5
      stunnel: upgrade 5.58 -> 5.59
      usbredir: upgrade 0.8.0 -> 0.9.0
      hwdata: upgrade 0.345 -> 0.346
      live555: upgrade 20210322 -> 20210406
      rabbitmq-c: upgrade 0.10.0 -> 0.11.0
      xterm: upgrade 366 -> 367

zhengruoqin (7):
      fetchmail: upgrade 6.4.17 -> 6.4.18
      lldpd: upgrade 1.0.4 -> 1.0.8
      networkmanager-openvpn: upgrade 1.8.12 -> 1.8.14
      snort: upgrade 2.9.17 -> 2.9.17.1
      python3-absl: upgrade 0.10.0 -> 0.12.0
      python3-astroid: upgrade 2.5.2 -> 2.5.3
      python3-bitarray: upgrade 1.9.1 -> 1.9.2

Signed-off-by: Andrew Geissler <geissonator@yahoo.com>
Change-Id: I1f0f809aeda70e82140fec5e3310cbf89c760ad4

1 files changed, 181 insertions, 0 deletions

diff --git a/meta-openembedded/meta-networking/recipes-connectivity/networkmanager/networkmanager_1.30.2.bb b/meta-openembedded/meta-networking/recipes-connectivity/networkmanager/networkmanager_1.30.2.bb
new file mode 100644
index 0000000000..ec3bdd22bd
--- /dev/null
+++ b/meta-openembedded/meta-networking/recipes-connectivity/networkmanager/networkmanager_1.30.2.bb
@@ -0,0 +1,181 @@
+SUMMARY = "NetworkManager"
+HOMEPAGE = "https://wiki.gnome.org/Projects/NetworkManager"
+SECTION = "net/misc"
+
+LICENSE = "GPLv2+ & LGPLv2.1+"
+LIC_FILES_CHKSUM = "file://COPYING;md5=b234ee4d69f5fce4486a80fdaf4a4263 \
+                    file://COPYING.LGPL;md5=4fbd65380cdd255951079008b364516c \
+"
+
+DEPENDS = " \
+    intltool-native \
+    libxslt-native \
+    libnl \
+    udev \
+    util-linux \
+    libndp \
+    libnewt \
+    curl \
+"
+
+inherit gnomebase gettext update-rc.d systemd vala gobject-introspection gtk-doc update-alternatives upstream-version-is-even
+
+SRC_URI = " \
+    ${GNOME_MIRROR}/NetworkManager/${@gnome_verdir("${PV}")}/NetworkManager-${PV}.tar.xz \
+    file://${BPN}.initd \
+    file://0001-Fixed-configure.ac-Fix-pkgconfig-sysroot-locations.patch \
+    file://0002-Do-not-create-settings-settings-property-documentati.patch \
+    file://0003-install-firewalld-to-var-libdir-rather-than-hardcod-.patch \
+"
+SRC_URI_append_libc-musl = " \
+    file://musl/0001-Fix-build-with-musl-systemd-specific.patch \
+    file://musl/0002-Fix-build-with-musl-systemd-specific.patch \
+"
+SRC_URI[sha256sum] = "0c8e80e77877860e4a4e6ab4a0f7cdc1186e356b65b042a751897188b88944d2"
+
+S = "${WORKDIR}/NetworkManager-${PV}"
+
+EXTRA_OECONF = " \
+    --disable-ifcfg-rh \
+    --disable-more-warnings \
+    --with-iptables=${sbindir}/iptables \
+    --with-tests \
+    --with-nmtui=yes \
+    --with-udev-dir=${nonarch_base_libdir}/udev \
+    --with-dhclient=no \
+    --with-dhcpcd=no \
+    --with-dhcpcanon=no \
+    --with-netconfig=no \
+"
+
+# stolen from https://github.com/void-linux/void-packages/blob/master/srcpkgs/NetworkManager/template
+# avoids:
+# | ../NetworkManager-1.16.0/libnm-core/nm-json.c:106:50: error: 'RTLD_DEEPBIND' undeclared (first use in this function); did you mean 'RTLD_DEFAULT'?
+CFLAGS_append_libc-musl = " \
+    -DRTLD_DEEPBIND=0 \
+"
+
+do_compile_prepend() {
+    export GIR_EXTRA_LIBS_PATH="${B}/libnm/.libs:${B}/libnm-glib/.libs:${B}/libnm-util/.libs"
+}
+
+PACKAGECONFIG ??= "nss ifupdown dnsmasq nmcli \
+    ${@bb.utils.contains('DISTRO_FEATURES', 'systemd', 'systemd', bb.utils.contains('DISTRO_FEATURES', 'x11', 'consolekit', '', d), d)} \
+    ${@bb.utils.contains('DISTRO_FEATURES', 'bluetooth', 'bluez5', '', d)} \
+    ${@bb.utils.filter('DISTRO_FEATURES', 'wifi polkit', d)} \
+"
+
+inherit ${@bb.utils.contains('PACKAGECONFIG', 'nmcli', 'bash-completion', '', d)}
+
+PACKAGECONFIG[systemd] = " \
+    --with-systemdsystemunitdir=${systemd_unitdir}/system --with-session-tracking=systemd, \
+    --without-systemdsystemunitdir, \
+"
+PACKAGECONFIG[polkit] = "--enable-polkit,--disable-polkit,polkit"
+PACKAGECONFIG[bluez5] = "--enable-bluez5-dun,--disable-bluez5-dun,bluez5"
+# consolekit is not picked by shlibs, so add it to RDEPENDS too
+PACKAGECONFIG[consolekit] = "--with-session-tracking=consolekit,,consolekit,consolekit"
+PACKAGECONFIG[modemmanager] = "--with-modem-manager-1=yes,--with-modem-manager-1=no,modemmanager"
+PACKAGECONFIG[ppp] = "--enable-ppp,--disable-ppp,ppp,ppp"
+PACKAGECONFIG[dnsmasq] = "--with-dnsmasq=${bindir}/dnsmasq"
+PACKAGECONFIG[nss] = "--with-crypto=nss,,nss"
+PACKAGECONFIG[resolvconf] = "--with-resolvconf=${base_sbindir}/resolvconf,,,resolvconf"
+PACKAGECONFIG[gnutls] = "--with-crypto=gnutls,,gnutls"
+PACKAGECONFIG[wifi] = "--with-wext=yes --enable-wifi=yes,--with-wext=no --enable-wifi=no,,wpa-supplicant"
+PACKAGECONFIG[ifupdown] = "--enable-ifupdown,--disable-ifupdown"
+PACKAGECONFIG[qt4-x11-free] = "--enable-qt,--disable-qt,qt4-x11-free"
+PACKAGECONFIG[cloud-setup] = "--with-nm-cloud-setup=yes,--with-nm-cloud-setup=no"
+PACKAGECONFIG[nmcli] = "--with-nmcli=yes,--with-nmcli=no,readline"
+PACKAGECONFIG[ovs] = "--enable-ovs,--disable-ovs,jansson"
+
+PACKAGES =+ " \
+  ${PN}-nmcli ${PN}-nmcli-doc \
+  ${PN}-nmtui ${PN}-nmtui-doc \
+  ${PN}-adsl ${PN}-cloud-setup \
+"
+
+SYSTEMD_PACKAGES = "${PN} ${PN}-cloud-setup"
+
+FILES_${PN}-adsl = "${libdir}/NetworkManager/${PV}/libnm-device-plugin-adsl.so"
+
+FILES_${PN}-cloud-setup = " \
+    ${libexecdir}/nm-cloud-setup \
+    ${systemd_system_unitdir}/nm-cloud-setup.service \
+    ${systemd_system_unitdir}/nm-cloud-setup.timer \
+    ${libdir}/NetworkManager/dispatcher.d/90-nm-cloud-setup.sh \
+    ${libdir}/NetworkManager/dispatcher.d/no-wait.d/90-nm-cloud-setup.sh \
+"
+ALLOW_EMPTY_${PN}-cloud-setup = "1"
+SYSTEMD_SERVICE_${PN}-cloud-setup = "${@bb.utils.contains('PACKAGECONFIG', 'cloud-setup', 'nm-cloud-setup.service nm-cloud-setup.timer', '', d)}"
+
+FILES_${PN} += " \
+    ${libexecdir} \
+    ${libdir}/NetworkManager/${PV}/*.so \
+    ${libdir}/NetworkManager \
+    ${libdir}/firewalld/zones \
+    ${nonarch_libdir}/NetworkManager/conf.d \
+    ${nonarch_libdir}/NetworkManager/dispatcher.d \
+    ${nonarch_libdir}/NetworkManager/dispatcher.d/pre-down.d \
+    ${nonarch_libdir}/NetworkManager/dispatcher.d/pre-up.d \
+    ${nonarch_libdir}/NetworkManager/dispatcher.d/no-wait.d \
+    ${nonarch_libdir}/NetworkManager/VPN \
+    ${nonarch_libdir}/NetworkManager/system-connections \
+    ${datadir}/polkit-1 \
+    ${datadir}/dbus-1 \
+    ${nonarch_base_libdir}/udev/* \
+    ${systemd_system_unitdir} \
+    ${libdir}/pppd \
+"
+
+RRECOMMENDS_${PN} += "iptables \
+    ${@bb.utils.filter('PACKAGECONFIG', 'dnsmasq', d)} \
+"
+RCONFLICTS_${PN} = "connman"
+
+FILES_${PN}-dev += " \
+    ${datadir}/NetworkManager/gdb-cmd \
+    ${libdir}/pppd/*/*.la \
+    ${libdir}/NetworkManager/*.la \
+    ${libdir}/NetworkManager/${PV}/*.la \
+"
+
+FILES_${PN}-nmcli = " \
+    ${bindir}/nmcli \
+"
+
+FILES_${PN}-nmcli-doc = " \
+    ${mandir}/man1/nmcli* \
+"
+
+FILES_${PN}-nmtui = " \
+    ${bindir}/nmtui \
+    ${bindir}/nmtui-edit \
+    ${bindir}/nmtui-connect \
+    ${bindir}/nmtui-hostname \
+"
+
+FILES_${PN}-nmtui-doc = " \
+    ${mandir}/man1/nmtui* \
+"
+
+INITSCRIPT_NAME = "network-manager"
+SYSTEMD_SERVICE_${PN} = "${@bb.utils.contains('PACKAGECONFIG', 'systemd', 'NetworkManager.service NetworkManager-dispatcher.service', '', d)}"
+
+ALTERNATIVE_PRIORITY = "100"
+ALTERNATIVE_${PN} = "${@bb.utils.contains('DISTRO_FEATURES','systemd','resolv-conf','',d)}"
+ALTERNATIVE_TARGET[resolv-conf] = "${@bb.utils.contains('DISTRO_FEATURES','systemd','${sysconfdir}/resolv-conf.NetworkManager','',d)}"
+ALTERNATIVE_LINK_NAME[resolv-conf] = "${@bb.utils.contains('DISTRO_FEATURES','systemd','${sysconfdir}/resolv.conf','',d)}"
+
+do_install_append() {
+    install -Dm 0755 ${WORKDIR}/${BPN}.initd ${D}${sysconfdir}/init.d/network-manager
+
+    rm -rf ${D}/run ${D}${localstatedir}/run
+
+    if ${@bb.utils.contains('DISTRO_FEATURES','systemd','true','false',d)}; then
+        # For read-only filesystem, do not create links during bootup
+        ln -sf ../run/NetworkManager/resolv.conf ${D}${sysconfdir}/resolv-conf.NetworkManager
+
+        # systemd v210 and newer do not need this rule file
+        rm ${D}/${nonarch_base_libdir}/udev/rules.d/84-nm-drivers.rules
+    fi
+}