meta-openembedded: subtree update:08c0280b7c..4fe1065655

Alexander Kanavin (1):
      libmicrohttpd: remove the recipe

Andreas Müller (4):
      jack: upgrade 1.19.17 -> 1.19.18
      xfce4-settings: upgrade 4.16.0 -> 4.16.1
      zsh: reduce priority slightly to avoid conflict with bash
      mutter/wayland: replace xserver-xorg-xwayland by xwayland in rdep

Andrej Kozemcak (1):
      proftpd: Update to 1.3.7a release

Armin Kuster (3):
      wireguard: update to v1.0.20210219 +1
      nostromo: remove recipe
      packagegroup-meta-webserver: remove nostromo from pkg grp

Chen Qi (3):
      tigervnc: upgrade to 1.11.0
      python3-django: upgrade to 2.2.20
      tigervnc: fix do_package error when enabling user merge

Gianfranco (1):
      vboxguestdrivers: upgrade 6.1.18 -> 6.1.20

Hongxu Jia (1):
      debootstrap: explicitly add virtual/fakeroot-native to depends

Joe Hershberger (1):
      strongswan: Make PACKAGECONFIG a default value

Justin Standring (1):
      tslib: add PACKAGECONFIG for evthres, one-wire-ts-input

Kai Kang (1):
      freeradius: check existence of openssl's commands in bootstrap

Khem Raj (36):
      nss: Re-enable -Werror
      gimp: Disable vector icon generation on mips/glibc too
      iwd: Upgade to 1.13
      python3-icu: Upgrade to 2.7.2
      nodejs: Update to 14.16.1
      nodejs: Fix build with icu-69
      nodejs: Use qemu usermode to run target binaries during build
      nodejs: Fix build on mips
      nodejs: Fix build with clang for x86 target
      tbb: Re-introduce PE
      bearssl: Update to tip of master
      gimp: Disable vector icons on musl/x86
      gd: Replace deprecated types from tiff
      nodejs: Enable snapshot
      python3-docutils: Delete
      libchamplain: Require opengl distro feature
      aom: Match the name for AOM-Patent-License-1.0
      libdevmapper,lvm2: Do not inherit license
      gnome-disk-utility: Require polkit in distro features
      README: Make git send-email example work
      sysprof: Enable sysprofd/libsysprof only when polkit in DISTRO_FEATURES
      packagegroup-gnome-apps: Add gnome-disk-utility only if polkit is in DISTRO_FEATURES
      python3-jinja2_2.%.bbappend: Delete
      python3-pyyaml: Do not check for meta-python
      python3-pyyaml: Delete
      python3-markupsafe: Delete bbappend
      snort,proftpd,net-snmp: Deal with -ffile-prefix-map as well
      apache2: Deal with -ffile-prefix-map
      vk-gl-cts: Fix build with GCC 11
      gegl: Update to 0.4.30
      python3-m2crypto: Upgrade to 0.37.1
      libupnp: Upgrade to 1.14.6
      ctags: Switch to universal ctags
      dibbler: Add libpthread to linker flags
      libowfat: Replace __pure__ with pure and remove using __deprecated__
      emacs: Do not use SIGSTKSZ

Leon Anavi (21):
      python3-bitarray: Upgrade 1.9.2 -> 2.0.0
      python3-xxhash: Upgrade 2.0.0 -> 2.0.2
      python3-xlsxwriter: Upgrade 1.3.8 -> 1.3.9
      python3-docutils: Upgrade 0.17 -> 0.17.1
      python3-portion: Upgrade 2.1.5 -> 2.1.6
      python3-huey: Upgrade 2.3.1 -> 2.3.2
      python3-pysonos: Upgrade 0.0.42 -> 0.0.43
      python3-asttokens: Upgrade 2.0.4 -> 2.0.5
      python3-hyperframe: Upgrade 6.0.0 -> 6.0.1
      python3-argcomplete: Upgrade 1.12.2 -> 1.12.3
      python3-python-vlc: Upgrade 3.0.12117 -> 3.0.12118
      python3-bitarray: Upgrade 2.0.0 -> 2.0.1
      python3-sqlalchemy: Upgrade 1.4.7 -> 1.4.11
      python3-watchdog: Upgrade 2.0.2 -> 2.0.3
      python3-pytest-asyncio: Upgrade 0.14.0 -> 0.15.1
      python3-xlsxwriter: Upgrade 1.3.9 -> 1.4.0
      python3-astroid: Upgrade 2.5.3 -> 2.5.6
      python3-arpeggio: Upgrade 1.10.1 -> 1.10.2
      python3-cachetools: Upgrade 4.2.1 -> 4.2.2
      python3-pymisp: Upgrade 2.4.141.1 -> 2.4.142
      python3-et-xmlfile: Upgrade 1.0.1 -> 1.1.0

Mingli Yu (4):
      python3-cryptography: Upgrade to 3.3.2
      onig: add oniguruma to PROVIDES
      php: Upgrade to 7.4.16
      tk: adapt to potential pseudo changes

Persian Prince (1):
      libdvdnav 6.1.1

Peter Kjellerstedt (1):
      syslog-ng: Merge .bb and .inc

Ramon Fried (1):
      bitwise: Upgrade 0.41 -> 0.42

Reto Schneider (1):
      nng: Upgrade 1.2.5 -> 1.4.0

Saul Wold (2):
      tbb: Disable PPC as COMPATIBLE_MACHINE
      packagegroup-meta-oe: conditional remove tbb for powerpc

Silcet (2):
      ufw: fix python shebang
      ufw: bump version to 0.36 and add services

Sinan Kaya (1):
      zram: add support for mem_limit

Stefan Ghinea (1):
      python3-django: fix CVE-2021-28658

Ulrich Ölmann (1):
      v4l-utils: fix reproducibility

Yi Fan Yu (3):
      syslog-ng: upgrade 3.24.1 -> 3.31.2
      syslog-ng: remove CONFIG_TLS override for arm DEBUG_BUILD
      syslog-ng: Drop an obsolete patch to add --enable-libnet

Yi Zhao (1):
      gvfs: rdepend on gsettings-desktop-schemas

zangrc (19):
      fuse3: upgrade 3.10.2 -> 3.10.3
      cifs-utils: upgrade 6.12 -> 6.13
      dnsmasq: upgrade 2.84 -> 2.85
      nbdkit: upgrade 1.25.5 -> 1.25.6
      wolfssl: upgrade 4.7.0 -> 4.7.1
      networkmanager: upgrade 1.30.2 -> 1.30.4
      libdvdread: upgrade 6.1.1 -> 6.1.2
      libwebsockets: upgrade 4.1.6 -> 4.2.0
      ostree: upgrade 2021.1 -> 2021.2
      redis: upgrade 6.2.1 -> 6.2.2
      tinyproxy: upgrade 1.10.0 -> 1.11.0
      nss: upgrade 3.63 -> 3.64
      babeld: upgrade 1.9.2 -> 1.10
      fetchmail: upgrade 6.4.18 -> 6.4.19
      openvpn: upgrade 2.5.1 -> 2.5.2
      wireshark: upgrade 3.4.4 -> 3.4.5
      debootstrap: upgrade 1.0.123 -> 1.0.124
      mailcap: upgrade 2.1.52 -> 2.1.53
      rsyslog: upgrade 8.2102.0 -> 8.2104.0

zhengruoqin (7):
      irssi: upgrade 1.2.2 -> 1.2.3
      librsync: upgrade 2.3.1 -> 2.3.2
      hiawatha: upgrade 10.11 -> 10.12
      python3-supervisor: upgrade 4.2.1 -> 4.2.2
      python3-zopeinterface: upgrade 5.3.0 -> 5.4.0
      sdparm: upgrade 1.11 -> 1.12
      tcsh: upgrade 6.22.03 -> 6.22.04

Signed-off-by: Andrew Geissler <geissonator@yahoo.com>
Change-Id: Iaeb2fe4ee0a49cf44ea60bc3c1aef83528d92f55

1 files changed, 205 insertions, 0 deletions

diff --git a/meta-openembedded/meta-oe/recipes-extended/rsyslog/rsyslog_8.2104.0.bb b/meta-openembedded/meta-oe/recipes-extended/rsyslog/rsyslog_8.2104.0.bb
new file mode 100644
index 0000000000..3f1ec91ab0
--- /dev/null
+++ b/meta-openembedded/meta-oe/recipes-extended/rsyslog/rsyslog_8.2104.0.bb
@@ -0,0 +1,205 @@
+SUMMARY = "Rsyslog is an enhanced multi-threaded syslogd"
+DESCRIPTION = "\
+Rsyslog is an enhanced syslogd supporting, among others, MySQL,\
+ PostgreSQL, failover log destinations, syslog/tcp, fine grain\
+ output format control, high precision timestamps, queued operations\
+ and the ability to filter on any message part. It is quite\
+ compatible to stock sysklogd and can be used as a drop-in replacement.\
+ Its advanced features make it suitable for enterprise-class,\
+ encryption protected syslog relay chains while at the same time being\
+ very easy to setup for the novice user."
+
+DEPENDS = "zlib libestr libfastjson bison-native flex-native liblogging"
+HOMEPAGE = "http://www.rsyslog.com/"
+LICENSE = "GPLv3 & LGPLv3 & Apache-2.0"
+LIC_FILES_CHKSUM = "file://COPYING;md5=51d9635e646fb75e1b74c074f788e973 \
+                    file://COPYING.LESSER;md5=cb7903f1e5c39ae838209e130dca270a \
+                    file://COPYING.ASL20;md5=052f8a09206615ab07326ff8ce2d9d32\
+"
+
+SRC_URI = "http://www.rsyslog.com/download/files/download/rsyslog/${BPN}-${PV}.tar.gz \
+           file://initscript \
+           file://rsyslog.conf \
+           file://rsyslog.logrotate \
+           file://rsyslog.service \
+           file://use-pkgconfig-to-check-libgcrypt.patch \
+           file://run-ptest \
+           file://0001-tests-disable-the-check-for-inotify.patch \
+"
+
+SRC_URI_append_libc-musl = " \
+    file://0001-Include-sys-time-h.patch \
+"
+
+SRC_URI[md5sum] = "a0213c989bce297944901e1a85286b8b"
+SRC_URI[sha256sum] = "710981c3c34f88d5d1fb55ecfc042aecad8af69414b2b1602b304f4dedbf9f43"
+
+UPSTREAM_CHECK_URI = "https://github.com/rsyslog/rsyslog/releases"
+UPSTREAM_CHECK_REGEX = "(?P<pver>\d+(\.\d+)+)"
+
+inherit autotools pkgconfig systemd update-rc.d ptest
+
+EXTRA_OECONF += "--disable-generate-man-pages ap_cv_atomic_builtins=yes"
+EXTRA_OECONF += "--enable-imfile-tests"
+EXTRA_OECONF_remove_mipsarch = "ap_cv_atomic_builtins=yes"
+EXTRA_OECONF_remove_powerpc = "ap_cv_atomic_builtins=yes"
+EXTRA_OECONF_remove_riscv32 = "ap_cv_atomic_builtins=yes"
+
+# first line is default yes in configure
+PACKAGECONFIG ??= " \
+    rsyslogd rsyslogrt klog inet regexp uuid libgcrypt \
+    fmhttp imdiag gnutls imfile \
+    ${@bb.utils.filter('DISTRO_FEATURES', 'snmp systemd', d)} \
+    ${@bb.utils.contains('DISTRO_FEATURES', 'ptest', 'testbench relp ${VALGRIND}', '', d)} \
+"
+
+# default yes in configure
+PACKAGECONFIG[relp] = "--enable-relp,--disable-relp,librelp,"
+PACKAGECONFIG[rsyslogd] = "--enable-rsyslogd,--disable-rsyslogd,,"
+PACKAGECONFIG[rsyslogrt] = "--enable-rsyslogrt,--disable-rsyslogrt,,"
+PACKAGECONFIG[fmhttp] = "--enable-fmhttp,--disable-fmhttp,curl,"
+PACKAGECONFIG[inet] = "--enable-inet,--disable-inet,,"
+PACKAGECONFIG[klog] = "--enable-klog,--disable-klog,,"
+PACKAGECONFIG[regexp] = "--enable-regexp,--disable-regexp,,"
+PACKAGECONFIG[uuid] = "--enable-uuid,--disable-uuid,util-linux,"
+PACKAGECONFIG[libgcrypt] = "--enable-libgcrypt,--disable-libgcrypt,libgcrypt,"
+PACKAGECONFIG[testbench] = "--enable-testbench --enable-omstdout,--disable-testbench --disable-omstdout,,"
+
+# default no in configure
+PACKAGECONFIG[debug] = "--enable-debug,--disable-debug,,"
+PACKAGECONFIG[imdiag] = "--enable-imdiag,--disable-imdiag,,"
+PACKAGECONFIG[imfile] = "--enable-imfile,--disable-imfile,,"
+PACKAGECONFIG[snmp] = "--enable-snmp,--disable-snmp,net-snmp,"
+PACKAGECONFIG[gnutls] = "--enable-gnutls,--disable-gnutls,gnutls,"
+PACKAGECONFIG[systemd] = "--with-systemdsystemunitdir=${systemd_unitdir}/system/,--without-systemdsystemunitdir,systemd,"
+PACKAGECONFIG[imjournal] = "--enable-imjournal,--disable-imjournal,"
+PACKAGECONFIG[mmjsonparse] = "--enable-mmjsonparse,--disable-mmjsonparse,"
+PACKAGECONFIG[mysql] = "--enable-mysql,--disable-mysql,mysql5,"
+PACKAGECONFIG[postgresql] = "--enable-pgsql,--disable-pgsql,postgresql,"
+PACKAGECONFIG[libdbi] = "--enable-libdbi,--disable-libdbi,libdbi,"
+PACKAGECONFIG[mail] = "--enable-mail,--disable-mail,,"
+PACKAGECONFIG[valgrind] = ",--without-valgrind-testbench,valgrind,"
+PACKAGECONFIG[imhttp] = "--enable-imhttp,--disable-imhttp,civetweb,"
+
+
+TESTDIR = "tests"
+do_compile_ptest() {
+    echo 'buildtest-TESTS: $(check_PROGRAMS)' >> ${TESTDIR}/Makefile
+    oe_runmake -C ${TESTDIR} buildtest-TESTS
+}
+
+do_install_ptest() {
+    # install the tests
+    cp -rf ${S}/${TESTDIR} ${D}${PTEST_PATH}
+    cp -rf ${B}/${TESTDIR} ${D}${PTEST_PATH}
+
+    # give permissions to all users
+    # some tests need to write to this directory as user 'daemon'
+    chmod 777 -R ${D}${PTEST_PATH}/tests
+
+    # do NOT need to rebuild Makefile itself
+    sed -i 's/^Makefile:.*$/Makefile:/' ${D}${PTEST_PATH}/${TESTDIR}/Makefile
+    # do NOT need to rebuild $(check_PROGRAMS)
+    sed -i 's/^check-TESTS:.*$/check-TESTS:/' ${D}${PTEST_PATH}/${TESTDIR}/Makefile
+
+    # fix the srcdir, top_srcdir
+    sed -i 's,^\(srcdir = \).*,\1${PTEST_PATH}/tests,' ${D}${PTEST_PATH}/${TESTDIR}/Makefile
+    sed -i 's,^\(top_srcdir = \).*,\1${PTEST_PATH}/tests,' ${D}${PTEST_PATH}/${TESTDIR}/Makefile
+    # fix the abs_top_builddir
+    sed -i 's,^\(abs_top_builddir = \).*,\1${PTEST_PATH}/,' ${D}${PTEST_PATH}/${TESTDIR}/Makefile
+
+    # install test-driver
+    install -m 644 ${S}/test-driver ${D}${PTEST_PATH}
+
+    # install necessary links
+    install -d ${D}${PTEST_PATH}/tools
+    ln -sf ${sbindir}/rsyslogd ${D}${PTEST_PATH}/tools/rsyslogd
+
+    install -d ${D}${PTEST_PATH}/runtime
+    install -d ${D}${PTEST_PATH}/runtime/.libs
+    (
+        cd ${D}/${libdir}/rsyslog
+        allso="*.so"
+        for i in $allso; do
+            ln -sf ${libdir}/rsyslog/$i ${D}${PTEST_PATH}/runtime/.libs/$i
+        done
+    )
+
+    # fix the module load path with runtime/.libs
+    find ${D}${PTEST_PATH}/${TESTDIR} -name "*.conf" -o -name "*.sh" -o -name "*.c" | xargs \
+        sed -i -e 's:../plugins/.*/.libs/:../runtime/.libs/:g'
+    # fix the python3 path for tests/set-envar
+    sed -i -e s:${HOSTTOOLS_DIR}:${bindir}:g ${D}${PTEST_PATH}/tests/set-envvars
+}
+
+do_install_append() {
+    install -d "${D}${sysconfdir}/init.d"
+    install -d "${D}${sysconfdir}/logrotate.d"
+    install -m 755 ${WORKDIR}/initscript ${D}${sysconfdir}/init.d/syslog
+    install -m 644 ${WORKDIR}/rsyslog.conf ${D}${sysconfdir}/rsyslog.conf
+    install -m 644 ${WORKDIR}/rsyslog.logrotate ${D}${sysconfdir}/logrotate.d/logrotate.rsyslog
+    sed -i -e "s#@BINDIR@#${bindir}#g" ${D}${sysconfdir}/logrotate.d/logrotate.rsyslog
+
+    if ${@bb.utils.contains('PACKAGECONFIG', 'imjournal', 'true', 'false', d)}; then
+        install -d 0755 ${D}${sysconfdir}/rsyslog.d
+        echo '$ModLoad imjournal' >> ${D}${sysconfdir}/rsyslog.d/imjournal.conf
+    fi
+    if ${@bb.utils.contains('PACKAGECONFIG', 'mmjsonparse', 'true', 'false', d)}; then
+        install -d 0755 ${D}${sysconfdir}/rsyslog.d
+        echo '$ModLoad mmjsonparse' >> ${D}${sysconfdir}/rsyslog.d/mmjsonparse.conf
+    fi
+    if ${@bb.utils.contains('DISTRO_FEATURES','systemd','true','false',d)}; then
+        install -d ${D}${systemd_system_unitdir}
+        install -m 644 ${WORKDIR}/rsyslog.service ${D}${systemd_system_unitdir}
+        sed -i -e "s,@sbindir@,${sbindir},g" ${D}${systemd_system_unitdir}/rsyslog.service
+    fi
+}
+
+FILES_${PN} += "${bindir}"
+
+INITSCRIPT_NAME = "syslog"
+INITSCRIPT_PARAMS = "defaults"
+
+CONFFILES_${PN} = "${sysconfdir}/rsyslog.conf"
+
+RCONFLICTS_${PN} = "busybox-syslog sysklogd syslog-ng"
+
+RPROVIDES_${PN} += "${PN}-systemd"
+RREPLACES_${PN} += "${PN}-systemd"
+RCONFLICTS_${PN} += "${PN}-systemd"
+SYSTEMD_SERVICE_${PN} = "${BPN}.service"
+
+RDEPENDS_${PN} += "logrotate"
+
+# for rsyslog-ptest
+VALGRIND = "valgrind"
+
+# valgrind supports armv7 and above
+VALGRIND_armv4 = ''
+VALGRIND_armv5 = ''
+VALGRIND_armv6 = ''
+
+# X32 isn't supported by valgrind at this time
+VALGRIND_linux-gnux32 = ''
+VALGRIND_linux-muslx32 = ''
+
+# Disable for some MIPS variants
+VALGRIND_mipsarchr6 = ''
+VALGRIND_linux-gnun32 = ''
+
+# Disable for powerpc64 with musl
+VALGRIND_libc-musl_powerpc64 = ''
+VALGRIND_libc-musl_powerpc64le = ''
+
+# RISC-V support for valgrind is not there yet
+VALGRIND_riscv64 = ""
+VALGRIND_riscv32 = ""
+
+# util-linux: logger needs the -d option
+RDEPENDS_${PN}-ptest += "\
+  make diffutils gzip bash gawk coreutils procps \
+  libgcc python3-core python3-io python3-json \
+  curl util-linux shadow \
+  "
+
+RRECOMMENDS_${PN}-ptest += "${TCLIBC}-dbg ${VALGRIND}"