meta-openembedded: subtree update:679bb49126..7c02c7d411

Adam Miartus (1):
      toybox: allow user to provide own defconfig

Adrian Bunk (5):
      uftrace: Fix PR
      mraa: Replace -fcommon with fix
      mozjs: Remove workaround for gcc < 4.9
      flatbuffers: Remove workarounds for gcc < 6
      protobuf-c: Remove workarounds for gcc < 6

Alejandro Enedino Hernandez Samaniego (2):
      weechat: introduce weechat recipe providing a fully working IRC client
      imapfilter: introduce imapfilter recipe providing a mailbox filter through the IMAP protocol

Alejandro Hernandez Samaniego (1):
      remmina: Upgrade to version 1.4.3

Alexander Vickberg (2):
      tcpdump: Fix PACKAGECONFIG for OpenSSL
      iperf3: Add OpenSSL build option to PACKAGECONFIG

Alistair Francis (2):
      geany-plugins: Support libgit2 version 1.0
      libgit2: Update to v1.0.0

Andreas Müller (5):
      xfce4-notifyd: upgrade 0.6.0 -> 0.6.1
      xfconf: upgrade 4.14.1 -> 4.14.2
      xfwm4: upgrade 4.14.1 -> 4.14.2
      qpdf: upgrade 9.1.0 -> 10.0.1
      qpdf: link libatomic explicitly on mips

Bartłomiej Burdukiewicz (2):
      pugixml: generate pkgconfig files.
      pugixml: add native and nativesdk BBCLASSEXTEND

Claude Bing (3):
      php: fix PACKAGECONFIG for soap
      php: fix opcache link error in 7.4
      php: update fix for opcache link issue in 7.4.4

Emmanuel Roullit (1):
      cockpit: fix metainfo.xml file ownership

Gianfranco Costamagna (1):
      cpprest: Disable one more test requiring internet connection

Gregory Vimont (1):
      opencv: 4.1.0 -> 4.3.0

Jonathan Liu (1):
      x11vnc: fix xfc NULL pointer dereference

Jorge Solla (1):
      Cockpit: Added missing dependency on udisks2 for package cockpit-storaged

Khem Raj (7):
      remmina: Depend on avahi instead of Avahi-ui
      libgit2: Enable pcre2 regexp backend
      con2fbmap: Add recipe
      xf86-input-void: Drop INC_PR
      nodejs: Fix build with icu 67.1
      nss: Remove mcpu to avoid march conflicts
      pmdk: Update to 1.8

Konrad Weihmann (2):
      php: fix zip package config
      php: add multibyte string support config

Leon Anavi (1):
      lirc: upgrade 0.9.4d -> 0.10.1

Michael Haener (1):
      cockpit: Add recipe version 218

Mingli Yu (10):
      python3-ntplib: add missing python3-io RDEPENDS
      python3-pid: add the missing rdepends
      python3-parallax: add the missing rdepends
      python3-pkgconfig: add missing rdepends
      python3-pathlib2: add the missing rdepends
      python3-ptyprocess: add the missing rdepends
      python3-pydbus: add the missing rdepends
      python3-pyudev: add the missing rdepends
      python3-zipp: add the missing rdepends
      gnome-themes-extra: correct the recipe name

Pierre-Jean Texier (1):
      ccid: upgrade 1.4.31 -> 1.4.32

Rasmus Villemoes (1):
      libgpiod: split c++ library to its own package

Sean Nyekjaer (1):
      gpsd: Upgrade 3.19 -> 3.20

Slater, Joseph (2):
      python-pretty-table: add rdep's
      python3-pyhamcrest: add rdep

Trevor Gamblin (7):
      python3-py: add python3-netclient to RDEPENDS
      python3-markdown: add logging and setuptools to RDEPENDS
      python3-pyrsistent: add python3-numbers to RDEPENDS
      python3-pytoml: add datetime and stringold to RDEPENDS
      python3-dbusmock: re-add recipe and fix patch path
      python3-pyyaml: add python3-netclient to RDEPENDS
      python3-werkzeug: add python3-logging to RDEPENDS

Wang Mingyu (6):
      mailcap: upgrade 2.1.48 -> 2.1.49
      sanlock: upgrade 3.8.0 -> 3.8.1
      libcgi-perl: upgrade 4.46 -> 4.47
      libencode-perl: upgrade 3.05 -> 3.06
      python3-idna: upgrade 2.8 -> 2.9
      multipath-tools: upgrade 0.8.3 -> 0.8.4

Yi Zhao (1):
      nginx: remove /var/log/nginx when do_install

Zang Ruochen (8):
      python3-parse-type: Modify ptest output format
      python3-pluggy: Modify ptest output format
      python3-polyline: Modify ptest output format
      python3-precise-runner: Modify ptest output format
      python3-prettytable: Modify ptest output format
      python3-ptyprocess: Modify ptest output format
      python3-pyasn1: Modify ptest output format
      python3-pyasn1-modules: Modify ptest output format

Zheng Ruoqin (4):
      python3-pyserial: Modify ptest output format
      python3-pyroute2: Modify ptest output format
      v4l-utils: upgrade 1.18.0 -> 1.18.1
      cpprest: upgrade 2.10.15 -> 2.10.16

Zong Li (1):
      Upgrade testfloat to 3e version.

niko.mauno@vaisala.com (3):
      python3-setuptools-scm: Cosmetic improvement
      python3-setuptools-scm: Add nativesdk to BBCLASSEXTEND
      python3-attrs: Add nativesdk to BBCLASSEXTEND

Change-Id: I696f29557eafda5f9f9d6e26525e1a5819982a4b
Signed-off-by: Andrew Geissler <geissonator@yahoo.com>

1 files changed, 137 insertions, 0 deletions

diff --git a/meta-openembedded/meta-oe/recipes-navigation/gpsd/gpsd_3.20.bb b/meta-openembedded/meta-oe/recipes-navigation/gpsd/gpsd_3.20.bb
new file mode 100644
index 0000000000..0914f7ec2b
--- /dev/null
+++ b/meta-openembedded/meta-oe/recipes-navigation/gpsd/gpsd_3.20.bb
@@ -0,0 +1,137 @@
+SUMMARY = "A TCP/IP Daemon simplifying the communication with GPS devices"
+SECTION = "console/network"
+LICENSE = "BSD-2-Clause"
+LIC_FILES_CHKSUM = "file://COPYING;md5=01764c35ae34d9521944bb6ab312af53"
+DEPENDS = "dbus ncurses python3 pps-tools"
+PROVIDES = "virtual/gpsd"
+
+SRC_URI = "${SAVANNAH_GNU_MIRROR}/${BPN}/${BP}.tar.gz \
+    file://0001-SConstruct-prefix-includepy-with-sysroot-and-drop-sy.patch \
+    file://0001-Revert-SConstruct-Add-test-for-sizeof-time_t-result-.patch \
+"
+SRC_URI[md5sum] = "cf7fdec7ce7221d20bee1a7246362b05"
+SRC_URI[sha256sum] = "172a7805068eacb815a3c5225436fcb0be46e7e49a5001a94034eac43df85e50"
+
+inherit scons update-rc.d python3-dir python3native systemd update-alternatives
+
+INITSCRIPT_PACKAGES = "gpsd-conf"
+INITSCRIPT_NAME = "gpsd"
+INITSCRIPT_PARAMS = "defaults 35"
+
+SYSTEMD_OESCONS = "${@bb.utils.contains('DISTRO_FEATURES', 'systemd', 'true', 'false',d)}"
+
+export STAGING_INCDIR
+export STAGING_LIBDIR
+
+PACKAGECONFIG ??= "${@bb.utils.contains('DISTRO_FEATURES', 'bluetooth', 'bluez', '', d)} usb"
+PACKAGECONFIG[bluez] = "bluez='true',bluez='false',bluez5"
+PACKAGECONFIG[qt] = "qt='yes' qt_versioned=5,qt='no',qtbase"
+PACKAGECONFIG[usb] = "usb='true',usb='false',libusb1"
+EXTRA_OESCONS = " \
+    sysroot=${STAGING_DIR_TARGET} \
+    libQgpsmm='false' \
+    debug='false' \
+    nostrip='true' \
+    systemd='${SYSTEMD_OESCONS}' \
+    libdir='${libdir}' \
+    manbuild='false' \
+    ${PACKAGECONFIG_CONFARGS} \
+"
+# this cannot be used, because then chrpath is not found and only static lib is built
+# target=${HOST_SYS}
+
+do_compile_prepend() {
+    export PKG_CONFIG_PATH="${PKG_CONFIG_PATH}"
+    export PKG_CONFIG="PKG_CONFIG_SYSROOT_DIR=\"${PKG_CONFIG_SYSROOT_DIR}\" pkg-config"
+    export STAGING_PREFIX="${STAGING_DIR_HOST}/${prefix}"
+    export LINKFLAGS="${LDFLAGS}"
+}
+
+do_install() {
+    export PKG_CONFIG_PATH="${PKG_CONFIG_PATH}"
+    export PKG_CONFIG="PKG_CONFIG_SYSROOT_DIR=\"${PKG_CONFIG_SYSROOT_DIR}\" pkg-config"
+    export STAGING_PREFIX="${STAGING_DIR_HOST}/${prefix}"
+    export LINKFLAGS="${LDFLAGS}"
+
+    export DESTDIR="${D}"
+    # prefix is used for RPATH and DESTDIR/prefix for instalation
+    ${STAGING_BINDIR_NATIVE}/scons prefix=${prefix} python_libdir=${libdir} install ${EXTRA_OESCONS} || \
+      bbfatal "scons install execution failed."
+}
+
+do_install_append() {
+    install -d ${D}/${sysconfdir}/init.d
+    install -m 0755 ${S}/packaging/deb/etc_init.d_gpsd ${D}/${sysconfdir}/init.d/gpsd
+    install -d ${D}/${sysconfdir}/default
+    install -m 0644 ${S}/packaging/deb/etc_default_gpsd ${D}/${sysconfdir}/default/gpsd.default
+
+    #support for udev
+    install -d ${D}/${sysconfdir}/udev/rules.d
+    install -m 0644 ${S}/gpsd.rules ${D}/${sysconfdir}/udev/rules.d/
+    install -d ${D}${base_libdir}/udev/
+    install -m 0755 ${S}/gpsd.hotplug ${D}${base_libdir}/udev/
+
+    #support for python
+    install -d ${D}/${PYTHON_SITEPACKAGES_DIR}/gps
+    install -m 755 ${S}/gps/*.py ${D}/${PYTHON_SITEPACKAGES_DIR}/gps
+
+    #support for systemd
+    install -d ${D}${systemd_unitdir}/system/
+    install -m 0644 ${S}/systemd/${BPN}.service ${D}${systemd_unitdir}/system/${BPN}.service
+    sed -i -e 's,/usr/local,/usr,g' ${D}${systemd_unitdir}/system/${BPN}.service
+    install -m 0644 ${S}/systemd/${BPN}ctl@.service ${D}${systemd_unitdir}/system/${BPN}ctl@.service
+    sed -i -e 's,/usr/local,/usr,g' ${D}${systemd_unitdir}/system/${BPN}ctl@.service
+    install -m 0644 ${S}/systemd/${BPN}.socket ${D}${systemd_unitdir}/system/${BPN}.socket
+}
+
+PACKAGES =+ "libgps libgpsd python3-pygps gpsd-udev gpsd-conf gpsd-gpsctl gps-utils"
+
+RPROVIDES_${PN}-dbg += "python-pygps-dbg"
+
+FILES_${PN}-dev += "${libdir}/pkgconfdir/libgpsd.pc ${libdir}/pkgconfdir/libgps.pc \
+                    ${libdir}/libQgpsmm.prl"
+
+RDEPENDS_${PN} = "gpsd-gpsctl"
+RRECOMMENDS_${PN} = "gpsd-conf gpsd-udev gpsd-machine-conf"
+
+SUMMARY_gpsd-udev = "udev relevant files to use gpsd hotplugging"
+FILES_gpsd-udev = "${base_libdir}/udev ${sysconfdir}/udev/*"
+RDEPENDS_gpsd-udev += "udev gpsd-conf"
+
+SUMMARY_libgpsd = "C service library used for communicating with gpsd"
+FILES_libgpsd = "${libdir}/libgpsd.so.*"
+
+SUMMARY_libgps = "C service library used for communicating with gpsd"
+FILES_libgps = "${libdir}/libgps.so.*"
+
+SUMMARY_gpsd-conf = "gpsd configuration files and init scripts"
+FILES_gpsd-conf = "${sysconfdir}"
+CONFFILES_gpsd-conf = "${sysconfdir}/default/gpsd.default"
+
+SUMMARY_gpsd-gpsctl = "Tool for tweaking GPS modes"
+FILES_gpsd-gpsctl = "${bindir}/gpsctl"
+
+SUMMARY_gps-utils = "Utils used for simulating, monitoring,... a GPS"
+# Python files are required for gps/fake, required for gpsfake.
+FILES_gps-utils = "${bindir}/* ${libdir}/gps/*.py ${libdir}/gps/*.so"
+RDEPENDS_gps-utils = "python3-pygps"
+
+SUMMARY_python3-pygps = "Python bindings to gpsd"
+FILES_python3-pygps = "${PYTHON_SITEPACKAGES_DIR}/* ${libdir}/gps/*.py ${libdir}/*.egg-info"
+RDEPENDS_python3-pygps = " \
+    python3-core \
+    python3-io \
+    python3-threading \
+    python3-terminal \
+    gpsd \
+    python3-json"
+
+RPROVIDES_${PN} += "${PN}-systemd"
+RREPLACES_${PN} += "${PN}-systemd"
+RCONFLICTS_${PN} += "${PN}-systemd"
+SYSTEMD_SERVICE_${PN} = "${BPN}.socket ${BPN}ctl@.service"
+
+
+ALTERNATIVE_${PN} = "gpsd-defaults"
+ALTERNATIVE_LINK_NAME[gpsd-defaults] = "${sysconfdir}/default/gpsd"
+ALTERNATIVE_TARGET[gpsd-defaults] = "${sysconfdir}/default/gpsd.default"