openpower: Build croserver from eCMD

This packages the croserver so it can be shipped as part of the image.
It should only be started on developer systems, as it listens on a
network port without further authentication.

The eCMD build process is unique. Due to the way it handles LDFLAGS the
recipe passes the GNU hash style to the linker manually. If/when eCMD's
build scripts are improved to support the build environment providing
extra LDFLAGS this could be removed.

(From meta-openpower rev: d02041513915469430aed06ad60804d625331b87)

Change-Id: Ic842089770e4f9e0c7e47ba855a074ae6ef70d73
Signed-off-by: Joel Stanley <joel@jms.id.au>
Signed-off-by: Brad Bishop <bradleyb@fuzziesquirrel.com>

1 files changed, 29 insertions, 0 deletions

diff --git a/meta-openpower/recipes-bsp/ecmd/croserver_git.bb b/meta-openpower/recipes-bsp/ecmd/croserver_git.bb
new file mode 100644
index 0000000000..a788e61642
--- /dev/null
+++ b/meta-openpower/recipes-bsp/ecmd/croserver_git.bb
@@ -0,0 +1,29 @@
+SUMMARY = "eCMD"
+DESCRIPTION = "eCMD is a hardware access API for IBM Systems"
+LICENSE= "Apache-2.0"
+LIC_FILES_CHKSUM = "file://${S}/NOTICE;md5=fee220301a2af3faf8f211524b4248ea"
+
+SRC_URI = "git://github.com/open-power/eCMD.git"
+SRCREV = "6c0348b12c95b3bd6e8d8003f9ff743d25400ae2"
+DEPENDS += "python-native zlib"
+
+S = "${WORKDIR}/git"
+
+# Add the hash style option here to Work around this warning:
+#   "QA Issue: No GNU_HASH in the elf binary"
+#
+# The recipe cannot set LDFLAGS in the environment as it overrides the
+# internal settings.
+do_configure() {
+   LD="${CXX} -Wl,--hash-style=gnu" ${S}/config.py --without-swig --output-root ${B} --target obj --extensions "cmd cip" --build-verbose
+}
+
+do_compile() {
+    cd ${S}/dllNetwork/server
+    oe_runmake
+}
+
+do_install() {
+    install -d ${D}${bindir}
+    install -m 0755 out_obj/lib/server1p ${D}${bindir}/croserver
+}