meta-phosphor: Move layer content from common/

Adopt a more conventional directory hierarchy.  meta-phosphor is still
a _long_ way from suitable for hosting on yoctoproject.org but things
like this don't help.

(From meta-phosphor rev: 471cfcefa74b8c7ceb704cb670e6d915cf27c63b)

Change-Id: I3f106b2f6cdc6cec734be28a6090800546f362eb
Signed-off-by: Brad Bishop <bradleyb@fuzziesquirrel.com>

1 files changed, 53 insertions, 0 deletions

diff --git a/meta-phosphor/recipes-phosphor/sensors/phosphor-hwmon.bb b/meta-phosphor/recipes-phosphor/sensors/phosphor-hwmon.bb
new file mode 100644
index 0000000000..fe051b57a9
--- /dev/null
+++ b/meta-phosphor/recipes-phosphor/sensors/phosphor-hwmon.bb
@@ -0,0 +1,53 @@
+SUMMARY = "OpenBMC hwmon poller"
+DESCRIPTION = "OpenBMC hwmon poller."
+PR = "r1"
+
+LICENSE = "Apache-2.0"
+LIC_FILES_CHKSUM = "file://LICENSE;md5=fa818a259cbed7ce8bc2a22d35a464fc"
+
+inherit autotools pkgconfig obmc-phosphor-systemd
+
+PACKAGE_BEFORE_PN = "max31785-msl"
+SYSTEMD_PACKAGES = "${PN} max31785-msl"
+
+SYSTEMD_SERVICE_${PN} = "xyz.openbmc_project.Hwmon@.service"
+SYSTEMD_SERVICE_max31785-msl = "phosphor-max31785-msl@.service"
+
+DEPENDS += "autoconf-archive-native"
+DEPENDS += " \
+        sdbusplus \
+        phosphor-dbus-interfaces \
+        phosphor-logging \
+        "
+
+
+RDEPENDS_${PN} += "\
+        sdbusplus \
+        phosphor-dbus-interfaces \
+        phosphor-logging \
+        bash \
+        "
+
+RRECOMMENDS_${PN} += "${VIRTUAL-RUNTIME_phosphor-hwmon-config}"
+
+FILES_max31785-msl = "${bindir}/max31785-msl"
+RDEPENDS_max31785-msl = "${VIRTUAL-RUNTIME_base-utils} i2c-tools"
+
+SRC_URI += "git://github.com/openbmc/phosphor-hwmon"
+SRC_URI += "file://70-hwmon.rules"
+SRC_URI += "file://70-iio.rules"
+SRC_URI += "file://start_hwmon.sh"
+
+SRCREV = "c9c818ed854f23a87dd77c2209b6a27805825adb"
+
+S = "${WORKDIR}/git"
+
+do_install_append() {
+
+        install -d ${D}/${base_libdir}/udev/rules.d/
+        install ${WORKDIR}/70-hwmon.rules ${D}/${base_libdir}/udev/rules.d/
+        install ${WORKDIR}/70-iio.rules ${D}/${base_libdir}/udev/rules.d/
+
+        install -d ${D}${bindir}
+        install -m 0755 ${WORKDIR}/start_hwmon.sh ${D}${bindir}
+}