meta-fii: meta-mori: Uniform syntax for recipes

Update bitbake recipe format to make uniform with the following rules:

1) Generally bbappends should have layer(mori) overrides
2) Add uniform appending by using "append" instead of "+="
3) bb files (excluding bbappends) typically should not have "append"
   phrase except for limited amount of variables
   (RDEPENDS,DEPENDS,FILES, ...)
4) Wrap lines greater than 80 chars when applicable
5) Switch syntax for long list values over multiple lines to use
   four-space indent

In addition, oe-stylize.py was applied to further refine recipe syntax.

Tested: Built successfully. Individual packages were tested for
functionality with no notable change.

Change-Id: I626c529373805aa696f7c574e10c1617493d4f61
Signed-off-by: Kyle Nieman <kyle.nieman@fii-na.com>

18 files changed, 157 insertions, 170 deletions

diff --git a/meta-fii/meta-mori/recipes-mori/boot-status-led/mori-boot-status-led.bb b/meta-fii/meta-mori/recipes-mori/boot-status-led/mori-boot-status-led.bb
index c9b2e9d5e4..4641e7f11e 100644
--- a/meta-fii/meta-mori/recipes-mori/boot-status-led/mori-boot-status-led.bb
+++ b/meta-fii/meta-mori/recipes-mori/boot-status-led/mori-boot-status-led.bb
@@ -1,25 +1,25 @@
 SUMMARY = "OpenBMC Mori Boot Status LED Service"
 DESCRIPTION = "OpenBMC Mori Boot Status LED Daemon."
-PR = "r1"
 LICENSE = "Apache-2.0"
 LIC_FILES_CHKSUM = "file://${COREBASE}/meta/files/common-licenses/Apache-2.0;md5=89aea4e17d99a7cacdbeed46a0096b10"
+DEPENDS:append = " systemd"
+PR = "r1"
 
-inherit systemd
+SRC_URI = " \
+    file://boot-status-led.sh \
+    file://boot-status-led.service \
+"
 
-DEPENDS += "systemd"
-RDEPENDS:${PN} += "bash"
+SYSTEMD_SERVICE:${PN} = "boot-status-led.service"
 
-SRC_URI = " file://boot-status-led.sh \
-            file://boot-status-led.service \
-          "
+inherit systemd
 
 do_install() {
     install -d ${D}${bindir}
     install -m 0755 ${WORKDIR}/boot-status-led.sh ${D}${bindir}/
-
     install -d ${D}${systemd_system_unitdir}
-    install -m 0644 ${WORKDIR}/boot-status-led.service ${D}${systemd_system_unitdir}
+    install -m 0644 ${WORKDIR}/boot-status-led.service \
+        ${D}${systemd_system_unitdir}
 }
 
-SYSTEMD_PACKAGES = "${PN}"
-SYSTEMD_SERVICE:${PN} = "boot-status-led.service"
+RDEPENDS:${PN}:append = " bash"
diff --git a/meta-fii/meta-mori/recipes-mori/mori-fw-utility/mori-bios-update.bb b/meta-fii/meta-mori/recipes-mori/mori-fw-utility/mori-bios-update.bb
index d0c47c055e..cf3cba9f2e 100644
--- a/meta-fii/meta-mori/recipes-mori/mori-fw-utility/mori-bios-update.bb
+++ b/meta-fii/meta-mori/recipes-mori/mori-fw-utility/mori-bios-update.bb
@@ -1,35 +1,31 @@
 SUMMARY = "Phosphor OpenBMC Mori BIOS Firmware Upgrade Command"
 DESCRIPTION = "Phosphor OpenBMC Mori BIOS Firmware Upgrade Comman Daemon"
-
-PR = "r1"
 LICENSE = "Apache-2.0"
 LIC_FILES_CHKSUM = "file://${COREBASE}/meta/files/common-licenses/Apache-2.0;md5=89aea4e17d99a7cacdbeed46a0096b10"
+DEPENDS:append = " systemd phosphor-ipmi-flash"
+PROVIDES:append = " virtual/bios-update"
+PR = "r1"
 
-inherit systemd
-inherit obmc-phosphor-systemd
-
-DEPENDS += "systemd"
-DEPENDS += "phosphor-ipmi-flash"
-RDEPENDS:${PN} += "libsystemd"
-RDEPENDS:${PN} += "mori-fw"
-PROVIDES += "virtual/bios-update"
-RPROVIDES:${PN} += "virtual/bios-update"
-
-FILES:${PN} += "${datadir}/phosphor-ipmi-flash/config-bios.json"
-
-SRC_URI += " \
+SRC_URI = " \
     file://phosphor-ipmi-flash-bios-update.service \
     file://config-bios.json \
-    "
+"
+
+SYSTEMD_SERVICE:${PN} = "phosphor-ipmi-flash-bios-update.service"
 
-SYSTEMD_PACKAGES = "${PN}"
-SYSTEMD_SERVICE:${PN} += " \
-    phosphor-ipmi-flash-bios-update.service \
-    "
+inherit systemd obmc-phosphor-systemd
 
 do_install () {
     install -d ${D}${datadir}/phosphor-ipmi-flash
-    install -m 0644 ${WORKDIR}/config-bios.json ${D}${datadir}/phosphor-ipmi-flash
+    install -m 0644 ${WORKDIR}/config-bios.json \
+        ${D}${datadir}/phosphor-ipmi-flash
     install -d ${D}${systemd_system_unitdir}
-    install -m 0644 ${WORKDIR}/phosphor-ipmi-flash-bios-update.service  ${D}${systemd_system_unitdir}
+    install -m 0644 ${WORKDIR}/phosphor-ipmi-flash-bios-update.service \
+        ${D}${systemd_system_unitdir}
 }
+
+RDEPENDS:${PN}:append = " libsystemd mori-fw"
+
+RPROVIDES:${PN}:append = " virtual/bios-update"
+
+FILES:${PN}:append = " ${datadir}/phosphor-ipmi-flash/config-bios.json"
diff --git a/meta-fii/meta-mori/recipes-mori/mori-fw-utility/mori-bmc-update.bb b/meta-fii/meta-mori/recipes-mori/mori-fw-utility/mori-bmc-update.bb
index db74f33964..2b802d06cc 100644
--- a/meta-fii/meta-mori/recipes-mori/mori-fw-utility/mori-bmc-update.bb
+++ b/meta-fii/meta-mori/recipes-mori/mori-fw-utility/mori-bmc-update.bb
@@ -1,23 +1,21 @@
 SUMMARY = "Phosphor OpenBMC Mori BMC Firmware Upgrade Command"
 DESCRIPTION = "Phosphor OpenBMC Mori BMC Firmware Upgrade Comman Daemon"
-
-PR = "r1"
 LICENSE = "Apache-2.0"
 LIC_FILES_CHKSUM = "file://${COREBASE}/meta/files/common-licenses/Apache-2.0;md5=89aea4e17d99a7cacdbeed46a0096b10"
+DEPENDS:append = " phosphor-ipmi-flash"
+PROVIDES:append = " virtual/bmc-update"
+PR = "r1"
 
-DEPENDS += "phosphor-ipmi-flash"
-RDEPENDS:${PN} += "mori-fw"
-
-RPROVIDES:${PN} += "virtual/bmc-update"
-PROVIDES += "virtual/bmc-update"
-RPROVIDES:${PN} += "virtual/bmc-update"
-FILES:${PN} += "${datadir}/phosphor-ipmi-flash/config-bmc.json"
-
-SRC_URI += " \
-    file://config-bmc.json \
-    "
+SRC_URI = "file://config-bmc.json"
 
 do_install () {
     install -d ${D}${datadir}/phosphor-ipmi-flash
-    install -m 0644 ${WORKDIR}/config-bmc.json ${D}${datadir}/phosphor-ipmi-flash
+    install -m 0644 ${WORKDIR}/config-bmc.json \
+        ${D}${datadir}/phosphor-ipmi-flash
 }
+
+RDEPENDS:${PN}:append = " mori-fw"
+
+RPROVIDES:${PN}:append = " virtual/bmc-update"
+
+FILES:${PN}:append = " ${datadir}/phosphor-ipmi-flash/config-bmc.json"
diff --git a/meta-fii/meta-mori/recipes-mori/mori-fw-utility/mori-cpld-update.bb b/meta-fii/meta-mori/recipes-mori/mori-fw-utility/mori-cpld-update.bb
index 7b19f8e14f..1161c75c3d 100644
--- a/meta-fii/meta-mori/recipes-mori/mori-fw-utility/mori-cpld-update.bb
+++ b/meta-fii/meta-mori/recipes-mori/mori-fw-utility/mori-cpld-update.bb
@@ -1,41 +1,43 @@
 SUMMARY = "Phosphor OpenBMC Mori CPLD Firmware Upgrade Command"
 DESCRIPTION = "Phosphor OpenBMC Mori CPLD Firmware Upgrade Comman Daemon"
-
-PR = "r1"
 LICENSE = "Apache-2.0"
 LIC_FILES_CHKSUM = "file://${COREBASE}/meta/files/common-licenses/Apache-2.0;md5=89aea4e17d99a7cacdbeed46a0096b10"
+DEPENDS:append = " systemd phosphor-ipmi-flash"
+PROVIDES:append = " virtual/cpld-update"
+PR = "r1"
 
-inherit systemd
-inherit obmc-phosphor-systemd
-
-DEPENDS += "systemd"
-DEPENDS += "phosphor-ipmi-flash"
-RDEPENDS:${PN} += "libsystemd"
-RDEPENDS:${PN} += "mori-fw"
-PROVIDES += "virtual/cpld-update"
-RPROVIDES:${PN} += "virtual/cpld-update"
-
-FILES:${PN} += "${datadir}/phosphor-ipmi-flash/config-bmccpld.json"
-FILES:${PN} += "${datadir}/phosphor-ipmi-flash/config-mbcpld.json"
-
-SRC_URI += " \
+SRC_URI = " \
     file://phosphor-ipmi-flash-bmccpld-update.service \
     file://phosphor-ipmi-flash-mbcpld-update.service \
     file://config-bmccpld.json \
     file://config-mbcpld.json \
-    "
+"
 
-SYSTEMD_PACKAGES = "${PN}"
-SYSTEMD_SERVICE:${PN} += " \
+SYSTEMD_SERVICE:${PN} = " \
     phosphor-ipmi-flash-bmccpld-update.service \
     phosphor-ipmi-flash-mbcpld-update.service \
-    "
+"
+
+inherit systemd obmc-phosphor-systemd
 
 do_install () {
     install -d ${D}${datadir}/phosphor-ipmi-flash
-    install -m 0644 ${WORKDIR}/config-bmccpld.json ${D}${datadir}/phosphor-ipmi-flash
-    install -m 0644 ${WORKDIR}/config-mbcpld.json ${D}${datadir}/phosphor-ipmi-flash
+    install -m 0644 ${WORKDIR}/config-bmccpld.json \
+        ${D}${datadir}/phosphor-ipmi-flash
+    install -m 0644 ${WORKDIR}/config-mbcpld.json \
+        ${D}${datadir}/phosphor-ipmi-flash
     install -d ${D}${systemd_system_unitdir}
-    install -m 0644 ${WORKDIR}/phosphor-ipmi-flash-bmccpld-update.service ${D}${systemd_system_unitdir}
-    install -m 0644 ${WORKDIR}/phosphor-ipmi-flash-mbcpld-update.service ${D}${systemd_system_unitdir}
+    install -m 0644 ${WORKDIR}/phosphor-ipmi-flash-bmccpld-update.service \
+        ${D}${systemd_system_unitdir}
+    install -m 0644 ${WORKDIR}/phosphor-ipmi-flash-mbcpld-update.service \
+        ${D}${systemd_system_unitdir}
 }
+
+RDEPENDS:${PN}:append = " libsystemd mori-fw"
+
+RPROVIDES:${PN}:append = " virtual/cpld-update"
+
+FILES:${PN}:append = " \
+    ${datadir}/phosphor-ipmi-flash/config-bmccpld.json \
+    ${datadir}/phosphor-ipmi-flash/config-mbcpld.json \
+"
diff --git a/meta-fii/meta-mori/recipes-mori/mori-fw-utility/mori-fw.bb b/meta-fii/meta-mori/recipes-mori/mori-fw-utility/mori-fw.bb
index 272106a6ae..71c69b0b2c 100644
--- a/meta-fii/meta-mori/recipes-mori/mori-fw-utility/mori-fw.bb
+++ b/meta-fii/meta-mori/recipes-mori/mori-fw-utility/mori-fw.bb
@@ -1,36 +1,30 @@
 SUMMARY = "Phosphor OpenBMC mori Firmware Upgrade Command"
 DESCRIPTION = "Phosphor OpenBMC mori Firmware Upgrade Comman Daemon"
-
-PR = "r1"
 LICENSE = "Apache-2.0"
 LIC_FILES_CHKSUM = "file://${COREBASE}/meta/files/common-licenses/Apache-2.0;md5=89aea4e17d99a7cacdbeed46a0096b10"
-
-inherit systemd
-inherit obmc-phosphor-systemd
-
-DEPENDS += "systemd"
-DEPENDS += "phosphor-ipmi-flash"
-RDEPENDS:${PN} += "libsystemd"
-RDEPENDS:${PN} += "bash"
+DEPENDS:append = " systemd phosphor-ipmi-flash"
+PR = "r1"
 
 SRC_URI = " \
     file://mori-fw.sh \
     file://mori-fw-ver.service \
     file://mori-fw-ver.sh \
     file://mori-lib.sh \
-    "
+"
+
+SYSTEMD_SERVICE:${PN} = "mori-fw-ver.service"
 
-SYSTEMD_PACKAGES = "${PN}"
-SYSTEMD_SERVICE:${PN} = " \
-    mori-fw-ver.service \
-    "
+inherit systemd obmc-phosphor-systemd
 
 do_install () {
     install -d ${D}${sbindir}
     install -d ${D}${libexecdir}/${PN}
     install -m 0755 ${WORKDIR}/mori-fw.sh ${D}${sbindir}/mori-fw.sh
-    install -m 0755 ${WORKDIR}/mori-fw-ver.sh ${D}${libexecdir}/${PN}/mori-fw-ver.sh
+    install -m 0755 ${WORKDIR}/mori-fw-ver.sh \
+        ${D}${libexecdir}/${PN}/mori-fw-ver.sh
     install -m 0755 ${WORKDIR}/mori-lib.sh ${D}${libexecdir}/${PN}/mori-lib.sh
     install -d ${D}${systemd_system_unitdir}
     install -m 0644 ${WORKDIR}/mori-fw-ver.service ${D}${systemd_system_unitdir}
 }
+
+RDEPENDS:${PN}:append = " libsystemd bash"
diff --git a/meta-fii/meta-mori/recipes-mori/mori-sys-utility/mori-boot.bb b/meta-fii/meta-mori/recipes-mori/mori-sys-utility/mori-boot.bb
index bceca8d935..acf0c03f17 100644
--- a/meta-fii/meta-mori/recipes-mori/mori-sys-utility/mori-boot.bb
+++ b/meta-fii/meta-mori/recipes-mori/mori-sys-utility/mori-boot.bb
@@ -1,30 +1,25 @@
 SUMMARY = "Phosphor OpenBMC Mori System Power Control Service"
 DESCRIPTION = "Phosphor OpenBMC Mori System Power Control Daemon"
-
-PR = "r1"
 LICENSE = "Apache-2.0"
 LIC_FILES_CHKSUM = "file://${COREBASE}/meta/files/common-licenses/Apache-2.0;md5=89aea4e17d99a7cacdbeed46a0096b10"
-
-inherit systemd
-inherit obmc-phosphor-systemd
-
-DEPENDS += "systemd"
-RDEPENDS:${PN} += "libsystemd"
-RDEPENDS:${PN} += "bash"
+DEPENDS:append = " systemd"
+PR = "r1"
 
 SRC_URI = " \
     file://init_once.sh \
     file://host-powerctrl.service \
-    "
+"
+
+SYSTEMD_SERVICE:${PN} = "host-powerctrl.service"
 
-SYSTEMD_PACKAGES = "${PN}"
-SYSTEMD_SERVICE:${PN} = " \
-    host-powerctrl.service \
-    "
+inherit systemd obmc-phosphor-systemd
 
 do_install () {
     install -d ${D}${libexecdir}/${PN}
     install -m 0755 ${WORKDIR}/init_once.sh ${D}${libexecdir}/${PN}
     install -d ${D}${systemd_unitdir}/system/
-    install -m 0644 ${WORKDIR}/host-powerctrl.service ${D}${systemd_unitdir}/system
+    install -m 0644 ${WORKDIR}/host-powerctrl.service \
+        ${D}${systemd_unitdir}/system
 }
+
+RDEPENDS:${PN}:append = " libsystemd bash"
diff --git a/meta-fii/meta-mori/recipes-mori/mori-sys-utility/mori-cmd.bb b/meta-fii/meta-mori/recipes-mori/mori-sys-utility/mori-cmd.bb
index 34d9e04597..3fb90a20df 100644
--- a/meta-fii/meta-mori/recipes-mori/mori-sys-utility/mori-cmd.bb
+++ b/meta-fii/meta-mori/recipes-mori/mori-sys-utility/mori-cmd.bb
@@ -1,19 +1,14 @@
 SUMMARY = "Phosphor OpenBMC Mori System Command"
 DESCRIPTION = "Phosphor OpenBMC Mori System Command Daemon"
-
-PR = "r1"
 LICENSE = "Apache-2.0"
 LIC_FILES_CHKSUM = "file://${COREBASE}/meta/files/common-licenses/Apache-2.0;md5=89aea4e17d99a7cacdbeed46a0096b10"
+PR = "r1"
 
-RDEPENDS:${PN} += "bash"
-
-SRC_URI = " \
-    file://mori.sh \
-    "
-
-SYSTEMD_PACKAGES = "${PN}"
+SRC_URI = "file://mori.sh"
 
 do_install () {
     install -d ${D}${sbindir}
     install -m 0755 ${WORKDIR}/mori.sh ${D}${sbindir}/mori.sh
 }
+
+RDEPENDS:${PN}:append = " bash"
diff --git a/meta-fii/meta-mori/recipes-phosphor/console/obmc-console_%.bbappend b/meta-fii/meta-mori/recipes-phosphor/console/obmc-console_%.bbappend
index 90b21cd5f3..54c15d13af 100644
--- a/meta-fii/meta-mori/recipes-phosphor/console/obmc-console_%.bbappend
+++ b/meta-fii/meta-mori/recipes-phosphor/console/obmc-console_%.bbappend
@@ -1,30 +1,34 @@
 FILESEXTRAPATHS:prepend:mori := "${THISDIR}/${PN}:"
-RDEPENDS:${PN}:append:mori = " bash"
-
-OBMC_CONSOLE_TTYS:mori = "ttyS1 ttyS3"
 
-SRC_URI:append:mori = " file://${BPN}@.service \
-                        file://host_console_uart_config.service \
-                        file://mori_uart_mux_ctrl.sh \
-                        file://server.ttyS1.conf \
-                        file://server.ttyS3.conf \
-                      "
+SRC_URI:append:mori = " \
+    file://${BPN}@.service \
+    file://host_console_uart_config.service \
+    file://mori_uart_mux_ctrl.sh \
+    file://server.ttyS1.conf \
+    file://server.ttyS3.conf \
+"
 
 SYSTEMD_SERVICE:${PN}:append:mori = " \
-        ${BPN}@.service \
-        host_console_uart_config.service \
-        "
+    ${BPN}@.service \
+    host_console_uart_config.service \
+"
 
 do_install:append:mori() {
     install -d ${D}${libexecdir}/${PN}
-    install -m 0755 ${WORKDIR}/mori_uart_mux_ctrl.sh ${D}${libexecdir}/${PN}/mori_uart_mux_ctrl.sh
-    install -m 0644 ${WORKDIR}/host_console_uart_config.service ${D}${systemd_unitdir}/system
+    install -m 0755 ${WORKDIR}/mori_uart_mux_ctrl.sh \
+        ${D}${libexecdir}/${PN}/mori_uart_mux_ctrl.sh
+    install -m 0644 ${WORKDIR}/host_console_uart_config.service \
+        ${D}${systemd_unitdir}/system
     # Overwrite base package's obmc-console@.service with our own
-    install -m 0644 ${WORKDIR}/${BPN}@.service ${D}${systemd_unitdir}/system/${BPN}@.service
+    install -m 0644 ${WORKDIR}/${BPN}@.service \
+        ${D}${systemd_unitdir}/system/${BPN}@.service
 }
 
+RDEPENDS:${PN}:append:mori = " bash"
+
 pkg_postinst:${PN}:append:mori () {
     systemctl --root=$D enable obmc-console@ttyS1.service
     systemctl --root=$D enable obmc-console@ttyS3.service
 }
 
+OBMC_CONSOLE_TTYS:mori = "ttyS1 ttyS3"
diff --git a/meta-fii/meta-mori/recipes-phosphor/fans/pwm-init.bb b/meta-fii/meta-mori/recipes-phosphor/fans/pwm-init.bb
index 97daab696e..798bf2bac7 100644
--- a/meta-fii/meta-mori/recipes-phosphor/fans/pwm-init.bb
+++ b/meta-fii/meta-mori/recipes-phosphor/fans/pwm-init.bb
@@ -1,29 +1,27 @@
 SUMMARY = "Initialize PWM sensors"
 DESCRIPTION = "Initialize PWM sensors"
 LICENSE = "CLOSED"
+DEPENDS:append = " systemd"
 PR = "r1"
 
-inherit systemd
-
-DEPENDS = "systemd"
-RDEPENDS:${PN} = "bash"
-
-S = "${WORKDIR}"
-FILESEXTRAPATHS:prepend := "${THISDIR}/${PN}:"
-SRC_URI += " \
+SRC_URI = " \
     file://pwm_init.service \
     file://bin/pwm_init.sh \
-    "
+"
 
-SYSTEMD_PACKAGES = "${PN}"
+S = "${WORKDIR}"
 SYSTEMD_AUTO_ENABLE = "enable"
-SYSTEMD_SERVICE:${PN} += "pwm_init.service"
+SYSTEMD_SERVICE:${PN} = " pwm_init.service"
 
-FILES:${PN} += "${bindir}/* ${systemd_system_unitdir}/*"
+inherit systemd
 
-do_install:append() {
+do_install() {
     install -d ${D}${libexecdir}/${PN}
     install -m 0755 ${S}/bin/* ${D}${libexecdir}/${PN}/
     install -d ${D}${systemd_system_unitdir}
     install -m 0644 ${S}/*.service ${D}${systemd_system_unitdir}
 }
+
+RDEPENDS:${PN}:append = " bash"
+
+FILES:${PN}:append = " ${bindir}/* ${systemd_system_unitdir}/*"
diff --git a/meta-fii/meta-mori/recipes-phosphor/ipmi/phosphor-ipmi-blobs-binarystore_%.bbappend b/meta-fii/meta-mori/recipes-phosphor/ipmi/phosphor-ipmi-blobs-binarystore_%.bbappend
index 3a353a2de1..967e308fbb 100644
--- a/meta-fii/meta-mori/recipes-phosphor/ipmi/phosphor-ipmi-blobs-binarystore_%.bbappend
+++ b/meta-fii/meta-mori/recipes-phosphor/ipmi/phosphor-ipmi-blobs-binarystore_%.bbappend
@@ -1,8 +1,10 @@
 FILESEXTRAPATHS:prepend:mori := "${THISDIR}/${PN}:"
+
 SRC_URI:append:mori = " file://config.json"
-FILES:${PN}:append:mori = " ${datadir}/binaryblob/config.json"
 
 do_install:append:mori() {
     install -d ${D}${datadir}/binaryblob/
     install ${WORKDIR}/config.json ${D}${datadir}/binaryblob/config.json
 }
+
+FILES:${PN}:append:mori = " ${datadir}/binaryblob/config.json"
diff --git a/meta-fii/meta-mori/recipes-phosphor/ipmi/phosphor-ipmi-flash_%.bbappend b/meta-fii/meta-mori/recipes-phosphor/ipmi/phosphor-ipmi-flash_%.bbappend
index ad45d1ab91..905611a383 100644
--- a/meta-fii/meta-mori/recipes-phosphor/ipmi/phosphor-ipmi-flash_%.bbappend
+++ b/meta-fii/meta-mori/recipes-phosphor/ipmi/phosphor-ipmi-flash_%.bbappend
@@ -1,3 +1,2 @@
 PACKAGECONFIG:append:mori = " nuvoton-p2a-mbox net-bridge"
-
 IPMI_FLASH_BMC_ADDRESS:mori = "0xF0848000"
diff --git a/meta-fii/meta-mori/recipes-phosphor/leds/mori-led-manager-config-native.bb b/meta-fii/meta-mori/recipes-phosphor/leds/mori-led-manager-config-native.bb
index 0a5282f4bd..843b7e39dc 100644
--- a/meta-fii/meta-mori/recipes-phosphor/leds/mori-led-manager-config-native.bb
+++ b/meta-fii/meta-mori/recipes-phosphor/leds/mori-led-manager-config-native.bb
@@ -1,15 +1,15 @@
 SUMMARY = "Phosphor LED Group Management for mori"
-PR = "r1"
 LICENSE = "Apache-2.0"
 LIC_FILES_CHKSUM = "file://${COREBASE}/meta/files/common-licenses/Apache-2.0;md5=89aea4e17d99a7cacdbeed46a0096b10"
+PROVIDES:append = " virtual/phosphor-led-manager-config-native"
+PR = "r1"
 
-FILES:${PN} += "${datadir}/phosphor-led-manager/led.yaml"
+SRC_URI = "file://led.yaml"
 
-inherit native
-PROVIDES += "virtual/phosphor-led-manager-config-native"
-SRC_URI += "file://led.yaml"
 S = "${WORKDIR}"
 
+inherit native
+
 # Overwrite the example led layout yaml file prior
 # to building the phosphor-led-manager package
 do_install() {
@@ -17,3 +17,5 @@ do_install() {
     DEST=${D}${datadir}/phosphor-led-manager
     install -D ${SRC}/led.yaml ${DEST}/led.yaml
 }
+
+FILES:${PN}:append = " ${datadir}/phosphor-led-manager/led.yaml"
diff --git a/meta-fii/meta-mori/recipes-phosphor/leds/phosphor-led-manager_%.bbappend b/meta-fii/meta-mori/recipes-phosphor/leds/phosphor-led-manager_%.bbappend
index 1231cae2ac..8e85c11e94 100644
--- a/meta-fii/meta-mori/recipes-phosphor/leds/phosphor-led-manager_%.bbappend
+++ b/meta-fii/meta-mori/recipes-phosphor/leds/phosphor-led-manager_%.bbappend
@@ -1 +1 @@
-CHASSIS_TARGETS=""
+CHASSIS_TARGETS:mori = ""
diff --git a/meta-fii/meta-mori/recipes-phosphor/sel-logger/phosphor-sel-logger_%.bbappend b/meta-fii/meta-mori/recipes-phosphor/sel-logger/phosphor-sel-logger_%.bbappend
index 84f448dc88..9299c56dea 100644
--- a/meta-fii/meta-mori/recipes-phosphor/sel-logger/phosphor-sel-logger_%.bbappend
+++ b/meta-fii/meta-mori/recipes-phosphor/sel-logger/phosphor-sel-logger_%.bbappend
@@ -1,2 +1,4 @@
 # Enable threshold, pulse, and watchdog monitoring
-PACKAGECONFIG:append:mori = " log-threshold log-alarm log-pulse log-watchdog clears-sel"
+PACKAGECONFIG:append:mori = " \
+    log-threshold log-alarm log-pulse log-watchdog clears-sel \
+"
diff --git a/meta-fii/meta-mori/recipes-phosphor/settings/phosphor-settings-manager_%.bbappend b/meta-fii/meta-mori/recipes-phosphor/settings/phosphor-settings-manager_%.bbappend
index bace54ca1f..a76d585f95 100644
--- a/meta-fii/meta-mori/recipes-phosphor/settings/phosphor-settings-manager_%.bbappend
+++ b/meta-fii/meta-mori/recipes-phosphor/settings/phosphor-settings-manager_%.bbappend
@@ -1,2 +1,3 @@
 FILESEXTRAPATHS:append:mori := ":${THISDIR}/${PN}"
+
 SRC_URI:append:mori = " file://chassis_capabilities.override.yml"
diff --git a/meta-fii/meta-mori/recipes-phosphor/skeleton/obmc-libobmc-intf_%.bbappend b/meta-fii/meta-mori/recipes-phosphor/skeleton/obmc-libobmc-intf_%.bbappend
index 2b62a49a9e..d321224303 100644
--- a/meta-fii/meta-mori/recipes-phosphor/skeleton/obmc-libobmc-intf_%.bbappend
+++ b/meta-fii/meta-mori/recipes-phosphor/skeleton/obmc-libobmc-intf_%.bbappend
@@ -1,4 +1,3 @@
 FILESEXTRAPATHS:append:mori := ":${THISDIR}/${PN}"
 
 SRC_URI:append:mori = " file://gpio_defs.json"
-
diff --git a/meta-fii/meta-mori/recipes-phosphor/smbios/smbios-mdr_%.bbappend b/meta-fii/meta-mori/recipes-phosphor/smbios/smbios-mdr_%.bbappend
index 0b7e413996..12f45c32e9 100644
--- a/meta-fii/meta-mori/recipes-phosphor/smbios/smbios-mdr_%.bbappend
+++ b/meta-fii/meta-mori/recipes-phosphor/smbios/smbios-mdr_%.bbappend
@@ -1,3 +1,2 @@
 PACKAGECONFIG:append:mori = " smbios-ipmi-blob"
-
 PACKAGECONFIG:remove:mori = " cpuinfo"
diff --git a/meta-fii/meta-mori/recipes-phosphor/state/phosphor-state-manager_%.bbappend b/meta-fii/meta-mori/recipes-phosphor/state/phosphor-state-manager_%.bbappend
index 1eb8793046..c351919c3f 100644
--- a/meta-fii/meta-mori/recipes-phosphor/state/phosphor-state-manager_%.bbappend
+++ b/meta-fii/meta-mori/recipes-phosphor/state/phosphor-state-manager_%.bbappend
@@ -1,19 +1,36 @@
 FILESEXTRAPATHS:prepend:mori := "${THISDIR}/${PN}:"
-
 DEPENDS:append:mori = " gpioplus"
-EXTRA_OEMESON:append = " -Dhost-gpios=enabled"
+
+SRC_URI:append:mori = " \
+    file://xyz.openbmc_project.State.Chassis@.service \
+    file://xyz.openbmc_project.State.Host@.service \
+"
+
+SYSTEMD_SERVICE:${PN}-host:append:mori = " phosphor-host-condition-gpio@.service"
+
+EXTRA_OEMESON:append:mori = " -Dhost-gpios=enabled"
+
+do_install:append:mori() {
+    install -d ${D}${systemd_system_unitdir}
+    install -m 0644 ${WORKDIR}/xyz.openbmc_project.State.Chassis@.service \
+        ${D}${systemd_system_unitdir}/xyz.openbmc_project.State.Chassis@.service
+    install -m 0644 ${WORKDIR}/xyz.openbmc_project.State.Host@.service \
+        ${D}${systemd_system_unitdir}/xyz.openbmc_project.State.Host@.service
+}
 
 FILES:${PN}:append:mori = " ${systemd_system_unitdir}/*"
 FILES:${PN}-host:append:mori = " ${bindir}/phosphor-host-condition-gpio"
-SYSTEMD_SERVICE:${PN}-host:append:mori = " phosphor-host-condition-gpio@.service"
 
+pkg_prerm:${PN}-obmc-targets:prepend:mori() {
+    LINK="$D$systemd_system_unitdir/multi-user.target.requires/phosphor-host-condition-gpio@0.service"
+    rm $LINK
+}
 pkg_postinst:${PN}-obmc-targets:prepend:mori() {
     mkdir -p $D$systemd_system_unitdir/multi-user.target.requires
     LINK="$D$systemd_system_unitdir/multi-user.target.requires/phosphor-host-condition-gpio@0.service"
     TARGET="../phosphor-host-condition-gpio@.service"
     ln -s $TARGET $LINK
 }
-
 pkg_postinst:${PN}-obmc-targets:append:mori() {
     rm "$D$systemd_system_unitdir/obmc-host-reboot@0.target.requires/obmc-host-shutdown@0.target"
     rm "$D$systemd_system_unitdir/obmc-host-reboot@0.target.requires/phosphor-reboot-host@0.service"
@@ -23,19 +40,3 @@ pkg_postinst:${PN}-obmc-targets:append:mori() {
     rm "$D$systemd_system_unitdir/obmc-host-force-warm-reboot@0.target.requires/obmc-host-stop@0.target"
     rm "$D$systemd_system_unitdir/obmc-host-force-warm-reboot@0.target.requires/phosphor-reboot-host@0.service"
 }
-
-pkg_prerm:${PN}-obmc-targets:prepend:mori() {
-    LINK="$D$systemd_system_unitdir/multi-user.target.requires/phosphor-host-condition-gpio@0.service"
-    rm $LINK
-}
-
-SRC_URI:append:mori = " \
-    file://xyz.openbmc_project.State.Chassis@.service \
-    file://xyz.openbmc_project.State.Host@.service \
-    "
-
-do_install:append:mori() {
-    install -d ${D}${systemd_system_unitdir}
-    install -m 0644 ${WORKDIR}/xyz.openbmc_project.State.Chassis@.service ${D}${systemd_system_unitdir}/xyz.openbmc_project.State.Chassis@.service
-    install -m 0644 ${WORKDIR}/xyz.openbmc_project.State.Host@.service ${D}${systemd_system_unitdir}/xyz.openbmc_project.State.Host@.service
-}