diff options
author | Brad Bishop <bradleyb@fuzziesquirrel.com> | 2019-09-01 22:16:57 +0300 |
---|---|---|
committer | Brad Bishop <bradleyb@fuzziesquirrel.com> | 2019-09-01 22:17:10 +0300 |
commit | 0f291cce3faf2fd387c0db8f04bd2f9f4187f6df (patch) | |
tree | fd9642af54c93d167257fc64a83fd6b13e4797a2 /meta-openembedded/meta-gnome/recipes-gnome/eds/evolution-data-server_3.32.4.bb | |
parent | cb8d89a37dfb6211c4918867949f0f8cc4bf6bf4 (diff) | |
download | openbmc-0f291cce3faf2fd387c0db8f04bd2f9f4187f6df.tar.xz |
meta-openembedded: subtree update:1e8bc46e55..6a5d6bc9ad
Aaltonen Eero (1):
Recipe for docopt.cpp option parsing library
Aaron Chan (1):
python3-pyatspi: Add Dbus ATSPI recipe
Adrian Bunk (11):
xmlsec1: Import from meta-security
libgit2: Upgrade 0.27.9 -> 0.28.3
libenv-perl: Import from meta-security
libgit2: Don't pass parameters with their default values to cmake
Replace EXCLUDE_FROM_WORLD_libc-musl = "1" with COMPATIBLE_HOST_libc-musl = 'null'
libwebsockets: Fix the build with -Os
mimic: Fix the build with -Os
Adapt to the lsb -> lsb-release change in OE-core
meta-oe: Replace EXCLUDE_FROM_WORLD_libc-musl = "1" with COMPATIBLE_HOST_libc-musl = 'null'
Remove LICENSE = "MIT" from packagegroups and images
Remove bogus COMMON_LICENSE_DIR usage in LIC_FILES_CHKSUM
Andreas Müller (4):
cmark: initial add 0.29.0
libsigc++-2.0: upgrade 2.10.1 -> 2.10.2
glibmm: upgrade 2.58.1 -> 2.60.0
evolution-data-server: remove unused gconf dep and pythonnative dep
Anuj Mittal (2):
pugixml: add recipe
vlc: don't look at host headers for live555
Bruce Ashfield (1):
dnsmasq: fix build against 5.2 headers
Callaghan, Dan (1):
python3-pystemd: add new recipe
Changqing Li (3):
xfsprogs: support usrmerge
ntfs-3g-ntfsprogs: support usrmerge
grubby: support usrmerge
Chris Laplante (1):
breakpad: fix patch striplevel to avoid 'devtool modify breakpad' error
Christophe PRIOUZEAU (1):
python-script: update license md5sum
Gianfranco Costamagna (2):
libmodbus: update version to 3.1.6
ifmetric: add initial recipe based on Debian packaging and patches
Hongxu Jia (4):
libdevmapper/lvm2: force recipe libdevmapper to populate sysroot only
multipath-tools: lvm2 to DEPENDS
cryptsetup: add libdevmapper to RDEPENDS
cryptsetup: add libdevmapper to RDEPENDS
Kai Kang (1):
xfce4-datetime-setter: fix compile error and requires distro feature x11
Khem Raj (14):
libgpiod: nherit python3native unconditionally
kernel-selftest: Warn conditionally about clang-native dependency
docopt.cpp: Drop using gitpkgv
libnss-nisplus: Fix build with glibc >= 2.30
bpftool.bb: Disable SECURITY_CFLAGS
kernel-selftest: Explicitly disable stack protector
ncmpc: Update to 0.34
websocketpp_0.8.1.bb: Fix build with asio from boost 1.70+
can-utils: Fix build with kernel headers >= 5.2
android-tools: update license md5sum for BSD-2-Clause
can-isotp: Update to latest tip
linux-atm: Fix build with kernel headers 5.2+
drbd: Upgrade to 9.0.19-1
ssiapi: Upgrade to 1.3.0
Klauer, Daniel (1):
sjf2410-linux-native: Fix do_deploy sstate caching
Oleksandr Kravchuk (1):
nftables: update to 0.9.2
Piotr Tworek (18):
libmxml: Use autotools bbclass and cleanup the recipe a bit.
evolution-data-server: Update to version 3.32.4
evolution-data-server: Drop x11 as required distro feature.
evolution-data-server: Inherit upstream-version-is-even bbclass.
evolution-data-server: Add dedicated packages for libebook-contacts.
evolution-data-server: Specify SYSCONF_INSTALL_DIR in EXTRA_OECMAKE.
evolution-data-server: Drop bits related to autotools
evolution-data-server: Add PACKAGECONFIGs for oauth2 and kerberos.
evolution-data-server: Drop ENABLE_UOA from EXTRA_OECMAKE.
evolution-data-server: Drop glade file references.
evolution-data-server: Fix package gobject-introspection support.
evolution-data-server: Add PACKAGECONFIG for vala bindings.
evolution-data-server: Turn goa support into PACKAGECONFIG feature.
evolution-data-server: Add weather PACKAGECONFIG feature.
evolution-data-server: Add PACKAGECONFIG entry for phonenumber.
evolution-data-server: Use SRC_URI provided by gnomebase.
evolution-data-server: Remove unused FILES paterns.
evolution-data-server: Don't use explicit version number for libebook
Qi.Chen@windriver.com (1):
libblockdev: fix PACKAGECONFIG regarding python
Robert Yang (1):
netcf: Fix Manifest not found issue
Yi Zhao (1):
samba: upgrade 4.10.6 -> 4.10.7
Yuan Chao (11):
python-typing: upgrade 3.7.4 -> 3.7.4.1
python-twisted: upgrade 19.2.1 -> 19.7.0
python-jsonschema: upgrade 2.6.0 -> 3.0.2
kpatch: upgrade 0.7.1 -> 0.8.0
libtdb: upgrade 1.4.1 -> 1.4.2
python-paste: upgrade 3.1.0 -> 3.1.1
python-pip: upgrade 19.2.2 -> 19.2.3
python-pytest: upgrade 3.4.2 -> 5.1.1
python3-xxhash: upgrade 1.3.0 -> 1.4.1
python-pluggy: upgrade 0.6.0 -> 0.12.0
python-cmd2: upgrade 0.9.2 -> 0.9.16
Zang Ruochen (3):
python-futures: upgrade 3.2.0 -> 3.3.0
python-pyyaml: upgrade 3.13 -> 5.1.2
python-alembic: upgrade 1.0.11 -> 1.1.0
Change-Id: I3b55c2efba09c26e31018ee2cbbc908f06630c7c
Signed-off-by: Brad Bishop <bradleyb@fuzziesquirrel.com>
Diffstat (limited to 'meta-openembedded/meta-gnome/recipes-gnome/eds/evolution-data-server_3.32.4.bb')
-rw-r--r-- | meta-openembedded/meta-gnome/recipes-gnome/eds/evolution-data-server_3.32.4.bb | 155 |
1 files changed, 155 insertions, 0 deletions
diff --git a/meta-openembedded/meta-gnome/recipes-gnome/eds/evolution-data-server_3.32.4.bb b/meta-openembedded/meta-gnome/recipes-gnome/eds/evolution-data-server_3.32.4.bb new file mode 100644 index 000000000..429dd53d8 --- /dev/null +++ b/meta-openembedded/meta-gnome/recipes-gnome/eds/evolution-data-server_3.32.4.bb @@ -0,0 +1,155 @@ +SUMMARY = "Evolution database backend server" +HOMEPAGE = "http://www.gnome.org/projects/evolution/" +BUGTRACKER = "https://bugzilla.gnome.org/" + +LICENSE = "LGPLv2 & LGPLv2+" +LIC_FILES_CHKSUM = "file://COPYING;md5=6a6e689d19255cf0557f3fe7d7068212 \ + file://src/camel/camel.h;endline=24;md5=342fc5e9357254bc30c24e43ae47d9a1 \ + file://src/libedataserver/e-data-server-util.h;endline=20;md5=8f21a9c80ea82a4fb80b5f959f672543 \ + file://src/calendar/libecal/e-cal.h;endline=24;md5=e699ec3866f73f129f7a4ffffdcfc196" + +DEPENDS = " \ + intltool-native gperf-native glib-2.0-native \ + glib-2.0 gtk+3 libgnome-keyring libgdata libcanberra icu \ + dbus db virtual/libiconv zlib libsoup-2.4 libical nss libsecret \ +" + +inherit gnomebase cmake gtk-doc gettext gobject-introspection perlnative upstream-version-is-even vala + +SRC_URI += "file://0001-CMakeLists.txt-Remove-TRY_RUN-for-iconv.patch \ + file://0002-CMakeLists.txt-remove-CHECK_C_SOURCE_RUNS-check.patch \ + file://0003-contact-Replace-the-Novell-sample-contact-with-somet.patch \ + file://0004-Add-native-suffix-to-exacutables-produced-and-run-du.patch \ + file://0005-Use-LC_MESSAGES-for-address-localization-when-LC_ADD.patch \ + file://0006-Dont-add-usr-lib-to-LDFLAGS-when-linking-libphonenum.patch \ + file://0007-Modify-gobject-intrispection-support-to-work-with-OE.patch \ + file://iconv-detect.h \ + " +SRC_URI[archive.md5sum] = "57820f3f88fc554e1a58665a52e12c05" +SRC_URI[archive.sha256sum] = "83f67cb4b680e892b22b51bcde64c788b7ac63e92a99de401fb347e3794f4c7f" + +LKSTRFTIME = "HAVE_LKSTRFTIME=ON" +LKSTRFTIME_libc-musl = "HAVE_LKSTRFTIME=OFF" + +EXTRA_OECMAKE = " \ + -D${LKSTRFTIME} \ + -DSYSCONF_INSTALL_DIR=${sysconfdir} \ + -DLIB_SUFFIX=${@d.getVar('baselib').replace('lib', '')} \ +" + +PACKAGECONFIG ??= "${@bb.utils.contains('GI_DATA_ENABLED', 'True', 'introspection', '', d)}" +PACKAGECONFIG[openldap] = "-DWITH_OPENLDAP=ON,-DWITH_OPENLDAP=OFF,openldap" +PACKAGECONFIG[oauth2] = "-DENABLE_OAUTH2=ON,-DENABLE_OAUTH2=OFF,json-glib webkitgtk" +PACKAGECONFIG[mitkrb5] = "-DWITH_KRB5=ON,-DWITH_KRB5=OFF,krb5" +PACKAGECONFIG[goa] = "-DENABLE_GOA=ON,-DENABLE_GOA=OFF,gnome-online-accounts" +PACKAGECONFIG[weather] = "-DENABLE_WEATHER=ON,-DENABLE_WEATHER=OFF,libgweather" +PACKAGECONFIG[phonenumber] = "-DWITH_PHONENUMBER=ON,-DWITH_PHONENUMBER=OFF,libphonenumber" +PACKAGECONFIG[introspection] = "-DENABLE_INTROSPECTION=ON,-DENABLE_INTROSPECTION=OFF" +PACKAGECONFIG[vala] = "-DENABLE_VALA_BINDINGS=ON -DVAPIGEN=${STAGING_BINDIR_NATIVE}/vapigen,-DENABLE_VALA_BINDINGS=OFF" + +# -ldb needs this on some platforms +LDFLAGS += "-lpthread -lgmodule-2.0 -lgthread-2.0" + +do_configure_append () { + cp ${WORKDIR}/iconv-detect.h ${S}/src + + # fix native perl shebang + sed -i 's:${STAGING_BINDIR_NATIVE}/perl-native:${bindir}:' ${B}/src/tools/addressbook-export/csv2vcard +} + +do_compile_prepend() { + # CMake does not support building native binaries when cross compiling. As result + # it always cross compiles them for the target and then aborts when they fail to run. + # To work around this manually build required tools and patch cmake targets to use + # those native binaries we built here. + ${BUILD_CC} ${BUILD_CFLAGS} ${BUILD_LDFLAGS} -I${B} ${S}/src/camel/camel-gen-tables.c \ + -o ${B}/src/camel/camel-gen-tables-native + ${BUILD_CC} ${BUILD_CFLAGS} ${BUILD_LDFLAGS} -I${B} $(pkg-config-native --cflags glib-2.0) \ + ${S}/src/addressbook/libebook-contacts/gen-western-table.c \ + -o ${B}/src/addressbook/libebook-contacts/gen-western-table-native \ + $(pkg-config-native --libs glib-2.0) +} + + +PACKAGES =+ "libebook-contacts libebook-contacts-dev \ + libcamel libcamel-dev libebook libebook-dev libecal libecal-dev \ + libedata-book libedata-book-dev libedata-cal libedata-cal-dev \ + libedataserver libedataserver-dev \ + libedataserverui libedataserverui-dev" + +FILES_${PN} =+ "${systemd_user_unitdir} \ + ${datadir}/dbus-1 \ + ${datadir}/evolution-data-server-*/ui/" +RDEPENDS_${PN} += "perl" + +FILES_${PN}-dev =+ "${libdir}/pkgconfig/evolution-data-server-*.pc" +FILES_${PN}-dbg =+ "${libdir}/evolution-data-server*/camel-providers/.debug \ + ${libdir}/evolution-data-server*/calendar-backends/.debug \ + ${libdir}/evolution-data-server*/addressbook-backends/.debug \ + ${libdir}/evolution-data-server*/extensions/.debug/" + +RRECOMMENDS_${PN}-dev += "libecal-dev libebook-dev" + +FILES_libcamel = "${libdir}/libcamel-*.so.* \ + ${libdir}/libcamel-provider-*.so.* \ + ${libdir}/girepository-*/Camel-*.typelib \ + ${libdir}/evolution-data-server*/camel-providers/*.so \ + ${libdir}/evolution-data-server*/camel-providers/*.urls" +FILES_libcamel-dev = "${libdir}/libcamel-*.so ${libdir}/libcamel-provider-*.so \ + ${libdir}/pkgconfig/camel*pc \ + ${includedir}/evolution-data-server*/camel \ + ${datadir}/vala/vapi/camel-* \ + ${datadir}/gir-*/Camel-*.gir" + +FILES_libebook = "${libdir}/libebook-*.so.* \ + ${libdir}/girepository-*/EBook-*.typelib" +FILES_libebook-dev = "${libdir}/libebook-*.so \ + ${libdir}/pkgconfig/libebook-*.pc \ + ${datadir}/gir-*/EBook-*.gir \ + ${datadir}/vala/vapi/libebook-*.* \ + ${includedir}/evolution-data-server*/libebook/*.h" +RRECOMMENDS_libebook = "libedata-book" + +FILES_libebook-contacts = "${libdir}/libebook-contacts-*.so.* \ + ${libdir}/girepository-*/EBookContacts-*.typelib" +FILES_libebook-contacts-dev = "${libdir}/libebook-contacts-*.so \ + ${libdir}/pkgconfig/libebook-contacts-*.pc \ + ${datadir}/gir-*/EBookContacts-*.gir \ + ${datadir}/vala/vapi/libebook-contacts-* \ + ${includedir}/evolution-data-server*/libebook-contacts/*.h" + +FILES_libecal = "${libdir}/libecal-*.so.*" +FILES_libecal-dev = "${libdir}/libecal-*.so ${libdir}/pkgconfig/libecal-*.pc \ + ${includedir}/evolution-data-server*/libecal/*.h \ + ${includedir}/evolution-data-server*/libical/*.h" +RRECOMMENDS_libecal = "libedata-cal tzdata" + +FILES_libedata-book = "${libexecdir}/e-addressbook-factory \ + ${datadir}/dbus-1/services/*.AddressBook.service \ + ${libdir}/libedata-book-*.so.* \ + ${libdir}/evolution-data-server-*/extensions/libebook*.so" +FILES_libedata-book-dev = "${libdir}/libedata-book-*.so \ + ${libdir}/pkgconfig/libedata-book-*.pc \ + ${includedir}/evolution-data-server-*/libedata-book" + +FILES_libedata-cal = "${libexecdir}/e-calendar-factory \ + ${datadir}/dbus-1/services/*.Calendar.service \ + ${libdir}/libedata-cal-*.so.* \ + ${libdir}/evolution-data-server-*/extensions/libecal*.so" +FILES_libedata-cal-dev = "${libdir}/libedata-cal-*.so \ + ${libdir}/pkgconfig/libedata-cal-*.pc \ + ${includedir}/evolution-data-server-*/libedata-cal" + +FILES_libedataserver = "${libdir}/libedataserver-*.so.* \ + ${libdir}/girepository-*/EDataServer-*.typelib" +FILES_libedataserver-dev = "${libdir}/libedataserver-*.so \ + ${libdir}/pkgconfig/libedataserver-*.pc \ + ${datadir}/vala/vapi/libedataserver-* \ + ${includedir}/evolution-data-server-*/libedataserver/*.h" + +FILES_libedataserverui = "${libdir}/libedataserverui-*.so.*" +FILES_libedataserverui-dev = "${libdir}/libedataserverui-*.so \ + ${libdir}/pkgconfig/libedataserverui-*.pc \ + ${datadir}/gir-*/EDataServerUI-*.gir \ + ${datadir}/vala/vapi/libedataserverui-* \ + ${includedir}/evolution-data-server-*/libedataserverui/*.h" |