meta-openembedded: subtree update:c986cbed93..e0daf6f8e0

Adrian Bunk (19):
      lldpd: Upgrade 1.0.3 -> 1.0.4
      usrsctp: Upgrade to a more recent git snapshot
      cim-schema: Remove duplicate file
      dovecot: Upgrade 2.2.36.3 -> 2.2.36.4
      flashrom: Upgrade 1.0 -> 1.1
      doxygen: Upgrade 1.8.15 -> 1.8.16
      nodejs: Upgrade 10.16.3 -> 10.17.0
      php: Upgrade 7.3.9 -> 7.3.11
      libdivecomputer: Upgrade to 0.6.0
      libnss-nisplus: Upgrade to the latest upstream git
      pegtl: Upgrade 2.1.4 -> 2.8.1
      openwsman: Upgrade 2.6.9 -> 2.6.11
      cgdb: Upgrade 0.6.8 -> 0.7.1
      packagegroup-meta-networking: Exclude nonbuilding recipes with musl
      xf86-input-tslib: Upgrade 0.0.6 -> 0.0.7
      libmicrohttpd: Upgrade 0.9.66 -> 0.9.67
      poco: Upgrade 1.9.0 -> 1.9.4
      libgphoto2: Remove obsolete HAL files
      mdns: Mark as incompatible with musl

Andreas Müller (5):
      unicode-ucd: initial add 12.1.0
      unicode-ucd: Set correct SUMMARY and HOMEPAGE
      colord: initial add 1.4.4
      colord-gtk: initial add 0.2.0
      ibus: initial add 1.5.21

André Draszik (3):
      nodejs: allow use of system c-ares (and make default)
      libuv: update to 1.33.1
      nodejs: allow use of system libuv (and make default)

Carlos Rafael Giani (1):
      opencv: Enable pkg-config .pc file generation

Khem Raj (5):
      miniupnpd: Update to 2.1.20191006
      miniupnpd: Build config.h before full build
      poco: Fix build on risc-v
      python-docutils: Upgrade to 0.15.2
      iwd: Use python3 variant of docutils during build

Luca Boccassi (1):
      dbus-broker: build with libaudit if selinux is enabled

Martin Siegumfeldt (1):
      libiio: add python3 packageconfig

Paul Eggleton (1):
      python3-pillow: update to 6.2.1

Slater, Joseph (2):
      syslog-ng: add volatile directory init for systemd
      syslog-ng: change conf files to version 3.19

Trevor Gamblin (4):
      python-priority: add recipe
      python-h2: add recipe
      python-hyperframe: add recipe
      python-hpack: add recipe

Yi Zhao (1):
      freeradius: set CLEANBROKEN

Zang Ruochen (22):
      poppler: upgrade 0.80.0 -> 0.82.0
      gmime: upgrade 3.2.3 -> 3.2.4
      autofs: upgrade 5.1.5 -> 5.1.6
      python-simplejson: enable native and nativesdk
      python-dnspython: upgrade 1.15.0 -> 1.16.0
      python-engineio: upgrade 3.9.3 -> 3.10.0
      python-evdev: upgrade 0.7.0 -> 1.2.0
      python-future: upgrade 0.16.0 -> 0.18.2
      python-intervals: upgrade 1.5.4 -> 1.10.0
      python-isort: upgrade 4.3.4 -> 4.3.21
      python-javaobj-py3: upgrade 0.2.4 -> 0.3.0
      python-lazy-object-proxy: upgrade 1.3.1 -> 1.4.3
      python-parse: upgrade 1.8.4 -> 1.12.1
      python-pathlib2: upgrade 2.3.4 -> 2.3.5
      python-periphery: upgrade 1.1.1 -> 2.0.0
      python-pint: upgrade 0.8.1 -> 0.9
      python-progress: upgrade 1.4 -> 1.5
      python-prompt-toolkit: upgrade 2.0.4 -> 2.0.10
      python-pybind11: upgrade 2.2.3 -> 2.4.3
      python-pycryptodome: upgrade 3.4.11 -> 3.9.0
      python-pyexpect: upgrade 1.0.17 -> 1.0.19
      python-pyfirmata: upgrade 1.0.3 -> 1.1.0

Zheng Ruoqin (23):
      pure-ftpd: upgrade 1.0.47 -> 1.0.49
      grpc: upgrade 1.24.1 -> 1.24.3
      corosync: upgrade 2.4.4 -> 2.4.5
      dhcpcd: upgrade 8.0.2 -> 8.1.1
      iscsi-initiator-utils: upgrade 2.0.877 -> 2.0.878
      znc: upgrade 1.7.4 -> 1.7.5
      babeld: upgrade 1.8.4 -> 1.9.1
      htpdate: upgrade 1.2.1 -> 1.2.2
      nbd: upgrade 3.19 -> 3.20
      unbound: upgrade 1.9.2 -> 1.9.4
      wireshark: upgrade 3.0.3 -> 3.0.6
      mtr: upgrade 0.92 -> 0.93
      libowfat: upgrade 0.31 -> 0.32
      iozone3: upgrade 484 -> 487
      libhugetlbfs: upgrade 2.21 -> 2.22
      phoronix-test-suite: upgrade 8.8.1 -> 9.0.1
      lmsensors: upgrade 3.5.0 -> 3.6.0
      paho-mqtt-c: upgrade 1.3.0 -> 1.3.1
      rtorrent: upgrade 0.9.7 -> 0.9.8
      zabbix: upgrade 4.2.6 -> 4.2.7
      iwd: upgrade 0.20 -> 0.23
      libtorrent: upgrade 0.13.7 -> 0.13.8
      ledmon: upgrade to 0.93

Change-Id: I66f0f395da9087e46899cf882e36d9cc50718c62
Signed-off-by: Brad Bishop <bradleyb@fuzziesquirrel.com>

1 files changed, 168 insertions, 0 deletions

diff --git a/meta-openembedded/meta-oe/recipes-bsp/lm_sensors/lmsensors_3.6.0.bb b/meta-openembedded/meta-oe/recipes-bsp/lm_sensors/lmsensors_3.6.0.bb
new file mode 100644
index 000000000..48490e8d8
--- /dev/null
+++ b/meta-openembedded/meta-oe/recipes-bsp/lm_sensors/lmsensors_3.6.0.bb
@@ -0,0 +1,168 @@
+SUMMARY = "Hardware health monitoring applications"
+HOMEPAGE = "https://hwmon.wiki.kernel.org/"
+LICENSE = "GPLv2+ & LGPLv2.1+"
+LIC_FILES_CHKSUM = "file://COPYING;md5=751419260aa954499f7abaabaa882bbe \
+                    file://COPYING.LGPL;md5=4fbd65380cdd255951079008b364516c"
+
+DEPENDS = " \
+    bison-native \
+    flex-native \
+    rrdtool \
+    virtual/libiconv \
+"
+
+SRC_URI = "git://github.com/lm-sensors/lm-sensors.git;protocol=https \
+           file://fancontrol.init \
+           file://sensord.init \
+"
+SRCREV = "1667b850a1ce38151dae17156276f981be6fb557"
+
+inherit update-rc.d systemd
+
+RDEPENDS_${PN}-dev = ""
+
+PACKAGECONFIG ??= "sensord"
+PACKAGECONFIG[sensord] = "sensord,,rrdtool"
+
+INITSCRIPT_PACKAGES = "\
+    ${PN}-fancontrol \
+    ${@bb.utils.contains('PACKAGECONFIG', 'sensord', '${PN}-sensord', '', d)} \
+    "
+INITSCRIPT_NAME_${PN}-fancontrol = "fancontrol"
+INITSCRIPT_NAME_${PN}-sensord = "sensord"
+INITSCRIPT_PARAMS_${PN}-fancontrol = "defaults 66"
+INITSCRIPT_PARAMS_${PN}-sensord = "defaults 67"
+
+SYSTEMD_PACKAGES = "\
+    ${PN} \
+    ${PN}-fancontrol \
+    ${@bb.utils.contains('PACKAGECONFIG', 'sensord', '${PN}-sensord', '', d)} \
+    "
+SYSTEMD_SERVICE_${PN} = "lm_sensors.service"
+SYSTEMD_SERVICE_${PN}-fancontrol = "fancontrol.service"
+SYSTEMD_SERVICE_${PN}-sensord = "sensord.service"
+SYSTEMD_AUTO_ENABLE = "disable"
+
+S = "${WORKDIR}/git"
+
+EXTRA_OEMAKE = 'EXLDFLAGS="${LDFLAGS}" \
+        MACHINE=${TARGET_ARCH} PREFIX=${prefix} MANDIR=${mandir} \
+        LIBDIR=${libdir} \
+        CC="${CC}" AR="${AR}"'
+
+do_compile() {
+    sed -i -e 's:^# \(PROG_EXTRA\):\1:' ${S}/Makefile
+    # Respect LDFLAGS
+    sed -i -e 's/\$(LIBDIR)$/\$(LIBDIR) \$(LDFLAGS)/g' ${S}/Makefile
+    sed -i -e 's/\$(LIBSHSONAME) -o/$(LIBSHSONAME) \$(LDFLAGS) -o/g' \
+                ${S}/lib/Module.mk
+    oe_runmake user PROG_EXTRA="sensors ${PACKAGECONFIG_CONFARGS}"
+}
+
+do_install() {
+    oe_runmake user_install DESTDIR=${D}
+    if ${@bb.utils.contains('PACKAGECONFIG', 'sensord', 'true', 'false', d)}; then
+        install -m 0755 ${S}/prog/sensord/sensord ${D}${sbindir}
+        install -m 0644 ${S}/prog/sensord/sensord.8 ${D}${mandir}/man8
+    fi
+
+    # Install directory
+    install -d ${D}${INIT_D_DIR}
+
+    # Install fancontrol init script
+    install -m 0755 ${WORKDIR}/fancontrol.init ${D}${INIT_D_DIR}/fancontrol
+
+    if ${@bb.utils.contains('PACKAGECONFIG', 'sensord', 'true', 'false', d)}; then
+        # Install sensord init script
+        install -m 0755 ${WORKDIR}/sensord.init ${D}${INIT_D_DIR}/sensord
+    fi
+
+    # Insall sensord service script
+    install -d ${D}${systemd_unitdir}/system
+    install -m 0644 ${S}/prog/init/*.service ${D}${systemd_unitdir}/system
+    if ! ${@bb.utils.contains('PACKAGECONFIG', 'sensord', 'true', 'false', d)}; then
+        rm ${D}${systemd_system_unitdir}/sensord.service
+    fi
+}
+
+RPROVIDES_${PN}-dbg += "${PN}-libsensors-dbg ${PN}-sensors-dbg ${PN}-sensord-dbg ${PN}-isatools-dbg"
+
+ALLOW_EMPTY_${PN} = "1"
+RDEPENDS_${PN} += " \
+    ${PN}-libsensors \
+    ${PN}-sensors \
+    ${PN}-sensord \
+    ${PN}-fancontrol \
+    ${PN}-sensorsdetect \
+    ${PN}-sensorsconfconvert \
+    ${PN}-pwmconfig \
+    ${PN}-isatools \
+"
+
+# libsensors packages
+PACKAGES =+ "${PN}-libsensors ${PN}-libsensors-dev ${PN}-libsensors-staticdev ${PN}-libsensors-doc"
+
+# sensors command packages
+PACKAGES =+ "${PN}-sensors ${PN}-sensors-doc"
+
+# sensord logging daemon
+PACKAGES =+ "${@bb.utils.contains('PACKAGECONFIG', 'sensord', '${PN}-sensord ${PN}-sensord-doc', '', d)}"
+
+# fancontrol script
+PACKAGES =+ "${PN}-fancontrol ${PN}-fancontrol-doc"
+
+# sensors-detect script
+PACKAGES =+ "${PN}-sensorsdetect ${PN}-sensorsdetect-doc"
+
+# sensors-conf-convert script
+PACKAGES =+ "${PN}-sensorsconfconvert ${PN}-sensorsconfconvert-doc"
+
+# pwmconfig script
+PACKAGES =+ "${PN}-pwmconfig ${PN}-pwmconfig-doc"
+
+# isadump and isaset helper program
+PACKAGES =+ "${PN}-isatools ${PN}-isatools-doc"
+
+
+# libsensors files
+FILES_${PN}-libsensors = "${libdir}/libsensors.so.* ${sysconfdir}/sensors3.conf ${sysconfdir}/sensors.d"
+FILES_${PN}-libsensors-dev = "${libdir}/libsensors.so ${includedir}"
+FILES_${PN}-libsensors-staticdev = "${libdir}/libsensors.a"
+FILES_${PN}-libsensors-doc = "${mandir}/man3"
+RRECOMMENDS_${PN}-libsensors = "lmsensors-config-libsensors"
+
+# sensors command files
+FILES_${PN}-sensors = "${bindir}/sensors"
+FILES_${PN}-sensors-doc = "${mandir}/man1 ${mandir}/man5"
+RDEPENDS_${PN}-sensors = "${PN}-libsensors"
+
+# sensord logging daemon
+FILES_${PN}-sensord = "${sbindir}/sensord ${INIT_D_DIR}/sensord ${systemd_system_unitdir}/sensord.service"
+FILES_${PN}-sensord-doc = "${mandir}/man8/sensord.8"
+RDEPENDS_${PN}-sensord = "${PN}-sensors rrdtool"
+RRECOMMENDS_${PN}-sensord = "lmsensors-config-sensord"
+
+# fancontrol script files
+FILES_${PN}-fancontrol = "${sbindir}/fancontrol ${INIT_D_DIR}/fancontrol"
+FILES_${PN}-fancontrol-doc = "${mandir}/man8/fancontrol.8"
+RDEPENDS_${PN}-fancontrol = "bash"
+RRECOMMENDS_${PN}-fancontrol = "lmsensors-config-fancontrol"
+
+# sensors-detect script files
+FILES_${PN}-sensorsdetect = "${sbindir}/sensors-detect"
+FILES_${PN}-sensorsdetect-doc = "${mandir}/man8/sensors-detect.8"
+RDEPENDS_${PN}-sensorsdetect = "${PN}-sensors perl perl-modules"
+
+# sensors-conf-convert script files
+FILES_${PN}-sensorsconfconvert = "${bindir}/sensors-conf-convert"
+FILES_${PN}-sensorsconfconvert-doc = "${mandir}/man8/sensors-conf-convert.8"
+RDEPENDS_${PN}-sensorsconfconvert = "${PN}-sensors perl perl-modules"
+
+# pwmconfig script files
+FILES_${PN}-pwmconfig = "${sbindir}/pwmconfig"
+FILES_${PN}-pwmconfig-doc = "${mandir}/man8/pwmconfig.8"
+RDEPENDS_${PN}-pwmconfig = "${PN}-fancontrol bash"
+
+# isadump and isaset helper program files
+FILES_${PN}-isatools = "${sbindir}/isa*"
+FILES_${PN}-isatools-doc = "${mandir}/man8/isa*"