meta-xilinx: remove subtree

The meta-xilinx layer was used for a now-deleted EVB.  Neither the EVB
nor the meta-xilinx layer have been updated for the Yocto override
syntax change and the meta-xilinx still doesn't have a hardknott or
honister branch (or corresponding support).

I've asked the Xilinx maintainer back in May on when a hardknott
version would be supported and I was told "about a month from now".  I
followed up in August and was told "work is in progress".  As of today
there are still zero commits in meta-xilinx since January 2021.

As such, I do not believe this layer is well-maintained and we have no
specific use for it anymore.  Remove it until someone finds a good
reason to include it and the upstream shows signs of life.

Signed-off-by: Patrick Williams <patrick@stwcx.xyz>
Change-Id: Id14ea55db2ac2779edf42e63cb57ad7d25172ad5

1 files changed, 0 insertions, 69 deletions

diff --git a/meta-xilinx/meta-xilinx-standalone/recipes-standalone/psm-firmware/psm-firmware_2020.2.bb b/meta-xilinx/meta-xilinx-standalone/recipes-standalone/psm-firmware/psm-firmware_2020.2.bb
deleted file mode 100644
index cd346b123..000000000
--- a/meta-xilinx/meta-xilinx-standalone/recipes-standalone/psm-firmware/psm-firmware_2020.2.bb
+++ /dev/null
@@ -1,69 +0,0 @@
-inherit deploy
-
-LICENSE = "Proprietary"
-LIC_FILES_CHKSUM = "file://../../../../license.txt;md5=39ab6ab638f4d1836ba994ec6852de94"
-
-SRCREV = "e8db5fb118229fdc621e0ec7848641a23bf60998"
-PV = "${XILINX_RELEASE_VERSION}+git${SRCPV}"
-
-SRC_URI = "git://github.com/Xilinx/embeddedsw.git;protocol=https;nobranch=1"
-
-COMPATIBLE_HOST = "microblaze.*-elf"
-COMPATIBLE_MACHINE = "versal-mb"
-
-
-S = "${WORKDIR}/git/lib/sw_apps/versal_psmfw/src"
-
-# The makefile does not handle parallelization
-PARALLEL_MAKE = ""
-
-do_configure() {
-    # manually do the copy_bsp step first, so as to be able to fix up use of
-    # mb-* commands
-    ${S}/../misc/copy_bsp.sh
-}
-
-COMPILER = "${CC}"
-COMPILER_FLAGS = "-O2 -c"
-EXTRA_COMPILER_FLAGS = "-g -Wall -Wextra -Os -flto -ffat-lto-objects"
-ARCHIVER = "${AR}"
-
-BSP_DIR ?= "${S}/../misc/versal_psmfw_bsp"
-BSP_TARGETS_DIR ?= "${BSP_DIR}/psv_psm_0/libsrc"
-
-def bsp_make_vars(d):
-    s = ["COMPILER", "CC", "COMPILER_FLAGS", "EXTRA_COMPILER_FLAGS", "ARCHIVER", "AR", "AS"]
-    return " ".join(["\"%s=%s\"" % (v, d.getVar(v)) for v in s])
-
-do_compile() {
-    # the Makefile in ${S}/../misc/Makefile, does not handle CC, AR, AS, etc
-    # properly. So do its job manually. Preparing the includes first, then libs.
-    for i in $(ls ${BSP_TARGETS_DIR}/*/src/Makefile); do
-        oe_runmake -C $(dirname $i) -s include ${@bsp_make_vars(d)}
-    done
-    for i in $(ls ${BSP_TARGETS_DIR}/*/src/Makefile); do
-        oe_runmake -C $(dirname $i) -s libs ${@bsp_make_vars(d)}
-    done
-
-    # --build-id=none is required due to linker script not defining a location for it.
-    # Again, recipe-systoot include is necessary
-    oe_runmake CC="${CC}" CC_FLAGS="-MMD -MP -Wl,--build-id=none -I${STAGING_DIR_TARGET}/usr/include"
-}
-
-do_install() {
-    :
-}
-
-PSM_FIRMWARE_BASE_NAME ?= "${BPN}-${PKGE}-${PKGV}-${PKGR}-${MACHINE}-${DATETIME}"
-PSM_FIRMWARE_BASE_NAME[vardepsexclude] = "DATETIME"
-
-do_deploy() {
-    install -Dm 0644 ${B}/psmfw.elf ${DEPLOYDIR}/${PSM_FIRMWARE_BASE_NAME}.elf
-    ln -sf ${PSM_FIRMWARE_BASE_NAME}.elf ${DEPLOYDIR}/${BPN}-${MACHINE}.elf
-    ${OBJCOPY} -O binary ${B}/psmfw.elf ${B}/psmfw.bin
-    install -m 0644 ${B}/psmfw.bin ${DEPLOYDIR}/${PSM_FIRMWARE_BASE_NAME}.bin
-    ln -sf ${PSM_FIRMWARE_BASE_NAME}.bin ${DEPLOYDIR}/${BPN}-${MACHINE}.bin
-}
-
-addtask deploy before do_build after do_install
-