meta-openembedded: subtree update:e4ac09169d..459dbf1078

Alex Kiernan (1):
      leveldb: Upgrade 1.20 -> 1.22

Cengiz Can (1):
      recipes-support: gperftools: RDEPENDS for pprof

Changqing Li (2):
      python3-django: upgrade 1.11.14 -> 2.2.7
      python-sqlparse/python3-sqlparse: move from meta-cloud-services

Christopher Larson (1):
      kconfig-frontends: drop unneeded target flex/bison deps

Daniels Umanovskis (1):
      gattlib: add recipe

Fabio Berton (3):
      mdbus2: Add recipe
      jpnevulator: Add recipe
      emlog: Add recipe

Jacopo Dall'Aglio (1):
      python-netifaces: add recipes

Khem Raj (8):
      packagegroup-meta-oe: Drop gperftools for mips/musl as well
      python-slip-dbus: Add missing rdep on six module
      htop: Use python3
      pidgin: Use python3
      mercurial: Upgrade to 5.2 and switch to py3
      a2jmidid: Upgrade to release 9
      pidgin: Use python3 during build
      tvheadend: Demand use of py3 during build

Lei YU (1):
      googletest: Add PV and set to 1.10.0

Leon Anavi (1):
      stalonetray: Add a simple stand-alone system tray

Li Zhou (1):
      libssh2: Security Advisory - libssh2 - CVE-2019-17498

Michael Haener (1):
      libmbim: upgrade 1.20.0 -> 1.20.2

Nicola Lunghi (2):
      python-configargparse: add package (version 0.15.1)
      python3-dbussy: add recipe (v1.2.1)

Qi.Chen@windriver.com (1):
      python3-pid: upgrade to 2.2.5

Ross Burton (3):
      glmark2: upgrade to latest HEAD
      glmark2: use Python 3 to build
      jack: upgrade to 1.19.14

Ulrich Ölmann (1):
      python3-yarl: add missing dependencies

Zang Ruochen (6):
      p910nd: upgrade 0.95 -> 0.97
      links: upgrade 2.16 -> 2.20.2
      links-x11: upgrade 2.16 -> 2.20.2
      libmicrohttpd: upgrade 0.9.67 -> 0.9.68
      gsoap: upgrade 2.8.51 -> 2.8.95
      mksh: upgrade 56 -> 57

Zheng Ruoqin (1):
      libsdl: Refresh patch

zhangxiao (1):
      syslog-ng: Fix multilib header conflict - syslog-ng-config.h

Change-Id: I8557e00b893b61c10ee305fb3229db773b4b894f
Signed-off-by: Brad Bishop <bradleyb@fuzziesquirrel.com>

1 files changed, 51 insertions, 0 deletions

diff --git a/meta-openembedded/meta-oe/recipes-multimedia/jack/jack_1.19.14.bb b/meta-openembedded/meta-oe/recipes-multimedia/jack/jack_1.19.14.bb
new file mode 100644
index 0000000000..cebc952661
--- /dev/null
+++ b/meta-openembedded/meta-oe/recipes-multimedia/jack/jack_1.19.14.bb
@@ -0,0 +1,51 @@
+DESCRIPTION = "jackdmp is a C++ version of the JACK low-latency audio \
+server for multi-processor machines. It is a new implementation of the \
+JACK server core features that aims in removing some limitations of \
+the JACK1 design. The activation system has been changed for a data \
+flow model and lock-free programming techniques for graph access have \
+been used to have a more dynamic and robust system."
+SECTION = "libs/multimedia"
+
+LICENSE = "GPLv2 & LGPLv2.1"
+LIC_FILES_CHKSUM = " \
+    file://common/jack/control.h;beginline=2;endline=21;md5=e6df0bf30cde8b3b825451459488195d \
+    file://common/jack/jack.h;beginline=1;endline=19;md5=6b736ed6b810592b135480a5e853392e \
+"
+
+DEPENDS = "libsamplerate0 libsndfile1 readline"
+
+SRC_URI = "git://github.com/jackaudio/jack2.git"
+SRCREV = "b54a09bf7ef760d81fdb8544ad10e45575394624"
+
+S = "${WORKDIR}/git"
+
+inherit waf pkgconfig
+
+PACKAGECONFIG ??= "alsa"
+PACKAGECONFIG[alsa] = "--alsa=yes,--alsa=no,alsa-lib"
+# --dbus only stops building jackd -> add --classic
+PACKAGECONFIG[dbus] = "--dbus --classic,,dbus"
+PACKAGECONFIG[opus] = "--opus=yes,--opus=no,libopus"
+
+# portaudio is for windows builds only
+EXTRA_OECONF = "--portaudio=no"
+
+do_install_append() {
+	if ! ${@bb.utils.contains('PACKAGECONFIG', 'dbus', True, False, d)}; then
+		rm -f ${D}${bindir}/jack_control
+	fi
+}
+
+PACKAGES =+ "libjack jack-server jack-utils"
+
+RDEPENDS_jack-dev_remove = "${PN} (= ${EXTENDPKGV})"
+
+FILES_libjack = "${libdir}/*.so.* ${libdir}/jack/*.so"
+FILES_jack-server = " \
+    ${datadir}/dbus-1/services \
+    ${bindir}/jackdbus \
+    ${bindir}/jackd \
+"
+FILES_jack-utils = "${bindir}/*"
+
+FILES_${PN}-doc += " ${datadir}/jack-audio-connection-kit/reference/html/*"